/MSP-EXP430FR5969/MSP-EXP430FR5969_8MHz_SD_Card/RC5toLCD.4th
Forth | 489 lines | 446 code | 43 blank | 0 comment | 17 complexity | 64e3a45f12b2e42e374673e2605676b0 MD5 | raw file
Possible License(s): GPL-3.0
- ; ----------------------------------
- ; MSP-EXP430FR5969_8MHZ_RC5toLCD.4th
- ; ----------------------------------
- STOP ; to stop any interrupt in progress
- WIPE ;
- NOECHO ; comment to debug
- ; Copyright (C) <2015> <J.M. THOORENS>
- ;
- ; This program is free software: you can redistribute it and/or modify
- ; it under the terms of the GNU General Public License as published by
- ; the Free Software Foundation, either version 3 of the License, or
- ; (at your option) any later version.
- ;
- ; This program is distributed in the hope that it will be useful,
- ; but WITHOUT ANY WARRANTY; without even the implied warranty of
- ; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
- ; GNU General Public License for more details.
- ;
- ; You should have received a copy of the GNU General Public License
- ; along with this program. If not, see <http://www.gnu.org/licenses/>.
-
-
- ; display on a LCD 2x20 CHAR the code sent by an IR remote under philips RC5 protocol
-
- ; target : MSP-EXP430fr5969 LAUNCHPAD at 8 MHz
-
- ; DEMO : driver for IR remote compatible with the PHILIPS RC5 protocol
- ; plus : driver for 5V LCD 2x20 characters display with 4 bits data interface
- ; without usage of an auxiliary 5V to feed the LCD_Vo
- ; without potentiometer to adjust the LCD contrast :
- ; to adjust LCD contrast, just press S1 (-) or S2 (+)
- ; P2.2 current consumption ~ 500 uA
-
- ; ===================================================================================
- ; in case of 3.3V powered by UARTtoUSB bridge, open J13 straps {RST,TST,V+,5V} BEFORE
- ; ===================================================================================
- ; -----------------------------------------------
- ; MSP - LAUNCHPAD <--> OUTPUT WORLD
- ; -----------------------------------------------
- ; P4.6 - J6 - LED1 red
- ; P1.0 - LED2 green
- ; P4.5 - Switch S1 <--- LCD contrast + (finger :-)
- ; P1.1 - Switch S2 <--- LCD contrast - (finger ;-)
-
- ; GND - J1.2 <-------+---0V0----------> 1 LCD_Vss
- ; VCC - J1.3 >------ | --3V6-----+----> 2 LCD_Vdd
- ; | |
- ; |___ 470n ---
- ; ^ | ---
- ; / \ BAT54 |
- ; --- |
- ; 100n | 2k2 |
- ; P2.2 - J4.7 UCB0 CLK TB0.2 >---||--+--^/\/\/v--+----> 3 LCD_Vo (=0V6 without modulation)
- ; P3.4 - J4.8 -------------------------> 4 LCD_RS
- ; P3.5 - J4.9 -------------------------> 5 LCD_R/W
- ; P3.6 - J4.10 -------------------------> 6 LCD_EN0
- ; PJ.0 - J3.1 <------------------------> 11 LCD_DB4
- ; PJ.1 - J3.3 <------------------------> 12 LCD_DB5
- ; PJ.2 - J3.5 <------------------------> 13 LCD_DB5
- ; PJ.3 - J3.7 <------------------------> 14 LCD_DB7
- ; PJ.4 - LFXI 32768Hz quartz
- ; PJ.5 - LFXO 32768Hz quartz
- ; PJ.6 - HFXI
- ; PJ.7 - HFXO
-
- ; P2.0 - J13.8 UCA0 TXD ---> RX UARTtoUSB bridge
- ; P2.1 - J13.10 UCA0 RXD <--- TX UARTtoUSB bridge
- ; P4.1 - J13.14 RTS ---> CTS UARTtoUSB bridge (optional hardware control flow)
- ; VCC - J13.16 <--- VCC (optional supply from UARTtoUSB bridge - WARNING ! 3.3V !)
- ; GND - J13.20 <--> GND (optional supply from UARTtoUSB bridge)
-
- ; VCC - J11.1 ---> VCC SD_CardAdapter
- ; GND - J12.3 <--> GND SD_CardAdapter
- ; P2.4 - J4.6 UCA1 CLK ---> CLK SD_CardAdapter (SCK)
- ; P4.3 - J4.5 ---> CS SD_CardAdapter (Card Select)
- ; P2.5 - J4.4 UCA1 TXD/SIMO ---> SDI SD_CardAdapter (MOSI)
- ; P2.6 - J4.3 UCA1 RXD/SOMI <--- SDO SD_CardAdapter (MISO)
- ; P4.2 - J4.2 <--- CD SD_CardAdapter (Card Detect)
-
- ; P4.0 - J3.10 CTS <--- OUT IR_Receiver (1 TSOP32236)
- ; VCC - J3.2 ---> VCC IR_Receiver (2 TSOP32236)
- ; GND - J3.9 <--> GND IR_Receiver (3 TSOP32236)
-
- ; P1.2 - J5.19 <--> SDA I2C SOFTWARE MASTER
- ; P1.3 - J5.11 <--> SCL I2C SOFTWARE MASTER
- ; P1.4 - J5.12 TB0.1 <--> free
- ; P1.5 - J5.13 UCA0 CLK TB0.2 <--> free
- ; P1.7 - J5.14 UCB0 SCL/SOMI <--> SCL I2C MASTER/SLAVE
- ; P1.6 - J5.15 UCB0 SDA/SIMO <--> SDA I2C MASTER/SLAVE
- ; P3.0 - J5.7 <--- free
- ; P2.3 - NC
- ; P2.7 - NC
- ; P3.1 - NC
- ; P3.2 - NC
- ; P3.3 - NC
- ; P3.7 - NC
- ; P4.4 - NC
- ; P4.7 - NC
- ; HERE ; general minidump, part 1
- ; ------------------------------;
- CODE 20_us ; n -- n * 20 us
- ; ------------------------------;
- BEGIN ; 3 cycles loop + 6~
- ; MOV #5,W ; 3 MCLK = 1 MHz
- ; MOV #23,W ; 3 MCLK = 4 MHz
- MOV #51,W ; 3 MCLK = 8 MHz
- ; MOV #104,W ; 3 MCLK = 16 MHz
- ; MOV #158,W ; 3 MCLK = 24 MHz
- BEGIN ; 3 cycles loop ==> 3 * W / F us = 100 us - 1 @ 8 MHz
- SUB #1,W ; 1
- 0= UNTIL ; 2
- SUB #1,TOS ; 1
- 0= UNTIL ; 2
- MOV @PSP+,TOS ; 2
- MOV @IP+,PC ; 4
- ENDCODE
- ; ------------------------------;
- CODE TOP_LCD ; LCD Sample
- ; ------------------------------; if write : 0bxxxxWWWW --
- ; if read : -- 0b0000RRRR
- BIS.B #0x40,&0x222 ; P3OUT.6 LCD_EN 0-->1
- BIT.B #0x20,&0x220 ; P3IN.5 LCD_RW test
- 0= IF ; write LCD bits pattern
- AND #0x0F,TOS ;
- MOV.B TOS, &0x322 ; MOVE LCD_Data bits to PJ(0-3)
- BIC.B #0x40,&0x222 ; P3OUT.6 LCD_EN 1-->0 ==> strobe data
- MOV @PSP+,TOS ;
- MOV @IP+,PC
- THEN ; read LCD bits pattern
- SUB #2,PSP
- MOV TOS,0(PSP)
- BIC.B #0x40,&0x222 ; P3OUT.6 LCD_EN 1-->0 ==> strobe data
- MOV.B &0x320,TOS ; get LCD_Data from PJ(0-3)
- AND.B #0x0F,TOS
- MOV @IP+,PC
- ENDCODE
- ; ------------------------------;
- CODE LCD_W ; byte -- write byte
- ; ------------------------------;
- SUB #2,PSP ;
- MOV TOS,0(PSP) ; -- 0bxxxxLLLL 0bHHHHLLLL
- RRUM #4,TOS ; -- 0bxxxxLLLL 0bxxxxHHHH
- BIC.B #0x20,&0x222 ; P3OUT.5 LCD_RW=0
- BIS.B #0x0F,&0x324 ; PJDIR.(0-3) LCD_Data as output
- PUSH IP
- ASM>FORTH
- TOP_LCD 2 20_us \ write high nibble first
- TOP_LCD 2 20_us ;
- ; ------------------------------;
- CODE LCD_R ; -- byte read byte
- ; ------------------------------;
- BIC.B #0x0F,&0x324 ; PJ.(0-3) LCD_Data as intput
- BIS.B #0x20,&0x222 ; P3.5 LCD_RW=1
- PUSH IP
- ASM>FORTH
- TOP_LCD 2 20_us \ read high nibble first
- TOP_LCD 2 20_us
- FORTH>ASM ; -- 0b0000HHHH 0b0000LLLL
- MOV @RSP+,IP
- MOV @PSP+,W ; W = high nibble
- RLAM #4,W ; -- 0b0000LLLL W = 0bHHHH0000
- ADD.B W,TOS
- MOV @IP+,PC
- ENDCODE
- ; ------------------------------;
- CODE LCD_WrF ; func -- Write Fonction
- ; ------------------------------;
- BIC.B #0x10,&0x222 ; P3OUT.4 LCD_RS=0
- JMP LCD_W
- ENDCODE
- ; ------------------------------;
- CODE LCD_RdS ; -- status Read Status
- ; ------------------------------;
- BIC.B #0x10,&0x222 ; P3OUT.4 LCD_RS=0
- JMP LCD_R
- ENDCODE
- ; ------------------------------;
- CODE LCD_WrC ; char -- Write Char
- ; ------------------------------;
- BIS.B #0x10,&0x222 ; P3OUT.4 LCD_RS=1
- JMP LCD_W
- ENDCODE
- ; ------------------------------;
- CODE LCD_RdC ; -- char Read Char
- ; ------------------------------;
- BIS.B #0x10,&0x222 ; P3OUT.4 LCD_RS=1
- JMP LCD_R
- ENDCODE
- ; ------------------------------;
- \ : LCD_Clear 0x01 LCD_WrF 80 20_us ; bad init !
- : LCD_Clear 0x01 LCD_WrF 100 20_us ;
- ; ------------------------------;
- : LCD_Home 0x02 LCD_WrF 80 20_us ;
- ; ------------------------------;
- ; : LCD_Entry_set 0x04 OR LCD_WrF ;
- ; : LCD_Display_Ctrl 0x08 OR LCD_WrF ;
- ; : LCD_Display_Shift 0x10 OR LCD_WrF ;
- ; : LCD_Fn_Set 0x20 OR LCD_WrF ;
- ; : LCD_CGRAM_Set 0x40 OR LCD_WrF ;
- ; : LCD_Goto 0x80 OR LCD_WrF ;
- ; ------------------------------;
- ; IR_RC5 driver ;
- ; ******************************;
- CODE IR_RC5 ; wake up on P4.0 change interrupt
- ; ******************************;
- BIC #0xF8,0(RSP) ; CPU on, GIE off in oldSR
- ; ------------------------------;
- ; in : SR(9)=old Toggle bit memory
- ; SMclock = 8 MHz or 16 MHz
- ; use : U,V,W,X,Y, TA0 timer, TA0R register
- ; out : U = 0 x T A4 A3 A2 A1 A0| 0 C6 C5 C4 C3 C2 C1 C0
- ; SR(9)=new Toggle bit memory
- ; ------------------------------;
- ; RC5_FirstStartBitHalfCycle: ;
- ; ------------------------------;
- MOV #0,&0x0360 ; predivide by 1 in TA0EX0 register ( 8 MHZ), reset value
- ; MOV #1,&0x0360 ; predivide by 2 in TA0EX0 register (16 MHZ)
- ; MOV #2,&0x0360 ; predivide by 3 in TA0EX0 register (24 MHZ)
- MOV #1778,X ; RC5_Period in us
- MOV #14,W ; count of loop
- BEGIN ;
- ; ------------------------------;
- ; RC5_TopSynchro: ; <--- loop back ---+ with readjusted RC5_Period
- ; ------------------------------; | here, we are just after 1/2 RC5_cycle
- MOV #0b1011100100,&0x0340 ; (re)start timer_A | SMCLK_pre/2 /8 : 2us time interval,free running,clear TA0_IFG and TA0R
- ; RC5_Compute_3_4Period: ; |
- RRUM #1,X ; X=1/2 cycle |
- MOV X,Y ; Y=1/2 ^
- RRUM #1,Y ; Y=1/4
- ADD X,Y ; Y=3/4
- ; RC5_Wait_1_4: ; wait 3/4 cycle after 1/2 cycle to sample RC5_Input at 1/4 cycle
- BEGIN CMP Y,&0x0350 ; CMP &TA0R with 3/4 cycle value
- = UNTIL ;
- ; ------------------------------;
- ; RC5_Sample: ; at 1/4 cycle, we can sample RC5_input, ST2/C6 bit first
- ; ------------------------------;
- BIT.B #0x01,&0x0221 ; C_flag = P4.0 = IR bit
- ADDC V,V ; C_flag <-- V(15):V(0) <-- C_flag
- MOV.B &0x0221,&0x0239 ; preset IES_4.0 state for next IFG
- BIC.B #0x01,&0x023D ; clear P4.0_IFG after full cycle pin change
- SUB #1,W ; decrement count loop
- ; count = 13 ==> V = x x x x x x x x |x x x x x x x /C6
- ; count = 0 ==> V = x x /C6 Tg A4 A3 A2 A1|A0 C5 C4 C3 C2 C1 C0 1
- 0<> WHILE ; ----> out of loop ----+
- ; RC5_compute_2_4_OverFlow: ; |
- ADD X,Y ; | out of bound = 5/4 period
- ; RC5_WaitHalfCycleP1.2_IFG: ; |
- BEGIN ; |
- CMP Y,&0x0350 ; | TA0R = 5/4 cycle test
- >= IF ; | if cycle time out of bound
- MOV #4,&0x0340 ; | stop timer_A and clear TA0R
- RETI ; | then quit to do nothing
- THEN ; |
- ; ------------------------------; |
- BIT.B #0x01,&0x023D ; ^ | test P4.0_IFG
- <> UNTIL ; | |
- MOV &0x0350,X ; | | get new RC5_period value
- REPEAT ; ----> loop back --+ |
- ; ------------------------------; |
- ; RC5_SampleEndOf: ; <---------------------+
- ; ------------------------------;
- MOV #4,&0x0340 ; stop timer_A
- RLAM #1,V ; V = x /C6 Tg A4 A3 A2 A1 A0|C5 C4 C3 C2 C1 C0 1 0
- ; ------------------------------;
- ; ------------------------------;
- ; Only New_RC5_Command ADD_ON ; use SR(9) bit as toggle bit
- ; ------------------------------;
- MOV @RSP,X ; retiSR(9) = old RC5 toggle bit
- RLAM #4,X ; retiSR(9) --> X(13)
- XOR V,X ; (new XOR old)(13) Toggle bit
- BIT #0x2000,X ; X(13) = New_RC5_command
- 0= IF ;
- RETI ; case of repeated RC5_command : RETI without SR(9) change
- THEN ;
- XOR #0x0200,0(RSP) ; change Toggle bit memory SR(9)
- ; ------------------------------;
- ; ------------------------------;
- ; RC5_ComputeNewRC5word ;
- ; ------------------------------;
- MOV.B V,U ; U= 0 0 0 0 0 0 0 0 C5 C4 C3 C2 C1 C0 0 0
- RRUM #2,U ; U= 0 0 0 0 0 0 0 0 0 0 C5 C4 C3 C2 C1 C0
- ; AND #0x7F00,V ; V= 0 /C6 Tg A4 A3 A2 A1 A0 0 0 0 0 0 0 0 0
- ; ADD V,U ; U= 0 /C6 Tg A4 A3 A2 A1 A0 0 0 C5 C4 C3 C2 C1 C0
- ; ------------------------------;
- ; RC5_ComputeC6bit ;
- ; ------------------------------;
- BIT #0x4000,V ; test /C6
- 0= IF BIS.B #0x40,U ; set C6 bit
- THEN ;
- ; ------------------------------;
- ; RC5_CommandByteIsDone: ; U= 0 0 0 0 0 0 0 0 0 C6 C5 C4 C3 C2 C1 C0
- ; ------------------------------;
- ; ------------------------------;
- ; Display IR_RC5 code ;
- ; ------------------------------;
- BIS.B #0x40,&0x0223 ; P4.6 OUT high ==> switch ON LED1
- ; ------------------------------;
- SUB #4,PSP ;
- MOV &BASE,2(PSP) ; save base
- MOV TOS,0(PSP) ;
- MOV.B U,TOS ;
- ASM>FORTH \ ; IP is free
- ['] LCD_CLEAR IS CR
- ['] LCD_WrC IS EMIT
- CR ." 0x" HEX 2 U.R
- ['] (CR) IS CR
- ['] (EMIT) IS EMIT
- FORTH>ASM ; nice code, right ?
- MOV @PSP+,&BASE
- ; ------------------------------;
- BIC.B #0x40,&0x0223 ; P4.6 OUT low ==> switch OFF LED1
- ; ------------------------------;
- RETI ; CPU is ON, GIE is OFF
- ENDCODE ;
- ; ******************************;
- ; ******************************;
- CODE WDT_Int ; Watchdog interrupt routine, warning : not FORTH executable !
- ; ******************************;
- BIC #0xF8,0(RSP) ; set CPU ON and GIE OFF in retiSR
- ; ******************************;
- BIT.B #0x02,&0x200 ; test P1IN.1 = switch S2
- 0= IF ; case of switch S2 pressed
- CMP #34,&0x3D6 ; TB0CCR2 ; maxi Ton = 34/40 & VDD=3V6 ==> LCD_Vo = -2V2
- U< IF
- ADD #1,&0x3D6 ; TB0CCR2 ; action for switch S2 (P1.1) : 78 mV / increment
- THEN
- ELSE
- BIT.B #0x20,&0x221 ; test P4IN.5 = switch S1 input
- 0= IF ; case of Switch S1 pressed
- CMP #7,&0x3D6 ; TB0CCR2 ; mini Ton = 6/40 & VDD=3V6 ==> LCD_Vo = 0V
- U>= IF ;
- SUB #1,&0x3D6 ; TB0CCR2 ; action for switch S1 (P4.5) : -78 mV / decrement
- THEN ;
- THEN ;
- THEN ;
- RETI ; CPU is ON, GIE is OFF
- ENDCODE ;
- ; ******************************;
- ; ------------------------------;
- CODE START ; init application
- ; ------------------------------;
- ; 0b0000 0010 1001 0100 ; TB0CTL = 0x3C0
- ; - - ; CNTL Counter lentgh ; 00 = 16 bits
- ; -- ; TBSSEL TimerB clock select ; 10 = SMCLK
- ; -- ; ID input divider ; 10 = /4
- ; -- ; MC Mode Control ; 01 = up mode
- ; - ; TBCLR TimerB Clear
- ; - ; TBIE
- ; - ; TBIFG
- ; ------------------------------;
- ; 0b0000 0000 0110 0000 ; TB0CCTLx = 0x3C{2,4,6,8,A,C,E}
- ; -- ; CM Capture Mode
- ; -- ; CCIS
- ; - ; SCS
- ; -- ; CLLD
- ; - ; CAP
- ; --- ; OUTMOD ; 011 = set/reset
- ; - ; CCIE
- ; - ; CCI
- ; - ; OUT
- ; - ; COV
- ; - ; CCIFG
- ; ------------------------------;
- ; ; TB0CCRx 0x3D{2,4,6,8,A,C,E}
- ; ; TB0EX0 0x3E0
- ; ------------------------------;
- ; set TimerB to make 50kHz PWM ;
- ; ------------------------------;
- ; MOV #0b1000010100,&0x3C0 ; TB0CTL = SMCLK/1, up mode, clear timer, no int
- ; MOV #0,&0x03E0 ; predivide by 1 in TB0EX0 register (1 MHZ) (25 kHz PWM)
- ; ------------------------------;
- ; MOV #0b1000010100,&0x3C0 ; TB0CTL = SMCLK/1, up mode, clear timer, no int
- ; MOV #1,&0x03E0 ; predivide by 2 in TB0EX0 register (4 MHZ)
- ; ------------------------------;
- MOV #0b1010010100,&0x3C0 ; TB0CTL = SMCLK/4, up mode, clear timer, no int
- MOV #0,&0x03E0 ; predivide by 1 in TB0EX0 register (8 MHZ)
- ; ------------------------------;
- ; MOV #0b1010010100,&0x3C0 ; TB0CTL = SMCLK/4, up mode, clear timer, no int
- ; MOV #1,&0x03E0 ; predivide by 2 in TB0EX0 register (16 MHZ)
- ; ------------------------------;
- ; MOV #0b1010010100,&0x3C0 ; TB0CTL = SMCLK/4, up mode, clear timer, no int
- ; MOV #2,&0x03E0 ; predivide by 3 in TB0EX0 register (24 MHZ)
- ; ------------------------------;
- MOV #40,&0x3D2 ; TB0CCR0 = 40*0.5us=20us (40us @ 1MHz)
- ; ------------------------------;
- ; set TimerB to generate LCD_V0 via TB0.2 and P1.5/P2.2
- ; ------------------------------;
- MOV #0b1100000,&0x3C6 ; TB0CCTL2 output mode = set/reset ; clear CCIFG
- MOV #20,&0x3D6 ; TB0CCR2 ; contrast adjust : 20/40 ==> LCD_Vo = -1V1
- ; ------------------------------;
- ; init PORTA (P2:P1) (complement)
- BIS.B #0x04,&0x205 ; P2DIR.2 TB0.2 output
- BIS.B #0x04,&0x20B ; P2SEL0.2 TB0.2
- ; ------------------------------;
- ; init PORTB (P4:P3) (complement)
- BIS.B #0x70,&0x224 ; P3DIR.(4-6) as outputs
- BIC.B #0x70,&0x226 ; P3REN.(4-6) pullup/down disable
- BIC.B #0x30,&0x222 ; P3OUT.5 LCD_RW=0, P3OUT.4 LCD_RS=0
- BIS.B #1,&0x239 ; P4IES.0 high to low edge select
- BIC.B #1,&0x23D ; P4IFG.0 clear int flag TSOP32236 (after IES select)
- BIS.B #1,&0x23B ; P4IE.0 enable interrupt TSOP32236
- ; ------------------------------;
- ; init PORTJ (PJ) (complement)
- BIS.B #0x0F,&0x324 ; PJDIR.(0-3) as output, wired to DB(4-7) LCD_Data
- BIC.B #0x0F,&0x326 ; PJREN.(0-3) LCD_Data pullup/down disable
- ; ------------------------------;
- ; WDT interval init part ;
- ; ------------------------------;
- ; MOV #0x5A5E,&0x15C ; init WDT Vloclk source 10kHz /2^9 (50 ms), interval mode
- MOV #0x5A3D,&0x15C ; init WDT ACLK source 32.768kHz /2^13 (250 ms), interval mode
- ; MOV #0x5A5D,&0x15C ; init WDT Vloclk source 10kHz /2^13 (800 ms), interval mode
- BIS #1,&0x100 ; enable WDT interval mode interrupt in SFRIE
- ; ------------------------------;
- ; init interrupt vectors
- ; ------------------------------;
- MOV #WDT_Int,&0xFFF2 ; init WDT interval vector interrupt
- MOV #IR_RC5,&0xFFD0 ; init P4 interrupt vector
- ; ------------------------------;
- ; Init LCD 2x20 ;
- ; ------------------------------;
- ASM>FORTH
- 0x03E8 20_us \ ; 1- wait 20 ms
- 0x03 TOP_LCD \ ; 2- send DB5=DB4=1
- 0xCD 20_us \ ; 3- wait 4,1 ms
- 0x03 TOP_LCD \ ; 4- send again DB5=DB4=1
- 5 20_us \ ; 5- wait 0,1 ms
- 0x03 TOP_LCD \ ; 6- send again again DB5=DB4=1
- 2 20_us \ ; wait 40 us = LCD cycle
- 0x02 TOP_LCD \ ; 7- send DB5=1 DB4=0
- 2 20_us \ ; wait 40 us = LCD cycle
- 0x28 LCD_WrF \ ; 8- 0b001DNFxx "FonctionSet" D=8/4 DataBus width, Number of lines=2/1, Font bold/normal
- 0x08 LCD_WrF \ ; 9- 0b1DCB "DisplayControl" : Display off, Cursor off, Blink off.
- LCD_Clear \ ; 10- "LCD_Clear"
- 0x06 LCD_WrF \ ; 11- 0b01xx "LCD_EntrySet" : address and cursor shift after writing in RAM
- 0x0C LCD_WrF \ ; 12- 0b1DCB "DisplayControl" : Display on, Cursor off, Blink off.
- ." RC5toLCD is running. Type STOP to quit"
- LIT RECURSE IS WARM \ ; insert this starting routine between COLD and (WARM)...
- (WARM) ; ; ...and continue with (WARM) (very, very usefull after COLD or RESET !:-)
- ; ------------------------------;
- CODE STOP ; MUST BE USED before loading another program with new interrupt configuration.
- ; ------------------------------;
- MOV #0b1010000100,&0x3C0 ; TB0CTL = SMCLK/4, STOP mode, clear timer, no int
- BIC.B #0x01,&0x23B ; P4IE.0 disable interrupt for RC5_INT
- BIC #1,&0x100 ; disable WDT interval mode interrupt in SFRIE
- ASM>FORTH
- ['] (WARM) IS WARM \ ; reconnect WARM to (WARM)
- -1 ABORT"
- ; ; on previous line don't add any char after ABORT", so its message is empty
- ; DUP HERE SWAP - DUMP ; general minidump, part 2
- FORGET IR_RC5 FORGET WDT_Int ; not FORTH executable
- FORGET TOP_LCD FORGET 20_us ; because they are not necessary
- FORGET LCD_W FORGET LCD_R ; because they are not necessary
- ECHO
- ; compiling done
- RST_HERE ;
- START ; hit key enter :