PageRenderTime 82ms CodeModel.GetById 40ms app.highlight 2ms RepoModel.GetById 38ms app.codeStats 0ms

/indra/newview/app_settings/shaders/class1/deferred/sunLightSSAOMSF.glsl

https://bitbucket.org/lindenlab/viewer-beta/
text | 140 lines | 111 code | 29 blank | 0 comment | 0 complexity | 775a7b6c630cbb0ffc56a9a072a23754 MD5 | raw file
  1/** 
  2 * @file sunLightSSAOF.glsl
  3 * $LicenseInfo:firstyear=2007&license=viewerlgpl$
  4 * Second Life Viewer Source Code
  5 * Copyright (C) 2007, Linden Research, Inc.
  6 * 
  7 * This library is free software; you can redistribute it and/or
  8 * modify it under the terms of the GNU Lesser General Public
  9 * License as published by the Free Software Foundation;
 10 * version 2.1 of the License only.
 11 * 
 12 * This library is distributed in the hope that it will be useful,
 13 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 14 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
 15 * Lesser General Public License for more details.
 16 * 
 17 * You should have received a copy of the GNU Lesser General Public
 18 * License along with this library; if not, write to the Free Software
 19 * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA
 20 * 
 21 * Linden Research, Inc., 945 Battery Street, San Francisco, CA  94111  USA
 22 * $/LicenseInfo$
 23 */
 24 
 25
 26
 27#extension GL_ARB_texture_rectangle : enable
 28#extension GL_ARB_texture_multisample : enable
 29
 30//class 1 -- no shadow, SSAO only
 31
 32uniform sampler2DMS depthMap;
 33uniform sampler2DMS normalMap;
 34uniform sampler2D noiseMap;
 35
 36
 37// Inputs
 38uniform mat4 shadow_matrix[6];
 39uniform vec4 shadow_clip;
 40uniform float ssao_radius;
 41uniform float ssao_max_radius;
 42uniform float ssao_factor;
 43uniform float ssao_factor_inv;
 44
 45varying vec2 vary_fragcoord;
 46varying vec4 vary_light;
 47
 48uniform mat4 inv_proj;
 49uniform vec2 screen_res;
 50
 51uniform float shadow_bias;
 52uniform float shadow_offset;
 53
 54vec4 getPosition(ivec2 pos_screen, int sample)
 55{
 56	float depth = texelFetch(depthMap, pos_screen, sample).r;
 57	vec2 sc = pos_screen.xy*2.0;
 58	sc /= screen_res;
 59	sc -= vec2(1.0,1.0);
 60	vec4 ndc = vec4(sc.x, sc.y, 2.0*depth-1.0, 1.0);
 61	vec4 pos = inv_proj * ndc;
 62	pos /= pos.w;
 63	pos.w = 1.0;
 64	return pos;
 65}
 66
 67//calculate decreases in ambient lighting when crowded out (SSAO)
 68float calcAmbientOcclusion(vec4 pos, vec3 norm, int sample)
 69{
 70	float ret = 1.0;
 71	
 72	vec2 kern[8];
 73	// exponentially (^2) distant occlusion samples spread around origin
 74	kern[0] = vec2(-1.0, 0.0) * 0.125*0.125;
 75	kern[1] = vec2(1.0, 0.0) * 0.250*0.250;
 76	kern[2] = vec2(0.0, 1.0) * 0.375*0.375;
 77	kern[3] = vec2(0.0, -1.0) * 0.500*0.500;
 78	kern[4] = vec2(0.7071, 0.7071) * 0.625*0.625;
 79	kern[5] = vec2(-0.7071, -0.7071) * 0.750*0.750;
 80	kern[6] = vec2(-0.7071, 0.7071) * 0.875*0.875;
 81	kern[7] = vec2(0.7071, -0.7071) * 1.000*1.000;
 82
 83	vec2 pos_screen = vary_fragcoord.xy;
 84	vec3 pos_world = pos.xyz;
 85	vec2 noise_reflect = texture2D(noiseMap, vary_fragcoord.xy/128.0).xy;
 86		
 87	float angle_hidden = 0.0;
 88	int points = 0;
 89		
 90	float scale = min(ssao_radius / -pos_world.z, ssao_max_radius);
 91		
 92	// it was found that keeping # of samples a constant was the fastest, probably due to compiler optimizations unrolling?)
 93	for (int i = 0; i < 8; i++)
 94	{
 95		ivec2 samppos_screen = ivec2(pos_screen + scale * reflect(kern[i], noise_reflect));
 96		vec3 samppos_world = getPosition(samppos_screen, sample).xyz; 
 97			
 98		vec3 diff = pos_world - samppos_world;
 99		float dist2 = dot(diff, diff);
100			
101		// assume each sample corresponds to an occluding sphere with constant radius, constant x-sectional area
102		// --> solid angle shrinking by the square of distance
103		//radius is somewhat arbitrary, can approx with just some constant k * 1 / dist^2
104		//(k should vary inversely with # of samples, but this is taken care of later)
105			
106		angle_hidden = angle_hidden + float(dot((samppos_world - 0.05*norm - pos_world), norm) > 0.0) * min(1.0/dist2, ssao_factor_inv);
107			
108		// 'blocked' samples (significantly closer to camera relative to pos_world) are "no data", not "no occlusion" 
109		points = points + int(diff.z > -1.0);
110	}
111		
112	angle_hidden = min(ssao_factor*angle_hidden/float(points), 1.0);
113		
114	ret = (1.0 - (float(points != 0) * angle_hidden));
115	
116	return min(ret, 1.0);
117}
118
119void main() 
120{
121	vec2 pos_screen = vary_fragcoord.xy;
122	ivec2 itc = ivec2(pos_screen);
123		
124	float col = 0;
125
126	for (int i = 0; i < samples; i++)
127	{
128		vec4 pos = getPosition(itc, i);
129		vec3 norm = texelFetch(normalMap, itc, i).xyz;
130		norm = vec3((norm.xy-0.5)*2.0,norm.z); // unpack norm
131		col += calcAmbientOcclusion(pos,norm,i);
132	}
133
134	col /= samples;
135
136	gl_FragColor[0] = 1.0;
137	gl_FragColor[1] = col;
138	gl_FragColor[2] = 1.0; 
139	gl_FragColor[3] = 1.0;
140}