PageRenderTime 51ms CodeModel.GetById 12ms RepoModel.GetById 0ms app.codeStats 1ms

/wrfv2_fire/phys/module_mp_wsm5_accel.F

http://github.com/jbeezley/wrf-fire
FORTRAN Legacy | 3093 lines | 2052 code | 59 blank | 982 comment | 153 complexity | 4a961fc46c3dd28793c37a174419a9c5 MD5 | raw file
Possible License(s): AGPL-1.0

Large files files are truncated, but you can click here to view the full file

  1. #if ( RWORDSIZE == 4 )
  2. # define VREC vsrec
  3. # define VSQRT vssqrt
  4. #else
  5. # define VREC vrec
  6. # define VSQRT vsqrt
  7. #endif
  8. !Including inline expansion statistical function
  9. MODULE module_mp_wsm5
  10. !
  11. !
  12. REAL, PARAMETER, PRIVATE :: dtcldcr = 120. ! maximum time step for minor loops
  13. REAL, PARAMETER, PRIVATE :: n0r = 8.e6 ! intercept parameter rain
  14. REAL, PARAMETER, PRIVATE :: avtr = 841.9 ! a constant for terminal velocity of rain
  15. REAL, PARAMETER, PRIVATE :: bvtr = 0.8 ! a constant for terminal velocity of rain
  16. REAL, PARAMETER, PRIVATE :: r0 = .8e-5 ! 8 microm in contrast to 10 micro m
  17. REAL, PARAMETER, PRIVATE :: peaut = .55 ! collection efficiency
  18. REAL, PARAMETER, PRIVATE :: xncr = 3.e8 ! maritime cloud in contrast to 3.e8 in tc80
  19. REAL, PARAMETER, PRIVATE :: xmyu = 1.718e-5 ! the dynamic viscosity kgm-1s-1
  20. REAL, PARAMETER, PRIVATE :: avts = 11.72 ! a constant for terminal velocity of snow
  21. REAL, PARAMETER, PRIVATE :: bvts = .41 ! a constant for terminal velocity of snow
  22. REAL, PARAMETER, PRIVATE :: n0smax = 1.e11 ! maximum n0s (t=-90C unlimited)
  23. REAL, PARAMETER, PRIVATE :: lamdarmax = 8.e4 ! limited maximum value for slope parameter of rain
  24. REAL, PARAMETER, PRIVATE :: lamdasmax = 1.e5 ! limited maximum value for slope parameter of snow
  25. REAL, PARAMETER, PRIVATE :: lamdagmax = 6.e4 ! limited maximum value for slope parameter of graupel
  26. REAL, PARAMETER, PRIVATE :: dicon = 11.9 ! constant for the cloud-ice diamter
  27. REAL, PARAMETER, PRIVATE :: dimax = 500.e-6 ! limited maximum value for the cloud-ice diamter
  28. REAL, PARAMETER, PRIVATE :: n0s = 2.e6 ! temperature dependent intercept parameter snow
  29. REAL, PARAMETER, PRIVATE :: alpha = .12 ! .122 exponen factor for n0s
  30. REAL, PARAMETER, PRIVATE :: pfrz1 = 100. ! constant in Biggs freezing
  31. REAL, PARAMETER, PRIVATE :: pfrz2 = 0.66 ! constant in Biggs freezing
  32. REAL, PARAMETER, PRIVATE :: qcrmin = 1.e-9 ! minimun values for qr, qs, and qg
  33. REAL, PARAMETER, PRIVATE :: eacrc = 1.0 ! Snow/cloud-water collection efficiency
  34. REAL, SAVE :: &
  35. qc0, qck1,bvtr1,bvtr2,bvtr3,bvtr4,g1pbr, &
  36. g3pbr,g4pbr,g5pbro2,pvtr,eacrr,pacrr, &
  37. precr1,precr2,xmmax,roqimax,bvts1, &
  38. bvts2,bvts3,bvts4,g1pbs,g3pbs,g4pbs, &
  39. g5pbso2,pvts,pacrs,precs1,precs2,pidn0r, &
  40. pidn0s,xlv1,pacrc, &
  41. rslopermax,rslopesmax,rslopegmax, &
  42. rsloperbmax,rslopesbmax,rslopegbmax, &
  43. rsloper2max,rslopes2max,rslopeg2max, &
  44. rsloper3max,rslopes3max,rslopeg3max
  45. !
  46. ! Specifies code-inlining of fpvs function in WSM52D below. JM 20040507
  47. !
  48. CONTAINS
  49. !===================================================================
  50. !
  51. SUBROUTINE wsm5(th, q, qc, qr, qi, qs &
  52. ,den, pii, p, delz &
  53. ,delt,g, cpd, cpv, rd, rv, t0c &
  54. ,ep1, ep2, qmin &
  55. ,XLS, XLV0, XLF0, den0, denr &
  56. ,cliq,cice,psat &
  57. ,rain, rainncv &
  58. ,snow, snowncv &
  59. ,sr &
  60. ,ids,ide, jds,jde, kds,kde &
  61. ,ims,ime, jms,jme, kms,kme &
  62. ,its,ite, jts,jte, kts,kte &
  63. )
  64. #ifdef _OPENMP
  65. use omp_lib
  66. #endif
  67. !-------------------------------------------------------------------
  68. IMPLICIT NONE
  69. !-------------------------------------------------------------------
  70. !
  71. ! This code is a 5-class mixed ice microphyiscs scheme (WSM5) of the WRF
  72. ! Single-Moment MicroPhyiscs (WSMMP). The WSMMP assumes that ice nuclei
  73. ! number concentration is a function of temperature, and seperate assumption
  74. ! is developed, in which ice crystal number concentration is a function
  75. ! of ice amount. A theoretical background of the ice-microphysics and related
  76. ! processes in the WSMMPs are described in Hong et al. (2004).
  77. ! Production terms in the WSM6 scheme are described in Hong and Lim (2006).
  78. ! All units are in m.k.s. and source/sink terms in kgkg-1s-1.
  79. !
  80. ! WSM5 cloud scheme
  81. !
  82. ! Coded by Song-You Hong (Yonsei Univ.)
  83. ! Jimy Dudhia (NCAR) and Shu-Hua Chen (UC Davis)
  84. ! Summer 2002
  85. !
  86. ! Implemented by Song-You Hong (Yonsei Univ.) and Jimy Dudhia (NCAR)
  87. ! Summer 2003
  88. !
  89. ! Reference) Hong, Dudhia, Chen (HDC, 2004) Mon. Wea. Rev.
  90. ! Rutledge, Hobbs (RH83, 1983) J. Atmos. Sci.
  91. ! Hong and Lim (HL, 2006) J. Korean Meteor. Soc.
  92. !
  93. INTEGER, INTENT(IN ) :: ids,ide, jds,jde, kds,kde , &
  94. ims,ime, jms,jme, kms,kme , &
  95. its,ite, jts,jte, kts,kte
  96. REAL, DIMENSION( ims:ime , kms:kme , jms:jme ), &
  97. INTENT(INOUT) :: &
  98. th, &
  99. q, &
  100. qc, &
  101. qi, &
  102. qr, &
  103. qs
  104. REAL, DIMENSION( ims:ime , kms:kme , jms:jme ), &
  105. INTENT(IN ) :: &
  106. den, &
  107. pii, &
  108. p, &
  109. delz
  110. REAL, INTENT(IN ) :: delt, &
  111. g, &
  112. rd, &
  113. rv, &
  114. t0c, &
  115. den0, &
  116. cpd, &
  117. cpv, &
  118. ep1, &
  119. ep2, &
  120. qmin, &
  121. XLS, &
  122. XLV0, &
  123. XLF0, &
  124. cliq, &
  125. cice, &
  126. psat, &
  127. denr
  128. REAL, DIMENSION( ims:ime , jms:jme ), &
  129. INTENT(INOUT) :: rain, &
  130. rainncv, &
  131. sr
  132. REAL, DIMENSION( ims:ime , jms:jme ), OPTIONAL, &
  133. INTENT(INOUT) :: snow, &
  134. snowncv
  135. ! LOCAL VAR
  136. REAL, DIMENSION( its:ite , kts:kte ) :: t
  137. REAL, DIMENSION( its:ite , kts:kte, 2 ) :: qci, qrs
  138. CHARACTER*256 :: emess
  139. INTEGER :: mkx_test
  140. INTEGER :: i,j,k
  141. #ifdef _ACCEL_PROF
  142. INTEGER :: l
  143. real*8 wsm3_t(8,256), wsm5_t(8,256), t1, t2
  144. common /wsm_times/ wsm3_t(8,256), wsm5_t(8,256)
  145. #endif
  146. !-------------------------------------------------------------------
  147. #ifdef _ACCEL_PROF
  148. call cpu_time(t1)
  149. #endif
  150. #ifndef RUN_ON_GPU
  151. #ifdef _ACCEL
  152. ! Need to send th, pii, qc, qi, qr, qs
  153. ! Don't send t
  154. CALL wsm52D(th, pii, q, qc, qr, qi, qs &
  155. ,den &
  156. ,p, delz &
  157. ,delt,g, cpd, cpv, rd, rv, t0c &
  158. ,ep1, ep2, qmin &
  159. ,XLS, XLV0, XLF0, den0, denr &
  160. ,cliq,cice,psat &
  161. ,rain,rainncv &
  162. ,sr &
  163. ,ids,ide, jds,jde, kds,kde &
  164. ,ims,ime, jms,jme, kms,kme &
  165. ,its,ite, jts,jte, kts,kte &
  166. ,snow,snowncv &
  167. )
  168. #else
  169. DO j=jts,jte
  170. DO k=kts,kte
  171. DO i=its,ite
  172. t(i,k)=th(i,k,j)*pii(i,k,j)
  173. qci(i,k,1) = qc(i,k,j)
  174. qci(i,k,2) = qi(i,k,j)
  175. qrs(i,k,1) = qr(i,k,j)
  176. qrs(i,k,2) = qs(i,k,j)
  177. ENDDO
  178. ENDDO
  179. ! Sending array starting locations of optional variables may cause
  180. ! troubles, so we explicitly change the call.
  181. CALL wsm52D(t, q(ims,kms,j), qci, qrs &
  182. ,den(ims,kms,j) &
  183. ,p(ims,kms,j), delz(ims,kms,j) &
  184. ,delt,g, cpd, cpv, rd, rv, t0c &
  185. ,ep1, ep2, qmin &
  186. ,XLS, XLV0, XLF0, den0, denr &
  187. ,cliq,cice,psat &
  188. ,j &
  189. ,rain(ims,j),rainncv(ims,j) &
  190. ,sr(ims,j) &
  191. ,ids,ide, jds,jde, kds,kde &
  192. ,ims,ime, jms,jme, kms,kme &
  193. ,its,ite, jts,jte, kts,kte &
  194. ,snow,snowncv &
  195. )
  196. DO K=kts,kte
  197. DO I=its,ite
  198. th(i,k,j)=t(i,k)/pii(i,k,j)
  199. qc(i,k,j) = qci(i,k,1)
  200. qi(i,k,j) = qci(i,k,2)
  201. qr(i,k,j) = qrs(i,k,1)
  202. qs(i,k,j) = qrs(i,k,2)
  203. ENDDO
  204. ENDDO
  205. ENDDO
  206. #endif
  207. #else
  208. CALL get_wsm5_gpu_levels ( mkx_test )
  209. IF ( mkx_test .LT. kte ) THEN
  210. WRITE(emess,*)'Number of levels compiled for GPU WSM5 too small. ', &
  211. mkx_test,' < ',kte
  212. CALL wrf_error_fatal(emess)
  213. ENDIF
  214. CALL wsm5_host ( &
  215. th(its:ite,kts:kte,jts:jte), pii(its:ite,kts:kte,jts:jte) &
  216. ,q(its:ite,kts:kte,jts:jte), qc(its:ite,kts:kte,jts:jte) &
  217. ,qi(its:ite,kts:kte,jts:jte), qr(its:ite,kts:kte,jts:jte) &
  218. ,qs(its:ite,kts:kte,jts:jte), den(its:ite,kts:kte,jts:jte) &
  219. ,p(its:ite,kts:kte,jts:jte), delz(its:ite,kts:kte,jts:jte) &
  220. ,delt &
  221. ,rain(its:ite,jts:jte),rainncv(its:ite,jts:jte) &
  222. ,snow(its:ite,jts:jte),snowncv(its:ite,jts:jte) &
  223. ,sr(its:ite,jts:jte) &
  224. ,its, ite, jts, jte, kts, kte &
  225. ,its, ite, jts, jte, kts, kte &
  226. ,its, ite, jts, jte, kts, kte &
  227. )
  228. #endif
  229. #ifdef _ACCEL_PROF
  230. call cpu_time(t2)
  231. #ifdef _OPENMP
  232. l = omp_get_thread_num() + 1
  233. #else
  234. l = 1
  235. #endif
  236. wsm5_t(1,l) = wsm5_t(1,l) + (t2 - t1)
  237. #endif
  238. END SUBROUTINE wsm5
  239. #ifdef _ACCEL
  240. !===================================================================
  241. !
  242. SUBROUTINE wsm52D(th, pii, q, qc, qr, qi, qqs, den, p, delz &
  243. ,delt,g, cpd, cpv, rd, rv, t0c &
  244. ,ep1, ep2, qmin &
  245. ,XLS, XLV0, XLF0, den0, denr &
  246. ,cliq,cice,psat &
  247. ,rain,rainncv &
  248. ,sr &
  249. ,ids,ide, jds,jde, kds,kde &
  250. ,ims,ime, jms,jme, kms,kme &
  251. ,its,ite, jts,jte, kts,kte &
  252. ,snow,snowncv &
  253. )
  254. !-------------------------------------------------------------------
  255. IMPLICIT NONE
  256. !-------------------------------------------------------------------
  257. INTEGER, INTENT(IN ) :: ids,ide, jds,jde, kds,kde , &
  258. ims,ime, jms,jme, kms,kme , &
  259. its,ite, jts,jte, kts,kte
  260. REAL, DIMENSION( ims:ime , kms:kme , jms:jme ), &
  261. INTENT(INOUT) :: &
  262. th
  263. REAL, DIMENSION( ims:ime , kms:kme , jms:jme ), &
  264. INTENT(IN) :: &
  265. pii
  266. REAL, DIMENSION( ims:ime , kms:kme, jms:jme ), &
  267. INTENT(INOUT) :: &
  268. qc, &
  269. qr, &
  270. qi, &
  271. qqs
  272. REAL, DIMENSION( ims:ime , kms:kme, jms:jme ), &
  273. INTENT(INOUT) :: &
  274. q
  275. REAL, DIMENSION( ims:ime , kms:kme, jms:jme ), &
  276. INTENT(IN ) :: &
  277. den, &
  278. p, &
  279. delz
  280. REAL, INTENT(IN ) :: delt, &
  281. g, &
  282. cpd, &
  283. cpv, &
  284. t0c, &
  285. den0, &
  286. rd, &
  287. rv, &
  288. ep1, &
  289. ep2, &
  290. qmin, &
  291. XLS, &
  292. XLV0, &
  293. XLF0, &
  294. cliq, &
  295. cice, &
  296. psat, &
  297. denr
  298. REAL, DIMENSION( ims:ime, jms:jme ), &
  299. INTENT(INOUT) :: rain, &
  300. rainncv, &
  301. sr
  302. REAL, DIMENSION( ims:ime, jms:jme ), OPTIONAL, &
  303. INTENT(INOUT) :: snow, &
  304. snowncv
  305. ! LOCAL VAR
  306. REAL, DIMENSION( its:ite , kts:kte , 2) :: &
  307. rh, &
  308. qs, &
  309. rslope, &
  310. rslope2, &
  311. rslope3, &
  312. rslopeb, &
  313. falk, &
  314. fall, &
  315. work1
  316. REAL, DIMENSION( its:ite , kts:kte, jts:jte ) :: &
  317. t
  318. REAL, DIMENSION( its:ite , kts:kte , 2 ) :: &
  319. qci, &
  320. qrs
  321. REAL, DIMENSION( its:ite , kts:kte ) :: &
  322. falkc, &
  323. fallc, &
  324. xl, &
  325. cpm, &
  326. denfac, &
  327. xni, &
  328. n0sfac, &
  329. work2, &
  330. work1c, &
  331. work2c
  332. REAL, DIMENSION( its:ite , kts:kte ) :: &
  333. pigen, &
  334. pidep, &
  335. psdep, &
  336. praut, &
  337. psaut, &
  338. prevp, &
  339. psevp, &
  340. pracw, &
  341. psacw, &
  342. psaci, &
  343. pcond, &
  344. psmlt
  345. INTEGER :: &
  346. mstep, &
  347. numdt
  348. REAL :: rmstep
  349. REAL dtcldden, rdelz, rdtcld
  350. LOGICAL :: flgcld
  351. #define WSM_NO_CONDITIONAL_IN_VECTOR
  352. #ifdef WSM_NO_CONDITIONAL_IN_VECTOR
  353. REAL :: xal, xbl
  354. #endif
  355. REAL :: pi, &
  356. cpmcal, xlcal, lamdar, lamdas, diffus, &
  357. viscos, xka, venfac, conden, diffac, &
  358. x, y, z, a, b, c, d, e, &
  359. qdt, holdrr, holdrs, supcol, supcolt, pvt, &
  360. coeres, supsat, dtcld, xmi, eacrs, satdt, &
  361. vt2i,vt2s,acrfac, &
  362. qimax, diameter, xni0, roqi0, &
  363. fallsum, fallsum_qsi, xlwork2, factor, source, &
  364. value, xlf, pfrzdtc, pfrzdtr, supice, holdc, holdci
  365. ! variables for optimization
  366. REAL, DIMENSION( its:ite ) :: tvec1
  367. REAL :: temp
  368. INTEGER :: i, j, k, &
  369. iprt, latd, lond, loop, loops, ifsat, n
  370. ! Temporaries used for inlining fpvs function
  371. REAL :: dldti, xb, xai, tr, xbi, xa, hvap, cvap, hsub, dldt, ttp
  372. REAL :: logtr
  373. !
  374. !=================================================================
  375. ! compute internal functions
  376. !
  377. cpmcal(x) = cpd*(1.-max(x,qmin))+max(x,qmin)*cpv
  378. xlcal(x) = xlv0-xlv1*(x-t0c)
  379. !----------------------------------------------------------------
  380. ! size distributions: (x=mixing ratio, y=air density):
  381. ! valid for mixing ratio > 1.e-9 kg/kg.
  382. !
  383. ! Optimizatin : A**B => exp(log(A)*(B))
  384. lamdar(x,y)= sqrt(sqrt(pidn0r/(x*y))) ! (pidn0r/(x*y))**.25
  385. lamdas(x,y,z)= sqrt(sqrt(pidn0s*z/(x*y))) ! (pidn0s*z/(x*y))**.25
  386. !
  387. !----------------------------------------------------------------
  388. ! diffus: diffusion coefficient of the water vapor
  389. ! viscos: kinematic viscosity(m2s-1)
  390. ! diffus(x,y) = 8.794e-5 * exp(log(x)*(1.81)) / y ! 8.794e-5*x**1.81/y
  391. ! viscos(x,y) = 1.496e-6 * (x*sqrt(x)) /(x+120.)/y ! 1.496e-6*x**1.5/(x+120.)/y
  392. ! xka(x,y) = 1.414e3*viscos(x,y)*y
  393. ! diffac(a,b,c,d,e) = d*a*a/(xka(c,d)*rv*c*c)+1./(e*diffus(c,b))
  394. ! venfac(a,b,c) = exp(log((viscos(b,c)/diffus(b,a)))*((.3333333))) &
  395. ! /sqrt(viscos(b,c))*sqrt(sqrt(den0/c))
  396. ! conden(a,b,c,d,e) = (max(b,qmin)-c)/(1.+d*d/(rv*e)*c/(a*a))
  397. !
  398. !
  399. pi = 4. * atan(1.)
  400. !
  401. !----------------------------------------------------------------
  402. ! paddint 0 for negative values generated by dynamics
  403. !
  404. !
  405. ! Moved outside of accelerator region
  406. !
  407. loops = max(nint(delt/dtcldcr),1)
  408. dtcld = delt/loops
  409. if(delt.le.dtcldcr) dtcld = delt
  410. !
  411. !....!$acc local(t) &
  412. IF ( PRESENT (snowncv) .AND. PRESENT (snow)) THEN
  413. !$acc region &
  414. !$acc local(t) &
  415. !$acc copyin(delz(:,:,:),p(:,:,:),den(:,:,:),pii(:,:,:)) &
  416. !$acc copyout(snowncv(:,:),rainncv(:,:),sr(:,:)) &
  417. !$acc copy(qqs(:,:,:),qr(:,:,:),qi(:,:,:),qc(:,:,:)) &
  418. !$acc copy(th(:,:,:),q(:,:,:),snow(:,:),rain(:,:))
  419. !$acc do &
  420. !$acc private(rh,qs,rslope,rslope2,rslope3,rslopeb,falk,fall) &
  421. !$acc private(work1,qci,qrs,falkc,fallc,xl,cpm,denfac,xni) &
  422. !$acc private(n0sfac,work2,work1c,work2c,pigen,pidep,psdep) &
  423. !$acc private(praut,psaut,prevp,psevp) &
  424. !$acc private(pracw,psacw,psaci,pcond,psmlt) &
  425. !$acc parallel
  426. do j = jts, jte
  427. !$acc do &
  428. !$acc private(numdt,mstep) &
  429. !$acc kernel vector
  430. do i = its, ite
  431. do k = kts, kte
  432. t(i,k,j)=th(i,k,j)*pii(i,k,j)
  433. qci(i,k,1) = max(qc(i,k,j),0.0)
  434. qci(i,k,2) = max(qi(i,k,j),0.0)
  435. qrs(i,k,1) = max(qr(i,k,j),0.0)
  436. qrs(i,k,2) = max(qqs(i,k,j),0.0)
  437. enddo
  438. !
  439. !----------------------------------------------------------------
  440. ! latent heat for phase changes and heat capacity. neglect the
  441. ! changes during microphysical process calculation
  442. ! emanuel(1994)
  443. !
  444. do k = kts, kte
  445. cpm(i,k) = cpmcal(q(i,k,j))
  446. xl(i,k) = xlcal(t(i,k,j))
  447. enddo
  448. !
  449. !----------------------------------------------------------------
  450. ! compute the minor time steps.
  451. !
  452. ! loops = max(nint(delt/dtcldcr),1)
  453. ! dtcld = delt/loops
  454. ! if(delt.le.dtcldcr) dtcld = delt
  455. !
  456. do loop = 1,loops
  457. !
  458. !----------------------------------------------------------------
  459. ! initialize the large scale variables
  460. !
  461. mstep = 1
  462. flgcld = .true.
  463. !
  464. do k = kts, kte
  465. denfac(i,k) = sqrt(den0/den(i,k,j))
  466. enddo
  467. ! do k = kts, kte
  468. ! CALL VREC( tvec1(its), den(its,k,j), ite-its+1)
  469. ! do i = its, ite
  470. ! tvec1(i) = tvec1(i)*den0
  471. ! enddo
  472. ! CALL VSQRT( denfac(its,k), tvec1(its), ite-its+1)
  473. ! enddo
  474. !
  475. ! Inline expansion for fpvs
  476. ! qs(i,k,1) = fpvs(t(i,k,j),0,rd,rv,cpv,cliq,cice,xlv0,xls,psat,t0c)
  477. ! qs(i,k,2) = fpvs(t(i,k,j),1,rd,rv,cpv,cliq,cice,xlv0,xls,psat,t0c)
  478. hsub = xls
  479. hvap = xlv0
  480. cvap = cpv
  481. ttp=t0c+0.01
  482. dldt=cvap-cliq
  483. xa=-dldt/rv
  484. xb=xa+hvap/(rv*ttp)
  485. dldti=cvap-cice
  486. xai=-dldti/rv
  487. xbi=xai+hsub/(rv*ttp)
  488. ! this is for compilers where the conditional inhibits vectorization
  489. #ifdef WSM_NO_CONDITIONAL_IN_VECTOR
  490. do k = kts, kte
  491. if(t(i,k,j).lt.ttp) then
  492. xal = xai
  493. xbl = xbi
  494. else
  495. xal = xa
  496. xbl = xb
  497. endif
  498. tr=ttp/t(i,k,j)
  499. logtr=log(tr)
  500. qs(i,k,1)=psat*exp(logtr*(xa)+xb*(1.-tr))
  501. qs(i,k,1) = ep2 * qs(i,k,1) / (p(i,k,j) - qs(i,k,1))
  502. qs(i,k,1) = max(qs(i,k,1),qmin)
  503. rh(i,k,1) = max(q(i,k,j) / qs(i,k,1),qmin)
  504. qs(i,k,2)=psat*exp(logtr*(xal)+xbl*(1.-tr))
  505. qs(i,k,2) = ep2 * qs(i,k,2) / (p(i,k,j) - qs(i,k,2))
  506. qs(i,k,2) = max(qs(i,k,2),qmin)
  507. rh(i,k,2) = max(q(i,k,j) / qs(i,k,2),qmin)
  508. enddo
  509. #else
  510. do k = kts, kte
  511. tr=ttp/t(i,k,j)
  512. logtr=log(tr)
  513. qs(i,k,1)=psat*exp(logtr*(xa)+xb*(1.-tr))
  514. qs(i,k,1) = ep2 * qs(i,k,1) / (p(i,k,j) - qs(i,k,1))
  515. qs(i,k,1) = max(qs(i,k,1),qmin)
  516. rh(i,k,1) = max(q(i,k,j) / qs(i,k,1),qmin)
  517. if(t(i,k,j).lt.ttp) then
  518. qs(i,k,2)=psat*exp(logtr*(xai)+xbi*(1.-tr))
  519. else
  520. qs(i,k,2)=psat*exp(logtr*(xa)+xb*(1.-tr))
  521. endif
  522. qs(i,k,2) = ep2 * qs(i,k,2) / (p(i,k,j) - qs(i,k,2))
  523. qs(i,k,2) = max(qs(i,k,2),qmin)
  524. rh(i,k,2) = max(q(i,k,j) / qs(i,k,2),qmin)
  525. enddo
  526. #endif
  527. !
  528. !----------------------------------------------------------------
  529. ! initialize the variables for microphysical physics
  530. !
  531. !
  532. do k = kts, kte
  533. prevp(i,k) = 0.
  534. psdep(i,k) = 0.
  535. praut(i,k) = 0.
  536. psaut(i,k) = 0.
  537. pracw(i,k) = 0.
  538. psaci(i,k) = 0.
  539. psacw(i,k) = 0.
  540. pigen(i,k) = 0.
  541. pidep(i,k) = 0.
  542. pcond(i,k) = 0.
  543. psmlt(i,k) = 0.
  544. psevp(i,k) = 0.
  545. falk(i,k,1) = 0.
  546. falk(i,k,2) = 0.
  547. fall(i,k,1) = 0.
  548. fall(i,k,2) = 0.
  549. fallc(i,k) = 0.
  550. falkc(i,k) = 0.
  551. xni(i,k) = 1.e3
  552. enddo
  553. !
  554. !----------------------------------------------------------------
  555. ! compute the fallout term:
  556. ! first, vertical terminal velosity for minor loops
  557. !
  558. do k = kts, kte
  559. supcol = t0c-t(i,k,j)
  560. !---------------------------------------------------------------
  561. ! n0s: Intercept parameter for snow [m-4] [HDC 6]
  562. !---------------------------------------------------------------
  563. n0sfac(i,k) = max(min(exp(alpha*supcol),n0smax/n0s),1.)
  564. if(qrs(i,k,1).le.qcrmin)then
  565. rslope(i,k,1) = rslopermax
  566. rslopeb(i,k,1) = rsloperbmax
  567. rslope2(i,k,1) = rsloper2max
  568. rslope3(i,k,1) = rsloper3max
  569. else
  570. rslope(i,k,1) = 1./lamdar(qrs(i,k,1),den(i,k,j))
  571. rslopeb(i,k,1) = exp(log(rslope(i,k,1))*(bvtr))
  572. rslope2(i,k,1) = rslope(i,k,1)*rslope(i,k,1)
  573. rslope3(i,k,1) = rslope2(i,k,1)*rslope(i,k,1)
  574. endif
  575. if(qrs(i,k,2).le.qcrmin)then
  576. rslope(i,k,2) = rslopesmax
  577. rslopeb(i,k,2) = rslopesbmax
  578. rslope2(i,k,2) = rslopes2max
  579. rslope3(i,k,2) = rslopes3max
  580. else
  581. rslope(i,k,2) = 1./lamdas(qrs(i,k,2),den(i,k,j),n0sfac(i,k))
  582. rslopeb(i,k,2) = exp(log(rslope(i,k,2))*(bvts))
  583. rslope2(i,k,2) = rslope(i,k,2)*rslope(i,k,2)
  584. rslope3(i,k,2) = rslope2(i,k,2)*rslope(i,k,2)
  585. endif
  586. !-------------------------------------------------------------
  587. ! Ni: ice crystal number concentraiton [HDC 5c]
  588. !-------------------------------------------------------------
  589. ! xni(i,k) = min(max(5.38e7*(den(i,k,j) &
  590. ! *max(qci(i,k,2),qmin))**0.75,1.e3),1.e6)
  591. temp = (den(i,k,j)*max(qci(i,k,2),qmin))
  592. temp = sqrt(sqrt(temp*temp*temp))
  593. xni(i,k) = min(max(5.38e7*temp,1.e3),1.e6)
  594. enddo
  595. !
  596. numdt = 1
  597. do k = kte, kts, -1
  598. work1(i,k,1) = pvtr*rslopeb(i,k,1)*denfac(i,k)/delz(i,k,j)
  599. work1(i,k,2) = pvts*rslopeb(i,k,2)*denfac(i,k)/delz(i,k,j)
  600. numdt = max(nint(max(work1(i,k,1),work1(i,k,2))*dtcld+.5),1)
  601. if(numdt.ge.mstep) mstep = numdt
  602. enddo
  603. rmstep = 1./mstep
  604. !
  605. do n = 1, mstep
  606. k = kte
  607. ! falk(i,k,1) = den(i,k,j)*qrs(i,k,1)*work1(i,k,1)/mstep(i)
  608. ! falk(i,k,2) = den(i,k,j)*qrs(i,k,2)*work1(i,k,2)/mstep(i)
  609. falk(i,k,1) = den(i,k,j)*qrs(i,k,1)*work1(i,k,1)*rmstep
  610. falk(i,k,2) = den(i,k,j)*qrs(i,k,2)*work1(i,k,2)*rmstep
  611. fall(i,k,1) = fall(i,k,1)+falk(i,k,1)
  612. fall(i,k,2) = fall(i,k,2)+falk(i,k,2)
  613. ! qrs(i,k,1) = max(qrs(i,k,1)-falk(i,k,1)*dtcld/den(i,k,j),0.)
  614. ! qrs(i,k,2) = max(qrs(i,k,2)-falk(i,k,2)*dtcld/den(i,k,j),0.)
  615. dtcldden = dtcld/den(i,k,j)
  616. qrs(i,k,1) = max(qrs(i,k,1)-falk(i,k,1)*dtcldden,0.)
  617. qrs(i,k,2) = max(qrs(i,k,2)-falk(i,k,2)*dtcldden,0.)
  618. ! endif
  619. do k = kte-1, kts, -1
  620. falk(i,k,1) = den(i,k,j)*qrs(i,k,1)*work1(i,k,1)*rmstep
  621. falk(i,k,2) = den(i,k,j)*qrs(i,k,2)*work1(i,k,2)*rmstep
  622. fall(i,k,1) = fall(i,k,1)+falk(i,k,1)
  623. fall(i,k,2) = fall(i,k,2)+falk(i,k,2)
  624. dtcldden = dtcld/den(i,k,j)
  625. rdelz = 1./delz(i,k,j)
  626. qrs(i,k,1) = max(qrs(i,k,1)-(falk(i,k,1)-falk(i,k+1,1) &
  627. *delz(i,k+1,j)*rdelz)*dtcldden,0.)
  628. qrs(i,k,2) = max(qrs(i,k,2)-(falk(i,k,2)-falk(i,k+1,2) &
  629. *delz(i,k+1,j)*rdelz)*dtcldden,0.)
  630. enddo
  631. do k = kte, kts, -1
  632. if(t(i,k,j).gt.t0c.and.qrs(i,k,2).gt.0.) then
  633. !----------------------------------------------------------------
  634. ! psmlt: melting of snow [HL A33] [RH83 A25]
  635. ! (T>T0: S->R)
  636. !----------------------------------------------------------------
  637. xlf = xlf0
  638. ! work2(i,k)= venfac(p(i,k),t(i,k,j),den(i,k,j))
  639. work2(i,k)= (exp(log(((1.496e-6*((t(i,k,j))*sqrt(t(i,k,j))) &
  640. /((t(i,k,j))+120.)/(den(i,k,j)))/(8.794e-5 &
  641. *exp(log(t(i,k,j))*(1.81))/p(i,k,j)))) &
  642. *((.3333333)))/sqrt((1.496e-6*((t(i,k,j)) &
  643. *sqrt(t(i,k,j)))/((t(i,k,j))+120.)/(den(i,k,j)))) &
  644. *sqrt(sqrt(den0/(den(i,k,j)))))
  645. coeres = rslope2(i,k,2)*sqrt(rslope(i,k,2)*rslopeb(i,k,2))
  646. ! psmlt(i,k) = xka(t(i,k,j),den(i,k,j))/xlf*(t0c-t(i,k,j))*pi/2. &
  647. ! *n0sfac(i,k)*(precs1*rslope2(i,k,2)+precs2 &
  648. ! *work2(i,k)*coeres)
  649. psmlt(i,k) = (1.414e3*(1.496e-6*((t(i,k,j))*sqrt(t(i,k,j))) &
  650. /((t(i,k,j))+120.)/(den(i,k,j)) )*(den(i,k,j))) &
  651. /xlf*(t0c-t(i,k,j))*pi/2. &
  652. *n0sfac(i,k)*(precs1*rslope2(i,k,2)+precs2 &
  653. *work2(i,k)*coeres)
  654. psmlt(i,k) = min(max(psmlt(i,k)*dtcld/mstep, &
  655. -qrs(i,k,2)/mstep),0.)
  656. qrs(i,k,2) = qrs(i,k,2) + psmlt(i,k)
  657. qrs(i,k,1) = qrs(i,k,1) - psmlt(i,k)
  658. t(i,k,j) = t(i,k,j) + xlf/cpm(i,k)*psmlt(i,k)
  659. endif
  660. enddo
  661. enddo
  662. !---------------------------------------------------------------
  663. ! Vice [ms-1] : fallout of ice crystal [HDC 5a]
  664. !---------------------------------------------------------------
  665. mstep = 1
  666. numdt = 1
  667. do k = kte, kts, -1
  668. if(qci(i,k,2).le.0.) then
  669. work2c(i,k) = 0.
  670. else
  671. xmi = den(i,k,j)*qci(i,k,2)/xni(i,k)
  672. ! diameter = min(dicon * sqrt(xmi),dimax)
  673. diameter = max(min(dicon * sqrt(xmi),dimax), 1.e-25)
  674. work1c(i,k) = 1.49e4*exp(log(diameter)*(1.31))
  675. work2c(i,k) = work1c(i,k)/delz(i,k,j)
  676. endif
  677. numdt = max(nint(work2c(i,k)*dtcld+.5),1)
  678. if(numdt.ge.mstep) mstep = numdt
  679. enddo
  680. !
  681. do n = 1, mstep
  682. k = kte
  683. falkc(i,k) = den(i,k,j)*qci(i,k,2)*work2c(i,k)/mstep
  684. holdc = falkc(i,k)
  685. fallc(i,k) = fallc(i,k)+falkc(i,k)
  686. holdci = qci(i,k,2)
  687. qci(i,k,2) = max(qci(i,k,2)-falkc(i,k)*dtcld/den(i,k,j),0.)
  688. ! endif
  689. do k = kte-1, kts, -1
  690. falkc(i,k) = den(i,k,j)*qci(i,k,2)*work2c(i,k)/mstep
  691. holdc = falkc(i,k)
  692. fallc(i,k) = fallc(i,k)+falkc(i,k)
  693. holdci = qci(i,k,2)
  694. qci(i,k,2) = max(qci(i,k,2)-(falkc(i,k)-falkc(i,k+1) &
  695. *delz(i,k+1,j)/delz(i,k,j))*dtcld/den(i,k,j),0.)
  696. ! endif
  697. enddo
  698. enddo
  699. !
  700. !
  701. !----------------------------------------------------------------
  702. ! rain (unit is mm/sec;kgm-2s-1: /1000*delt ===> m)==> mm for wrf
  703. !
  704. fallsum = fall(i,1,1)+fall(i,1,2)+fallc(i,1)
  705. fallsum_qsi = fall(i,1,2)+fallc(i,1)
  706. rainncv(i,j) = 0.
  707. if(fallsum.gt.0.) then
  708. rainncv(i,j) = fallsum*delz(i,1,j)/denr*dtcld*1000.
  709. rain(i,j) = fallsum*delz(i,1,j)/denr*dtcld*1000. + rain(i,j)
  710. endif
  711. snowncv(i,j) = 0.
  712. if(fallsum_qsi.gt.0.) then
  713. snowncv(i,j) = fallsum_qsi*delz(i,kts,j)/denr*dtcld*1000.
  714. snow(i,j) = fallsum_qsi*delz(i,kts,j)/denr*dtcld*1000. + snow(i,j)
  715. endif
  716. sr(i,j) = 0.
  717. if(fallsum.gt.0.)sr(i,j)=fallsum_qsi*delz(i,kts,j)/denr*dtcld*1000. &
  718. /(rainncv(i,j)+1.e-12)
  719. !
  720. !---------------------------------------------------------------
  721. ! pimlt: instantaneous melting of cloud ice [HL A47] [RH83 A28]
  722. ! (T>T0: I->C)
  723. !---------------------------------------------------------------
  724. do k = kts, kte
  725. supcol = t0c-t(i,k,j)
  726. xlf = xls-xl(i,k)
  727. if(supcol.lt.0.) xlf = xlf0
  728. if(supcol.lt.0.and.qci(i,k,2).gt.0.) then
  729. qci(i,k,1) = qci(i,k,1) + qci(i,k,2)
  730. t(i,k,j) = t(i,k,j) - xlf/cpm(i,k)*qci(i,k,2)
  731. qci(i,k,2) = 0.
  732. endif
  733. !---------------------------------------------------------------
  734. ! pihmf: homogeneous freezing of cloud water below -40c [HL A45]
  735. ! (T<-40C: C->I)
  736. !---------------------------------------------------------------
  737. if(supcol.gt.40..and.qci(i,k,1).gt.0.) then
  738. qci(i,k,2) = qci(i,k,2) + qci(i,k,1)
  739. t(i,k,j) = t(i,k,j) + xlf/cpm(i,k)*qci(i,k,1)
  740. qci(i,k,1) = 0.
  741. endif
  742. !---------------------------------------------------------------
  743. ! pihtf: heterogeneous freezing of cloud water [HL A44]
  744. ! (T0>T>-40C: C->I)
  745. !---------------------------------------------------------------
  746. if(supcol.gt.0..and.qci(i,k,1).gt.0.) then
  747. supcolt=min(supcol,50.)
  748. ! pfrzdtc = min(pfrz1*(exp(pfrz2*supcol)-1.) &
  749. ! *den(i,k,j)/denr/xncr*qci(i,k,1)**2*dtcld,qci(i,k,1))
  750. pfrzdtc = min(pfrz1*(exp(pfrz2*supcolt)-1.) &
  751. *den(i,k,j)/denr/xncr*qci(i,k,1)*qci(i,k,1)*dtcld,qci(i,k,1))
  752. qci(i,k,2) = qci(i,k,2) + pfrzdtc
  753. t(i,k,j) = t(i,k,j) + xlf/cpm(i,k)*pfrzdtc
  754. qci(i,k,1) = qci(i,k,1)-pfrzdtc
  755. endif
  756. !---------------------------------------------------------------
  757. ! psfrz: freezing of rain water [HL A20] [LFO 45]
  758. ! (T<T0, R->S)
  759. !---------------------------------------------------------------
  760. if(supcol.gt.0..and.qrs(i,k,1).gt.0.) then
  761. supcolt=min(supcol,50.)
  762. ! pfrzdtr = min(20.*pi**2*pfrz1*n0r*denr/den(i,k,j) &
  763. ! *(exp(pfrz2*supcol)-1.)*rslope(i,k,1)**7*dtcld, &
  764. ! qrs(i,k,1))
  765. temp = rslope(i,k,1)
  766. temp = temp*temp*temp*temp*temp*temp*temp
  767. pfrzdtr = min(20.*(pi*pi)*pfrz1*n0r*denr/den(i,k,j) &
  768. *(exp(pfrz2*supcolt)-1.)*temp*dtcld, &
  769. qrs(i,k,1))
  770. qrs(i,k,2) = qrs(i,k,2) + pfrzdtr
  771. t(i,k,j) = t(i,k,j) + xlf/cpm(i,k)*pfrzdtr
  772. qrs(i,k,1) = qrs(i,k,1)-pfrzdtr
  773. endif
  774. enddo
  775. !
  776. !----------------------------------------------------------------
  777. ! rsloper: reverse of the slope parameter of the rain(m)
  778. ! xka: thermal conductivity of air(jm-1s-1k-1)
  779. ! work1: the thermodynamic term in the denominator associated with
  780. ! heat conduction and vapor diffusion
  781. ! (ry88, y93, h85)
  782. ! work2: parameter associated with the ventilation effects(y93)
  783. !
  784. do k = kts, kte
  785. if(qrs(i,k,1).le.qcrmin)then
  786. rslope(i,k,1) = rslopermax
  787. rslopeb(i,k,1) = rsloperbmax
  788. rslope2(i,k,1) = rsloper2max
  789. rslope3(i,k,1) = rsloper3max
  790. else
  791. ! rslope(i,k,1) = 1./lamdar(qrs(i,k,1),den(i,k,j))
  792. rslope(i,k,1) = 1./(sqrt(sqrt(pidn0r/((qrs(i,k,1))*(den(i,k,j))))))
  793. rslopeb(i,k,1) = exp(log(rslope(i,k,1))*(bvtr))
  794. rslope2(i,k,1) = rslope(i,k,1)*rslope(i,k,1)
  795. rslope3(i,k,1) = rslope2(i,k,1)*rslope(i,k,1)
  796. endif
  797. if(qrs(i,k,2).le.qcrmin)then
  798. rslope(i,k,2) = rslopesmax
  799. rslopeb(i,k,2) = rslopesbmax
  800. rslope2(i,k,2) = rslopes2max
  801. rslope3(i,k,2) = rslopes3max
  802. else
  803. ! rslope(i,k,2) = 1./lamdas(qrs(i,k,2),den(i,k,j),n0sfac(i,k))
  804. rslope(i,k,2) = 1./(sqrt(sqrt(pidn0s*(n0sfac(i,k))/((qrs(i,k,2)) &
  805. *(den(i,k,j))))))
  806. rslopeb(i,k,2) = exp(log(rslope(i,k,2))*(bvts))
  807. rslope2(i,k,2) = rslope(i,k,2)*rslope(i,k,2)
  808. rslope3(i,k,2) = rslope2(i,k,2)*rslope(i,k,2)
  809. endif
  810. enddo
  811. !
  812. do k = kts, kte
  813. ! work1(i,k,1) = diffac(xl(i,k),p(i,k,j),t(i,k,j),den(i,k,j),qs(i,k,1))
  814. work1(i,k,1) = ((((den(i,k,j))*(xl(i,k))*(xl(i,k)))*((t(i,k,j))+120.) &
  815. *(den(i,k,j)))/(1.414e3*(1.496e-6*((t(i,k,j))*sqrt(t(i,k,j))))&
  816. *(den(i,k,j))*(rv*(t(i,k,j))*(t(i,k,j))))) &
  817. + p(i,k,j)/((qs(i,k,1))*(8.794e-5*exp(log(t(i,k,j))*(1.81))))
  818. ! work1(i,k,2) = diffac(xls,p(i,k,j),t(i,k,j),den(i,k,j),qs(i,k,2))
  819. work1(i,k,2) = ((((den(i,k,j))*(xls)*(xls))*((t(i,k,j))+120.)*(den(i,k,j)))&
  820. /(1.414e3*(1.496e-6*((t(i,k,j))*sqrt(t(i,k,j))))*(den(i,k,j)) &
  821. *(rv*(t(i,k,j))*(t(i,k,j)))) &
  822. + p(i,k,j)/(qs(i,k,2)*(8.794e-5*exp(log(t(i,k,j))*(1.81)))))
  823. ! work2(i,k) = venfac(p(i,k,j),t(i,k,j),den(i,k,j))
  824. work2(i,k) = (exp(.3333333*log(((1.496e-6 * ((t(i,k,j))*sqrt(t(i,k,j)))) &
  825. *p(i,k,j))/(((t(i,k,j))+120.)*den(i,k,j)*(8.794e-5 &
  826. *exp(log(t(i,k,j))*(1.81))))))*sqrt(sqrt(den0/(den(i,k,j))))) &
  827. /sqrt((1.496e-6*((t(i,k,j))*sqrt(t(i,k,j)))) &
  828. /(((t(i,k,j))+120.)*den(i,k,j)))
  829. enddo
  830. !
  831. !===============================================================
  832. !
  833. ! warm rain processes
  834. !
  835. ! - follows the processes in RH83 and LFO except for autoconcersion
  836. !
  837. !===============================================================
  838. !
  839. do k = kts, kte
  840. supsat = max(q(i,k,j),qmin)-qs(i,k,1)
  841. satdt = supsat/dtcld
  842. !---------------------------------------------------------------
  843. ! praut: auto conversion rate from cloud to rain [HDC 16]
  844. ! (C->R)
  845. !---------------------------------------------------------------
  846. if(qci(i,k,1).gt.qc0) then
  847. praut(i,k) = qck1*exp(log(qci(i,k,1))*((7./3.)))
  848. praut(i,k) = min(praut(i,k),qci(i,k,1)/dtcld)
  849. endif
  850. !---------------------------------------------------------------
  851. ! pracw: accretion of cloud water by rain [HL A40] [LFO 51]
  852. ! (C->R)
  853. !---------------------------------------------------------------
  854. if(qrs(i,k,1).gt.qcrmin.and.qci(i,k,1).gt.qmin) then
  855. pracw(i,k) = min(pacrr*rslope3(i,k,1)*rslopeb(i,k,1) &
  856. *qci(i,k,1)*denfac(i,k),qci(i,k,1)/dtcld)
  857. endif
  858. !---------------------------------------------------------------
  859. ! prevp: evaporation/condensation rate of rain [HDC 14]
  860. ! (V->R or R->V)
  861. !---------------------------------------------------------------
  862. if(qrs(i,k,1).gt.0.) then
  863. coeres = rslope2(i,k,1)*sqrt(rslope(i,k,1)*rslopeb(i,k,1))
  864. prevp(i,k) = (rh(i,k,1)-1.)*(precr1*rslope2(i,k,1) &
  865. +precr2*work2(i,k)*coeres)/work1(i,k,1)
  866. if(prevp(i,k).lt.0.) then
  867. prevp(i,k) = max(prevp(i,k),-qrs(i,k,1)/dtcld)
  868. prevp(i,k) = max(prevp(i,k),satdt/2)
  869. else
  870. prevp(i,k) = min(prevp(i,k),satdt/2)
  871. endif
  872. endif
  873. enddo
  874. !
  875. !===============================================================
  876. !
  877. ! cold rain processes
  878. !
  879. ! - follows the revised ice microphysics processes in HDC
  880. ! - the processes same as in RH83 and RH84 and LFO behave
  881. ! following ice crystal hapits defined in HDC, inclduing
  882. ! intercept parameter for snow (n0s), ice crystal number
  883. ! concentration (ni), ice nuclei number concentration
  884. ! (n0i), ice diameter (d)
  885. !
  886. !===============================================================
  887. !
  888. rdtcld = 1./dtcld
  889. do k = kts, kte
  890. supcol = t0c-t(i,k,j)
  891. supsat = max(q(i,k,j),qmin)-qs(i,k,2)
  892. satdt = supsat/dtcld
  893. ifsat = 0
  894. !-------------------------------------------------------------
  895. ! Ni: ice crystal number concentraiton [HDC 5c]
  896. !-------------------------------------------------------------
  897. ! xni(i,k) = min(max(5.38e7*(den(i,k,j) &
  898. ! *max(qci(i,k,2),qmin))**0.75,1.e3),1.e6)
  899. temp = (den(i,k,j)*max(qci(i,k,2),qmin))
  900. temp = sqrt(sqrt(temp*temp*temp))
  901. xni(i,k) = min(max(5.38e7*temp,1.e3),1.e6)
  902. eacrs = exp(0.07*(-supcol))
  903. !
  904. if(supcol.gt.0) then
  905. if(qrs(i,k,2).gt.qcrmin.and.qci(i,k,2).gt.qmin) then
  906. xmi = den(i,k,j)*qci(i,k,2)/xni(i,k)
  907. diameter = min(dicon * sqrt(xmi),dimax)
  908. vt2i = 1.49e4*diameter**1.31
  909. vt2s = pvts*rslopeb(i,k,2)*denfac(i,k)
  910. !-------------------------------------------------------------
  911. ! psaci: Accretion of cloud ice by rain [HDC 10]
  912. ! (T<T0: I->S)
  913. !-------------------------------------------------------------
  914. acrfac = 2.*rslope3(i,k,2)+2.*diameter*rslope2(i,k,2) &
  915. +diameter**2*rslope(i,k,2)
  916. psaci(i,k) = pi*qci(i,k,2)*eacrs*n0s*n0sfac(i,k) &
  917. *abs(vt2s-vt2i)*acrfac/4.
  918. endif
  919. endif
  920. !-------------------------------------------------------------
  921. ! psacw: Accretion of cloud water by snow [HL A7] [LFO 24]
  922. ! (T<T0: C->S, and T>=T0: C->R)
  923. !-------------------------------------------------------------
  924. if(qrs(i,k,2).gt.qcrmin.and.qci(i,k,1).gt.qmin) then
  925. psacw(i,k) = min(pacrc*n0sfac(i,k)*rslope3(i,k,2) &
  926. *rslopeb(i,k,2)*qci(i,k,1)*denfac(i,k) &
  927. ! ,qci(i,k,1)/dtcld)
  928. ,qci(i,k,1)*rdtcld)
  929. endif
  930. if(supcol .gt. 0) then
  931. !-------------------------------------------------------------
  932. ! pidep: Deposition/Sublimation rate of ice [HDC 9]
  933. ! (T<T0: V->I or I->V)
  934. !-------------------------------------------------------------
  935. if(qci(i,k,2).gt.0.and.ifsat.ne.1) then
  936. xmi = den(i,k,j)*qci(i,k,2)/xni(i,k)
  937. diameter = dicon * sqrt(xmi)
  938. pidep(i,k) = 4.*diameter*xni(i,k)*(rh(i,k,2)-1.)/work1(i,k,2)
  939. supice = satdt-prevp(i,k)
  940. if(pidep(i,k).lt.0.) then
  941. ! pidep(i,k) = max(max(pidep(i,k),satdt/2),supice)
  942. ! pidep(i,k) = max(pidep(i,k),-qci(i,k,2)/dtcld)
  943. pidep(i,k) = max(max(pidep(i,k),satdt*.5),supice)
  944. pidep(i,k) = max(pidep(i,k),-qci(i,k,2)*rdtcld)
  945. else
  946. ! pidep(i,k) = min(min(pidep(i,k),satdt/2),supice)
  947. pidep(i,k) = min(min(pidep(i,k),satdt*.5),supice)
  948. endif
  949. if(abs(prevp(i,k)+pidep(i,k)).ge.abs(satdt)) ifsat = 1
  950. endif
  951. !-------------------------------------------------------------
  952. ! psdep: deposition/sublimation rate of snow [HDC 14]
  953. ! (V->S or S->V)
  954. !-------------------------------------------------------------
  955. if(qrs(i,k,2).gt.0..and.ifsat.ne.1) then
  956. coeres = rslope2(i,k,2)*sqrt(rslope(i,k,2)*rslopeb(i,k,2))
  957. psdep(i,k) = (rh(i,k,2)-1.)*n0sfac(i,k) &
  958. *(precs1*rslope2(i,k,2)+precs2 &
  959. *work2(i,k)*coeres)/work1(i,k,2)
  960. supice = satdt-prevp(i,k)-pidep(i,k)
  961. if(psdep(i,k).lt.0.) then
  962. ! psdep(i,k) = max(psdep(i,k),-qrs(i,k,2)/dtcld)
  963. ! psdep(i,k) = max(max(psdep(i,k),satdt/2),supice)
  964. psdep(i,k) = max(psdep(i,k),-qrs(i,k,2)*rdtcld)
  965. psdep(i,k) = max(max(psdep(i,k),satdt*.5),supice)
  966. else
  967. ! psdep(i,k) = min(min(psdep(i,k),satdt/2),supice)
  968. psdep(i,k) = min(min(psdep(i,k),satdt*.5),supice)
  969. endif
  970. if(abs(prevp(i,k)+pidep(i,k)+psdep(i,k)).ge.abs(satdt)) &
  971. ifsat = 1
  972. endif
  973. !-------------------------------------------------------------
  974. ! pigen: generation(nucleation) of ice from vapor [HL A50] [HDC 7-8]
  975. ! (T<T0: V->I)
  976. !-------------------------------------------------------------
  977. if(supsat.gt.0.and.ifsat.ne.1) then
  978. supice = satdt-prevp(i,k)-pidep(i,k)-psdep(i,k)
  979. xni0 = 1.e3*exp(0.1*supcol)
  980. roqi0 = 4.92e-11*exp(log(xni0)*(1.33))
  981. pigen(i,k) = max(0.,(roqi0/den(i,k,j)-max(qci(i,k,2),0.)) &
  982. ! /dtcld)
  983. *rdtcld)
  984. pigen(i,k) = min(min(pigen(i,k),satdt),supice)
  985. endif
  986. !
  987. !-------------------------------------------------------------
  988. ! psaut: conversion(aggregation) of ice to snow [HDC 12]
  989. ! (T<T0: I->S)
  990. !-------------------------------------------------------------
  991. if(qci(i,k,2).gt.0.) then
  992. qimax = roqimax/den(i,k,j)
  993. ! psaut(i,k) = max(0.,(qci(i,k,2)-qimax)/dtcld)
  994. psaut(i,k) = max(0.,(qci(i,k,2)-qimax)*rdtcld)
  995. endif
  996. endif
  997. !-------------------------------------------------------------
  998. ! psevp: Evaporation of melting snow [HL A35] [RH83 A27]
  999. ! (T>T0: S->V)
  1000. !-------------------------------------------------------------
  1001. if(supcol.lt.0.) then
  1002. if(qrs(i,k,2).gt.0..and.rh(i,k,1).lt.1.) &
  1003. psevp(i,k) = psdep(i,k)*work1(i,k,2)/work1(i,k,1)
  1004. ! psevp(i,k) = min(max(psevp(i,k),-qrs(i,k,2)/dtcld),0.)
  1005. psevp(i,k) = min(max(psevp(i,k),-qrs(i,k,2)*rdtcld),0.)
  1006. endif
  1007. enddo
  1008. !
  1009. !
  1010. !----------------------------------------------------------------
  1011. ! check mass conservation of generation terms and feedback to the
  1012. ! large scale
  1013. !
  1014. do k = kts, kte
  1015. if(t(i,k,j).le.t0c) then
  1016. !
  1017. ! cloud water
  1018. !
  1019. value = max(qmin,qci(i,k,1))
  1020. source = (praut(i,k)+pracw(i,k)+psacw(i,k))*dtcld
  1021. if (source.gt.value) then
  1022. factor = value/source
  1023. praut(i,k) = praut(i,k)*factor
  1024. pracw(i,k) = pracw(i,k)*factor
  1025. psacw(i,k) = psacw(i,k)*factor
  1026. endif
  1027. !
  1028. ! cloud ice
  1029. !
  1030. value = max(qmin,qci(i,k,2))
  1031. source = (psaut(i,k)+psaci(i,k)-pigen(i,k)-pidep(i,k))*dtcld
  1032. if (source.gt.value) then
  1033. factor = value/source
  1034. psaut(i,k) = psaut(i,k)*factor
  1035. psaci(i,k) = psaci(i,k)*factor
  1036. pigen(i,k) = pigen(i,k)*factor
  1037. pidep(i,k) = pidep(i,k)*factor
  1038. endif
  1039. !
  1040. ! rain
  1041. !
  1042. !
  1043. value = max(qmin,qrs(i,k,1))
  1044. source = (-praut(i,k)-pracw(i,k)-prevp(i,k))*dtcld
  1045. if (source.g

Large files files are truncated, but you can click here to view the full file