PageRenderTime 56ms CodeModel.GetById 19ms RepoModel.GetById 0ms app.codeStats 1ms

/wrfv2_fire/phys/module_radiation_driver.F

http://github.com/jbeezley/wrf-fire
FORTRAN Legacy | 2514 lines | 1658 code | 313 blank | 543 comment | 69 complexity | 9d966cb238d9a0fd94321cfd8e985733 MD5 | raw file
Possible License(s): AGPL-1.0

Large files files are truncated, but you can click here to view the full file

  1. !WRF:MEDIATION_LAYER:PHYSICS
  2. !
  3. MODULE module_radiation_driver
  4. CONTAINS
  5. !BOP
  6. ! !IROUTINE: radiation_driver - interface to radiation physics options
  7. ! !INTERFACE:
  8. SUBROUTINE radiation_driver ( &
  9. ACFRCV ,ACFRST ,ALBEDO &
  10. ,CFRACH ,CFRACL ,CFRACM &
  11. ,CUPPT ,CZMEAN ,DT &
  12. ,DZ8W ,EMISS ,GLW &
  13. ,GMT ,GSW ,HBOT &
  14. ,HTOP ,HBOTR ,HTOPR &
  15. ,ICLOUD &
  16. ,ITIMESTEP,JULDAY, JULIAN &
  17. ,JULYR ,LW_PHYSICS &
  18. ,NCFRCV ,NCFRST ,NPHS &
  19. ,P8W ,P ,PI &
  20. ,RADT ,RA_CALL_OFFSET &
  21. ,RHO ,RLWTOA &
  22. ,RSWTOA ,RTHRATEN &
  23. ,RTHRATENLW ,RTHRATENSW &
  24. ,SNOW ,STEPRA ,SWDOWN &
  25. ,SWDOWNC ,SW_PHYSICS &
  26. ,T8W ,T ,TAUCLDC &
  27. ,TAUCLDI ,TSK ,VEGFRA &
  28. ,WARM_RAIN ,XICE ,XLAND &
  29. ,XLAT ,XLONG ,YR &
  30. !Optional solar variables
  31. ,DECLINX ,SOLCONX ,COSZEN ,HRANG &
  32. , CEN_LAT &
  33. ,Z &
  34. ,LEVSIZ, N_OZMIXM &
  35. ,N_AEROSOLC &
  36. ,PAERLEV &
  37. ,CAM_ABS_DIM1, CAM_ABS_DIM2 &
  38. ,CAM_ABS_FREQ_S &
  39. ,XTIME &
  40. ,CURR_SECS, ADAPT_STEP_FLAG &
  41. ! indexes
  42. ,IDS,IDE, JDS,JDE, KDS,KDE &
  43. ,IMS,IME, JMS,JME, KMS,KME &
  44. ,i_start,i_end &
  45. ,j_start,j_end &
  46. ,kts, kte &
  47. ,num_tiles &
  48. ! Optional
  49. , TLWDN, TLWUP & ! goddard schemes
  50. , SLWDN, SLWUP & ! goddard schemes
  51. , TSWDN, TSWUP & ! goddard schemes
  52. , SSWDN, SSWUP & ! goddard schemes
  53. , CLDFRA &
  54. , PB &
  55. , F_ICE_PHY,F_RAIN_PHY &
  56. , QV, F_QV &
  57. , QC, F_QC &
  58. , QR, F_QR &
  59. , QI, F_QI &
  60. , QS, F_QS &
  61. , QG, F_QG &
  62. , QNDROP, F_QNDROP &
  63. ,ACSWUPT ,ACSWUPTC &
  64. ,ACSWDNT ,ACSWDNTC &
  65. ,ACSWUPB ,ACSWUPBC &
  66. ,ACSWDNB ,ACSWDNBC &
  67. ,ACLWUPT ,ACLWUPTC &
  68. ,ACLWDNT ,ACLWDNTC &
  69. ,ACLWUPB ,ACLWUPBC &
  70. ,ACLWDNB ,ACLWDNBC &
  71. ,SWUPT ,SWUPTC &
  72. ,SWDNT ,SWDNTC &
  73. ,SWUPB ,SWUPBC &
  74. ,SWDNB ,SWDNBC &
  75. ,LWUPT ,LWUPTC &
  76. ,LWDNT ,LWDNTC &
  77. ,LWUPB ,LWUPBC &
  78. ,LWDNB ,LWDNBC &
  79. ,LWCF &
  80. ,SWCF &
  81. ,OLR &
  82. ,OZMIXM, PIN &
  83. ,M_PS_1, M_PS_2, AEROSOLC_1 &
  84. ,AEROSOLC_2, M_HYBI0 &
  85. ,ABSTOT, ABSNXT, EMSTOT &
  86. ,CU_RAD_FEEDBACK &
  87. ,AER_RA_FEEDBACK &
  88. ,QC_ADJUST , QI_ADJUST &
  89. ,PM2_5_DRY, PM2_5_WATER &
  90. ,PM2_5_DRY_EC &
  91. ,TAUAER300, TAUAER400 & ! jcb
  92. ,TAUAER600, TAUAER999 & ! jcb
  93. ,GAER300, GAER400, GAER600, GAER999 & ! jcb
  94. ,WAER300, WAER400, WAER600, WAER999 & ! jcb
  95. ,TAUAERlw1, TAUAERlw2 &
  96. ,TAUAERlw3, TAUAERlw4 &
  97. ,TAUAERlw5, TAUAERlw6 &
  98. ,TAUAERlw7, TAUAERlw8 &
  99. ,TAUAERlw9, TAUAERlw10 &
  100. ,TAUAERlw11, TAUAERlw12 &
  101. ,TAUAERlw13, TAUAERlw14 &
  102. ,TAUAERlw15, TAUAERlw16 &
  103. ,progn &
  104. ,slope_rad,topo_shading &
  105. ,shadowmask,ht,dx,dy &
  106. ,SWUPFLX,SWUPFLXC,SWDNFLX,SWDNFLXC & ! Optional
  107. ,LWUPFLX,LWUPFLXC,LWDNFLX,LWDNFLXC & ! Optional
  108. ,radtacttime &
  109. ,ALSWVISDIR, ALSWVISDIF, ALSWNIRDIR, ALSWNIRDIF & !fds ssib alb comp (06/2010)
  110. ,SWVISDIR, SWVISDIF, SWNIRDIR, SWNIRDIF & !fds ssib swr comp (06/2010)
  111. ,SF_SURFACE_PHYSICS & !fds
  112. )
  113. !-------------------------------------------------------------------------
  114. ! !USES:
  115. USE module_state_description, ONLY : RRTMSCHEME, GFDLLWSCHEME &
  116. ,RRTMG_LWSCHEME, RRTMG_SWSCHEME &
  117. ,SWRADSCHEME, GSFCSWSCHEME &
  118. ,GFDLSWSCHEME, CAMLWSCHEME, CAMSWSCHEME &
  119. ,HELDSUAREZ &
  120. #ifdef HWRF
  121. ,HWRFSWSCHEME, HWRFLWSCHEME &
  122. #endif
  123. ,goddardlwscheme &
  124. ,goddardswscheme &
  125. ,FLGLWSCHEME, FLGSWSCHEME
  126. USE module_model_constants
  127. #ifndef HWRF
  128. USE module_wrf_error , ONLY : wrf_err_message
  129. #endif
  130. ! *** add new modules of schemes here
  131. USE module_ra_sw , ONLY : swrad
  132. USE module_ra_gsfcsw , ONLY : gsfcswrad
  133. USE module_ra_rrtm , ONLY : rrtmlwrad
  134. USE module_ra_rrtmg_lw , ONLY : rrtmg_lwrad
  135. USE module_ra_rrtmg_sw , ONLY : rrtmg_swrad
  136. USE module_ra_cam , ONLY : camrad
  137. USE module_ra_gfdleta , ONLY : etara
  138. #ifdef HWRF
  139. USE module_ra_hwrf
  140. #endif
  141. USE module_ra_hs , ONLY : hsrad
  142. USE module_ra_goddard , ONLY : goddardrad
  143. USE module_ra_flg , ONLY : RAD_FLG
  144. ! This driver calls subroutines for the radiation parameterizations.
  145. !
  146. ! short wave radiation choices:
  147. ! 1. swrad (19??)
  148. ! 4. rrtmg_sw - Added November 2008, MJIacono, AER, Inc.
  149. !
  150. ! long wave radiation choices:
  151. ! 1. rrtmlwrad
  152. ! 4. rrtmg_lw - Added November 2008, MJIacono, AER, Inc.
  153. !
  154. !----------------------------------------------------------------------
  155. IMPLICIT NONE
  156. !<DESCRIPTION>
  157. !
  158. ! Radiation_driver is the WRF mediation layer routine that provides the interface to
  159. ! to radiation physics packages in the WRF model layer. The radiation
  160. ! physics packages to call are chosen by setting the namelist variable
  161. ! (Rconfig entry in Registry) to the integer value assigned to the
  162. ! particular package (package entry in Registry). For example, if the
  163. ! namelist variable ra_lw_physics is set to 1, this corresponds to the
  164. ! Registry Package entry for swradscheme. Note that the Package
  165. ! names in the Registry are defined constants (frame/module_state_description.F)
  166. ! in the CASE statements in this routine.
  167. !
  168. ! Among the arguments is moist, a four-dimensional scalar array storing
  169. ! a variable number of moisture tracers, depending on the physics
  170. ! configuration for the WRF run, as determined in the namelist. The
  171. ! highest numbered index of active moisture tracers the integer argument
  172. ! n_moist (note: the number of tracers at run time is the quantity
  173. ! <tt>n_moist - PARAM_FIRST_SCALAR + 1</tt> , not n_moist. Individual tracers
  174. ! may be indexed from moist by the Registry name of the tracer prepended
  175. ! with P_; for example P_QC is the index of cloud water. An index
  176. ! represents a valid, active field only if the index is greater than
  177. ! or equal to PARAM_FIRST_SCALAR. PARAM_FIRST_SCALAR and the individual
  178. ! indices for each tracer is defined in module_state_description and
  179. ! set in <a href=set_scalar_indices_from_config.html>set_scalar_indices_from_config</a> defined in frame/module_configure.F.
  180. !
  181. ! Physics drivers in WRF 2.0 and higher, originally model-layer
  182. ! routines, have been promoted to mediation layer routines and they
  183. ! contain OpenMP threaded loops over tiles. Thus, physics drivers
  184. ! are called from single-threaded regions in the solver. The physics
  185. ! routines that are called from the physics drivers are model-layer
  186. ! routines and fully tile-callable and thread-safe.
  187. !</DESCRIPTION>
  188. !
  189. !======================================================================
  190. ! Grid structure in physics part of WRF
  191. !----------------------------------------------------------------------
  192. ! The horizontal velocities used in the physics are unstaggered
  193. ! relative to temperature/moisture variables. All predicted
  194. ! variables are carried at half levels except w, which is at full
  195. ! levels. Some arrays with names (*8w) are at w (full) levels.
  196. !
  197. !----------------------------------------------------------------------
  198. ! In WRF, kms (smallest number) is the bottom level and kme (largest
  199. ! number) is the top level. In your scheme, if 1 is at the top level,
  200. ! then you have to reverse the order in the k direction.
  201. !
  202. ! kme - half level (no data at this level)
  203. ! kme ----- full level
  204. ! kme-1 - half level
  205. ! kme-1 ----- full level
  206. ! .
  207. ! .
  208. ! .
  209. ! kms+2 - half level
  210. ! kms+2 ----- full level
  211. ! kms+1 - half level
  212. ! kms+1 ----- full level
  213. ! kms - half level
  214. ! kms ----- full level
  215. !
  216. !======================================================================
  217. ! Grid structure in physics part of WRF
  218. !
  219. !-------------------------------------
  220. ! The horizontal velocities used in the physics are unstaggered
  221. ! relative to temperature/moisture variables. All predicted
  222. ! variables are carried at half levels except w, which is at full
  223. ! levels. Some arrays with names (*8w) are at w (full) levels.
  224. !
  225. !==================================================================
  226. ! Definitions
  227. !-----------
  228. ! Theta potential temperature (K)
  229. ! Qv water vapor mixing ratio (kg/kg)
  230. ! Qc cloud water mixing ratio (kg/kg)
  231. ! Qr rain water mixing ratio (kg/kg)
  232. ! Qi cloud ice mixing ratio (kg/kg)
  233. ! Qs snow mixing ratio (kg/kg)
  234. !-----------------------------------------------------------------
  235. !-- PM2_5_DRY Dry PM2.5 aerosol mass for all species (ug m^-3)
  236. !-- PM2_5_WATER PM2.5 water mass (ug m^-3)
  237. !-- PM2_5_DRY_EC Dry PM2.5 elemental carbon aersol mass (ug m^-3)
  238. !-- RTHRATEN Theta tendency
  239. ! due to radiation (K/s)
  240. !-- RTHRATENLW Theta tendency
  241. ! due to long wave radiation (K/s)
  242. !-- RTHRATENSW Theta temperature tendency
  243. ! due to short wave radiation (K/s)
  244. !-- dt time step (s)
  245. !-- itimestep number of time steps
  246. !-- GLW downward long wave flux at ground surface (W/m^2)
  247. !-- GSW net short wave flux at ground surface (W/m^2)
  248. !-- SWDOWN downward short wave flux at ground surface (W/m^2)
  249. !-- SWDOWNC clear-sky downward short wave flux at ground surface (W/m^2; optional; for AQ)
  250. !-- RLWTOA upward long wave at top of atmosphere (w/m2)
  251. !-- RSWTOA upward short wave at top of atmosphere (w/m2)
  252. !-- XLAT latitude, south is negative (degree)
  253. !-- XLONG longitude, west is negative (degree)
  254. !-- ALBEDO albedo (between 0 and 1)
  255. !-- CLDFRA cloud fraction (between 0 and 1)
  256. !-- EMISS surface emissivity (between 0 and 1)
  257. !-- rho_phy density (kg/m^3)
  258. !-- rr dry air density (kg/m^3)
  259. !-- moist moisture array (4D - last index is species) (kg/kg)
  260. !-- n_moist number of moisture species
  261. !-- qndrop Cloud droplet number (#/kg)
  262. !-- p8w pressure at full levels (Pa)
  263. !-- p_phy pressure (Pa)
  264. !-- Pb base-state pressure (Pa)
  265. !-- pi_phy exner function (dimensionless)
  266. !-- dz8w dz between full levels (m)
  267. !-- t_phy temperature (K)
  268. !-- t8w temperature at full levels (K)
  269. !-- GMT Greenwich Mean Time Hour of model start (hour)
  270. !-- JULDAY the initial day (Julian day)
  271. !-- RADT time for calling radiation (min)
  272. !-- ra_call_offset -1 (old) means usually just before output, 0 after
  273. !-- DEGRAD conversion factor for
  274. ! degrees to radians (pi/180.) (rad/deg)
  275. !-- DPD degrees per day for earth's
  276. ! orbital position (deg/day)
  277. !-- R_d gas constant for dry air (J/kg/K)
  278. !-- CP heat capacity at constant pressure for dry air (J/kg/K)
  279. !-- G acceleration due to gravity (m/s^2)
  280. !-- rvovrd R_v divided by R_d (dimensionless)
  281. !-- XTIME time since simulation start (min)
  282. !-- DECLIN solar declination angle (rad)
  283. !-- SOLCON solar constant (W/m^2)
  284. !-- ids start index for i in domain
  285. !-- ide end index for i in domain
  286. !-- jds start index for j in domain
  287. !-- jde end index for j in domain
  288. !-- kds start index for k in domain
  289. !-- kde end index for k in domain
  290. !-- ims start index for i in memory
  291. !-- ime end index for i in memory
  292. !-- jms start index for j in memory
  293. !-- jme end index for j in memory
  294. !-- kms start index for k in memory
  295. !-- kme end index for k in memory
  296. !-- i_start start indices for i in tile
  297. !-- i_end end indices for i in tile
  298. !-- j_start start indices for j in tile
  299. !-- j_end end indices for j in tile
  300. !-- kts start index for k in tile
  301. !-- kte end index for k in tile
  302. !-- num_tiles number of tiles
  303. !
  304. !==================================================================
  305. !
  306. INTEGER, INTENT(IN ) :: ids,ide, jds,jde, kds,kde, &
  307. ims,ime, jms,jme, kms,kme, &
  308. kts,kte, &
  309. num_tiles
  310. INTEGER, INTENT(IN) :: lw_physics, sw_physics
  311. INTEGER, DIMENSION(num_tiles), INTENT(IN) :: &
  312. i_start,i_end,j_start,j_end
  313. INTEGER, INTENT(IN ) :: STEPRA,ICLOUD,ra_call_offset
  314. INTEGER, INTENT(IN ) :: levsiz, n_ozmixm
  315. INTEGER, INTENT(IN ) :: paerlev, n_aerosolc, cam_abs_dim1, cam_abs_dim2
  316. REAL, INTENT(IN ) :: cam_abs_freq_s
  317. LOGICAL, INTENT(IN ) :: warm_rain
  318. REAL, INTENT(IN ) :: RADT
  319. REAL, DIMENSION( ims:ime, jms:jme ), &
  320. INTENT(IN ) :: XLAND, &
  321. XICE, &
  322. TSK, &
  323. VEGFRA, &
  324. SNOW
  325. REAL, DIMENSION( ims:ime, levsiz, jms:jme, n_ozmixm ), OPTIONAL, &
  326. INTENT(IN ) :: OZMIXM
  327. REAL, DIMENSION( ims:ime, levsiz, jms:jme, n_ozmixm ) :: OZFLG
  328. REAL, DIMENSION(levsiz), OPTIONAL, INTENT(IN ) :: PIN
  329. REAL, DIMENSION(ims:ime,jms:jme), OPTIONAL, INTENT(IN ) :: m_ps_1,m_ps_2
  330. REAL, DIMENSION( ims:ime, paerlev, jms:jme, n_aerosolc ), OPTIONAL, &
  331. INTENT(IN ) :: aerosolc_1, aerosolc_2
  332. REAL, DIMENSION(paerlev), OPTIONAL, &
  333. INTENT(IN ) :: m_hybi0
  334. REAL, DIMENSION( ims:ime, jms:jme ), &
  335. INTENT(INOUT) :: HTOP, &
  336. HBOT, &
  337. HTOPR, &
  338. HBOTR, &
  339. CUPPT
  340. INTEGER, INTENT(IN ) :: julyr
  341. !
  342. REAL, DIMENSION( ims:ime, kms:kme, jms:jme ), &
  343. INTENT(IN ) :: dz8w, &
  344. z, &
  345. p8w, &
  346. p, &
  347. pi, &
  348. t, &
  349. t8w, &
  350. rho
  351. !
  352. REAL, DIMENSION( ims:ime, kms:kme, jms:jme ), OPTIONAL , &
  353. INTENT(IN ) :: tauaer300,tauaer400,tauaer600,tauaer999, & ! jcb
  354. gaer300,gaer400,gaer600,gaer999, & ! jcb
  355. waer300,waer400,waer600,waer999, & ! jcb
  356. qc_adjust, qi_adjust
  357. REAL, DIMENSION( ims:ime, kms:kme, jms:jme ), OPTIONAL , &
  358. INTENT(IN ) :: tauaerlw1,tauaerlw2,tauaerlw3,tauaerlw4, & ! czhao
  359. tauaerlw5,tauaerlw6,tauaerlw7,tauaerlw8, & ! czhao
  360. tauaerlw9,tauaerlw10,tauaerlw11,tauaerlw12, & ! czhao
  361. tauaerlw13,tauaerlw14,tauaerlw15,tauaerlw16
  362. LOGICAL, INTENT(IN) :: cu_rad_feedback
  363. INTEGER, INTENT(IN ), OPTIONAL :: aer_ra_feedback
  364. !jdfcz INTEGER, OPTIONAL, INTENT(IN ) :: progn,prescribe
  365. INTEGER, OPTIONAL, INTENT(IN ) :: progn
  366. !
  367. ! variables for aerosols (only if running with chemistry)
  368. !
  369. REAL, DIMENSION( ims:ime, kms:kme, jms:jme ), OPTIONAL , &
  370. INTENT(IN ) :: pm2_5_dry, &
  371. pm2_5_water, &
  372. pm2_5_dry_ec
  373. !
  374. REAL, DIMENSION( ims:ime, kms:kme, jms:jme ), &
  375. INTENT(INOUT) :: RTHRATEN, &
  376. RTHRATENLW, &
  377. RTHRATENSW
  378. ! REAL, DIMENSION( ims:ime, kms:kme, jms:jme ), OPTIONAL , &
  379. ! INTENT(INOUT) :: SWUP, &
  380. ! SWDN, &
  381. ! SWUPCLEAR, &
  382. ! SWDNCLEAR, &
  383. ! LWUP, &
  384. ! LWDN, &
  385. ! LWUPCLEAR, &
  386. ! LWDNCLEAR
  387. REAL, DIMENSION( ims:ime, jms:jme ), OPTIONAL, INTENT(INOUT) ::&
  388. ACSWUPT,ACSWUPTC,ACSWDNT,ACSWDNTC, &
  389. ACSWUPB,ACSWUPBC,ACSWDNB,ACSWDNBC, &
  390. ACLWUPT,ACLWUPTC,ACLWDNT,ACLWDNTC, &
  391. ACLWUPB,ACLWUPBC,ACLWDNB,ACLWDNBC
  392. ! TOA and surface, upward and downward, total and clear fluxes
  393. REAL, DIMENSION( ims:ime, jms:jme ), OPTIONAL, INTENT(INOUT) ::&
  394. SWUPT, SWUPTC, SWDNT, SWDNTC, &
  395. SWUPB, SWUPBC, SWDNB, SWDNBC, &
  396. LWUPT, LWUPTC, LWDNT, LWDNTC, &
  397. LWUPB, LWUPBC, LWDNB, LWDNBC
  398. ! Upward and downward, total and clear sky layer fluxes (W m-2)
  399. REAL, DIMENSION( ims:ime, kms:kme+2, jms:jme ), &
  400. OPTIONAL, INTENT(INOUT) :: &
  401. SWUPFLX,SWUPFLXC,SWDNFLX,SWDNFLXC, &
  402. LWUPFLX,LWUPFLXC,LWDNFLX,LWDNFLXC
  403. REAL, DIMENSION( ims:ime, jms:jme ), OPTIONAL , &
  404. INTENT(INOUT) :: SWCF, &
  405. LWCF, &
  406. OLR
  407. ! ---- fds (06/2010) ssib alb components ------------
  408. REAL, DIMENSION( ims:ime, jms:jme ), OPTIONAL , &
  409. INTENT(IN ) :: ALSWVISDIR, &
  410. ALSWVISDIF, &
  411. ALSWNIRDIR, &
  412. ALSWNIRDIF
  413. ! ---- fds (06/2010) ssib swr components ------------
  414. REAL, DIMENSION( ims:ime, jms:jme ), OPTIONAL , &
  415. INTENT(OUT ) :: SWVISDIR, &
  416. SWVISDIF, &
  417. SWNIRDIR, &
  418. SWNIRDIF
  419. INTEGER, OPTIONAL, INTENT(IN ) :: sf_surface_physics
  420. !
  421. REAL, DIMENSION( ims:ime, jms:jme ), &
  422. INTENT(IN ) :: XLAT, &
  423. XLONG, &
  424. ALBEDO, &
  425. EMISS
  426. !
  427. REAL, DIMENSION( ims:ime, jms:jme ), &
  428. INTENT(INOUT) :: GSW, &
  429. GLW
  430. REAL, DIMENSION( ims:ime, jms:jme ), INTENT(OUT) :: SWDOWN
  431. !
  432. REAL, INTENT(IN ) :: GMT,dt, &
  433. julian, xtime
  434. INTEGER, INTENT(IN ),OPTIONAL :: YR
  435. !
  436. INTEGER, INTENT(IN ) :: JULDAY, itimestep
  437. REAL, INTENT(IN ),OPTIONAL :: CURR_SECS
  438. LOGICAL, INTENT(IN ),OPTIONAL :: ADAPT_STEP_FLAG
  439. INTEGER,INTENT(IN) :: NPHS
  440. REAL, DIMENSION( ims:ime, jms:jme ),INTENT(OUT) :: &
  441. CFRACH, & !Added
  442. CFRACL, & !Added
  443. CFRACM, & !Added
  444. CZMEAN !Added
  445. REAL, DIMENSION( ims:ime, jms:jme ), &
  446. INTENT(INOUT) :: &
  447. RLWTOA, & !Added
  448. RSWTOA, & !Added
  449. ACFRST, & !Added
  450. ACFRCV !Added
  451. INTEGER,DIMENSION( ims:ime, jms:jme ),INTENT(INOUT) :: &
  452. NCFRST, & !Added
  453. NCFRCV !Added
  454. ! Optional, only for Goddard LW and SW
  455. REAL, DIMENSION(IMS:IME, JMS:JME, 1:8) :: ERBE_out !extra output for SDSU
  456. REAL, DIMENSION(IMS:IME, JMS:JME), OPTIONAL, INTENT(OUT) :: &
  457. TLWDN, TLWUP, &
  458. SLWDN, SLWUP, &
  459. TSWDN, TSWUP, &
  460. SSWDN, SSWUP ! for Goddard schemes
  461. ! Optional (only used by CAM lw scheme)
  462. REAL, DIMENSION( ims:ime, kms:kme, cam_abs_dim2, jms:jme ), OPTIONAL ,&
  463. INTENT(INOUT) :: abstot
  464. REAL, DIMENSION( ims:ime, kms:kme, cam_abs_dim1, jms:jme ), OPTIONAL ,&
  465. INTENT(INOUT) :: absnxt
  466. REAL, DIMENSION( ims:ime, kms:kme, jms:jme ), OPTIONAL ,&
  467. INTENT(INOUT) :: emstot
  468. !
  469. ! Optional
  470. !
  471. REAL, DIMENSION( ims:ime, kms:kme, jms:jme ), &
  472. OPTIONAL, &
  473. INTENT(INOUT) :: CLDFRA
  474. REAL, DIMENSION( ims:ime, kms:kme, jms:jme ), &
  475. OPTIONAL, &
  476. INTENT(IN ) :: &
  477. F_ICE_PHY, &
  478. F_RAIN_PHY
  479. REAL, DIMENSION( ims:ime, jms:jme ), &
  480. OPTIONAL, &
  481. INTENT(OUT) :: SWDOWNC
  482. !
  483. REAL, DIMENSION( ims:ime, kms:kme, jms:jme ), &
  484. OPTIONAL, &
  485. INTENT(INOUT ) :: &
  486. pb &
  487. ,qv,qc,qr,qi,qs,qg,qndrop
  488. LOGICAL, OPTIONAL :: f_qv,f_qc,f_qr,f_qi,f_qs,f_qg,f_qndrop
  489. !
  490. REAL, DIMENSION( ims:ime, kms:kme, jms:jme ), &
  491. OPTIONAL, &
  492. INTENT(INOUT) :: taucldi,taucldc
  493. ! Variables for slope-dependent radiation
  494. REAL, OPTIONAL, INTENT(IN) :: dx,dy
  495. INTEGER, OPTIONAL, INTENT(IN) :: slope_rad,topo_shading
  496. REAL, DIMENSION( ims:ime, jms:jme ), OPTIONAL, INTENT(IN) :: ht
  497. INTEGER, DIMENSION( ims:ime, jms:jme ), OPTIONAL, INTENT(IN) :: shadowmask
  498. REAL , OPTIONAL, INTENT(INOUT) :: radtacttime ! Storing the time in s when radiation is called next
  499. ! LOCAL VAR
  500. REAL, DIMENSION( ims:ime, jms:jme ) :: GLAT,GLON
  501. REAL, DIMENSION( ims:ime, kms:kme, jms:jme ) :: CEMISS
  502. REAL, DIMENSION( ims:ime, jms:jme ) :: coszr
  503. REAL :: DECLIN,SOLCON,XXLAT,TLOCTM,XT24, CEN_LAT
  504. INTEGER :: i,j,k,its,ite,jts,jte,ij
  505. INTEGER :: STEPABS
  506. LOGICAL :: gfdl_lw,gfdl_sw
  507. LOGICAL :: doabsems
  508. LOGICAL, EXTERNAL :: wrf_dm_on_monitor
  509. REAL :: OBECL,SINOB,SXLONG,ARG,DECDEG, &
  510. DJUL,RJUL,ECCFAC
  511. REAL, DIMENSION( ims:ime, kms:kme, jms:jme ) :: qi_temp,qc_temp
  512. REAL, DIMENSION( ims:ime, kms:kme, jms:jme ) :: qi_save,qc_save
  513. REAL :: next_rad_time
  514. LOGICAL :: run_param , doing_adapt_dt , decided
  515. LOGICAL :: flg_lw, flg_sw
  516. !------------------------------------------------------------------
  517. ! solar related variables are added to declaration
  518. !-------------------------------------------------
  519. REAL, OPTIONAL, INTENT(OUT) :: DECLINX,SOLCONX
  520. REAL, OPTIONAL, DIMENSION( ims:ime, jms:jme), INTENT(OUT) :: COSZEN
  521. REAL, OPTIONAL, DIMENSION( ims:ime, jms:jme), INTENT(OUT) :: HRANG
  522. !------------------------------------------------------------------
  523. #ifdef HWRF
  524. CHARACTER(len=265) :: wrf_err_message
  525. #endif
  526. CALL wrf_debug (1, 'Top of Radiation Driver')
  527. ! WRITE ( wrf_err_message , * ) 'itimestep = ',itimestep,', dt = ',dt,', lw and sw options = ',lw_physics,sw_physics
  528. ! CALL wrf_debug (1, wrf_err_message )
  529. if (lw_physics .eq. 0 .and. sw_physics .eq. 0) return
  530. ! ra_call_offset = -1 gives old method where radiation may be called just before output
  531. ! ra_call_offset = 0 gives new method where radiation may be called just after output
  532. ! and is also consistent with removal of offset in new XTIME
  533. ! also need to account for stepra=1 which always has zero modulo output
  534. doing_adapt_dt = .FALSE.
  535. IF ( PRESENT(adapt_step_flag) ) THEN
  536. IF ( adapt_step_flag ) THEN
  537. doing_adapt_dt = .TRUE.
  538. IF ( radtacttime .eq. 0. ) THEN
  539. radtacttime = CURR_SECS + radt*60.
  540. END IF
  541. END IF
  542. END IF
  543. ! Do we run through this scheme or not?
  544. ! Test 1: If this is the initial model time, then yes.
  545. ! ITIMESTEP=1
  546. ! Test 2: If the user asked for the radiation to be run every time step, then yes.
  547. ! RADT=0 or STEPRA=1
  548. ! Test 3: If not adaptive dt, and this is on the requested radiation frequency, then yes.
  549. ! MOD(ITIMESTEP,STEPRA)=0 (or 1, depending on the offset setting)
  550. ! Test 4: If using adaptive dt and the current time is past the last requested activate radiation time, then yes.
  551. ! CURR_SECS >= RADTACTTIME
  552. ! If we do run through the scheme, we set the flag run_param to TRUE and we set the decided flag
  553. ! to TRUE. The decided flag says that one of these tests was able to say "yes", run the scheme.
  554. ! We only proceed to other tests if the previous tests all have left decided as FALSE.
  555. ! If we set run_param to TRUE and this is adaptive time stepping, we set the time to the next
  556. ! radiation run.
  557. run_param = .FALSE.
  558. decided = .FALSE.
  559. IF ( ( .NOT. decided ) .AND. &
  560. ( itimestep .EQ. 1 ) ) THEN
  561. run_param = .TRUE.
  562. decided = .TRUE.
  563. END IF
  564. IF ( ( .NOT. decided ) .AND. &
  565. ( ( radt .EQ. 0. ) .OR. ( stepra .EQ. 1 ) ) ) THEN
  566. run_param = .TRUE.
  567. decided = .TRUE.
  568. END IF
  569. IF ( ( .NOT. decided ) .AND. &
  570. ( .NOT. doing_adapt_dt ) .AND. &
  571. ( MOD(itimestep,stepra) .EQ. 1+ra_call_offset ) ) THEN
  572. run_param = .TRUE.
  573. decided = .TRUE.
  574. END IF
  575. IF ( ( .NOT. decided ) .AND. &
  576. ( doing_adapt_dt ) .AND. &
  577. ( curr_secs .GE. radtacttime ) ) THEN
  578. run_param = .TRUE.
  579. decided = .TRUE.
  580. radtacttime = curr_secs + radt*60
  581. END IF
  582. Radiation_step: IF ( run_param ) then
  583. ! CAM-specific additional radiation frequency - cam_abs_freq_s (=21600s by default)
  584. STEPABS = nint(cam_abs_freq_s/(dt*STEPRA))*STEPRA
  585. IF (itimestep .eq. 1 .or. mod(itimestep,STEPABS) .eq. 1 + ra_call_offset &
  586. .or. STEPABS .eq. 1 ) THEN
  587. doabsems = .true.
  588. ELSE
  589. doabsems = .false.
  590. ENDIF
  591. IF (PRESENT(adapt_step_flag)) THEN
  592. IF ((adapt_step_flag)) THEN
  593. IF ( (itimestep .EQ. 1) .OR. (cam_abs_freq_s .EQ. 0) .OR. &
  594. ( CURR_SECS + dt >= ( INT( CURR_SECS / ( cam_abs_freq_s ) + 1 ) * cam_abs_freq_s) ) ) THEN
  595. doabsems = .true.
  596. ELSE
  597. doabsems = .false.
  598. ENDIF
  599. ENDIF
  600. ENDIF
  601. gfdl_lw = .false.
  602. gfdl_sw = .false.
  603. ! moved up and out of OMP loop because it only needs to be computed once
  604. ! and because it is not entirely thread-safe (XT24, TOLOCTM and XXLAT need
  605. ! their thread-privacy) JM 20100217
  606. DO ij = 1 , num_tiles
  607. its = i_start(ij)
  608. ite = i_end(ij)
  609. jts = j_start(ij)
  610. jte = j_end(ij)
  611. CALL radconst(XTIME,DECLIN,SOLCON,JULIAN, &
  612. DEGRAD,DPD )
  613. IF(PRESENT(declinx).AND.PRESENT(solconx))THEN
  614. ! saved to state arrays used in surface driver
  615. declinx=declin
  616. solconx=solcon
  617. ENDIF
  618. IF(PRESENT(coszen).AND.PRESENT(hrang))THEN
  619. ! state arrays of hrang and coszen used in surface driver
  620. XT24=MOD(XTIME+RADT*0.5,1440.)
  621. DO j=jts,jte
  622. DO i=its,ite
  623. TLOCTM=GMT+XT24/60.+XLONG(I,J)/15.
  624. HRANG(I,J)=15.*(TLOCTM-12.)*DEGRAD
  625. XXLAT=XLAT(I,J)*DEGRAD
  626. COSZEN(I,J)=SIN(XXLAT)*SIN(DECLIN)+COS(XXLAT)*COS(DECLIN)*COS(HRANG(I,J))
  627. ENDDO
  628. ENDDO
  629. ENDIF
  630. ENDDO
  631. !---------------
  632. !$OMP PARALLEL DO &
  633. !$OMP PRIVATE ( ij ,i,j,k,its,ite,jts,jte)
  634. DO ij = 1 , num_tiles
  635. its = i_start(ij)
  636. ite = i_end(ij)
  637. jts = j_start(ij)
  638. jte = j_end(ij)
  639. ! initialize data
  640. DO j=jts,jte
  641. DO i=its,ite
  642. GSW(I,J)=0.
  643. GLW(I,J)=0.
  644. SWDOWN(I,J)=0.
  645. GLAT(I,J)=XLAT(I,J)*DEGRAD
  646. GLON(I,J)=XLONG(I,J)*DEGRAD
  647. ENDDO
  648. ENDDO
  649. DO j=jts,jte
  650. DO k=kts,kte+1
  651. DO i=its,ite
  652. RTHRATEN(I,K,J)=0.
  653. RTHRATENLW(I,K,J)=0.
  654. RTHRATENSW(I,K,J)=0.
  655. ! SWUP(I,K,J) = 0.0
  656. ! SWDN(I,K,J) = 0.0
  657. ! SWUPCLEAR(I,K,J) = 0.0
  658. ! SWDNCLEAR(I,K,J) = 0.0
  659. ! LWUP(I,K,J) = 0.0
  660. ! LWDN(I,K,J) = 0.0
  661. ! LWUPCLEAR(I,K,J) = 0.0
  662. ! LWDNCLEAR(I,K,J) = 0.0
  663. CEMISS(I,K,J)=0.0
  664. ENDDO
  665. ENDDO
  666. ENDDO
  667. IF ( PRESENT( SWUPFLX ) ) THEN
  668. DO j=jts,jte
  669. DO k=kts,kte+2
  670. DO i=its,ite
  671. SWUPFLX(I,K,J) = 0.0
  672. SWDNFLX(I,K,J) = 0.0
  673. SWUPFLXC(I,K,J) = 0.0
  674. SWDNFLXC(I,K,J) = 0.0
  675. LWUPFLX(I,K,J) = 0.0
  676. LWDNFLX(I,K,J) = 0.0
  677. LWUPFLXC(I,K,J) = 0.0
  678. LWDNFLXC(I,K,J) = 0.0
  679. ENDDO
  680. ENDDO
  681. ENDDO
  682. ENDIF
  683. ! temporarily modify hydrometeors (currently only done for GD scheme and WRF-Chem)
  684. !
  685. IF ( PRESENT( qc ) .AND. PRESENT( qc_adjust ) .AND. cu_rad_feedback ) THEN
  686. DO j=jts,jte
  687. DO k=kts,kte
  688. DO i=its,ite
  689. qc_save(i,k,j) = qc(i,k,j)
  690. qc(i,k,j) = qc(i,k,j) + qc_adjust(i,k,j)
  691. ENDDO
  692. ENDDO
  693. ENDDO
  694. ENDIF
  695. IF ( PRESENT( qi ) .AND. PRESENT( qi_adjust ) .AND. cu_rad_feedback ) THEN
  696. DO j=jts,jte
  697. DO k=kts,kte
  698. DO i=its,ite
  699. qi_save(i,k,j) = qi(i,k,j)
  700. qi(i,k,j) = qi(i,k,j) + qi_adjust(i,k,j)
  701. ENDDO
  702. ENDDO
  703. ENDDO
  704. ENDIF
  705. ! Fill temporary water variable depending on micro package (tgs 25 Apr 2006)
  706. if(PRESENT(qc) .and. PRESENT(F_QC)) then
  707. DO j=jts,jte
  708. DO k=kts,kte
  709. DO i=its,ite
  710. qc_temp(I,K,J)=qc(I,K,J)
  711. ENDDO
  712. ENDDO
  713. ENDDO
  714. else
  715. DO j=jts,jte
  716. DO k=kts,kte
  717. DO i=its,ite
  718. qc_temp(I,K,J)=0.
  719. ENDDO
  720. ENDDO
  721. ENDDO
  722. endif
  723. if(PRESENT(qr) .and. PRESENT(F_QR)) then
  724. DO j=jts,jte
  725. DO k=kts,kte
  726. DO i=its,ite
  727. qc_temp(I,K,J) = qc_temp(I,K,J) + qr(I,K,J)
  728. ENDDO
  729. ENDDO
  730. ENDDO
  731. endif
  732. !---------------
  733. ! Calculate constant for short wave radiation
  734. lwrad_cldfra_select: SELECT CASE(lw_physics)
  735. CASE (GFDLLWSCHEME)
  736. !-- Do nothing, since cloud fractions (with partial cloudiness effects)
  737. !-- are defined in GFDL LW/SW schemes and do not need to be initialized.
  738. CASE (CAMLWSCHEME)
  739. IF ( PRESENT ( CLDFRA ) .AND. &
  740. PRESENT(F_QC) .AND. PRESENT ( F_QI ) ) THEN
  741. ! Call to cloud fraction routine based on Randall 1994 (Hong Pan 1998)
  742. CALL cal_cldfra2(CLDFRA,qv,qc,qi,qs, &
  743. F_QV,F_QC,F_QI,F_QS,t,p, &
  744. F_ICE_PHY,F_RAIN_PHY, &
  745. ids,ide, jds,jde, kds,kde, &
  746. ims,ime, jms,jme, kms,kme, &
  747. its,ite, jts,jte, kts,kte )
  748. ENDIF
  749. CASE (RRTMG_LWSCHEME)
  750. IF ( PRESENT ( CLDFRA ) .AND. &
  751. PRESENT(F_QC) .AND. PRESENT ( F_QI ) ) THEN
  752. ! Call to cloud fraction routine based on Randall 1994 (Hong Pan 1998)
  753. CALL cal_cldfra2(CLDFRA,qv,qc,qi,qs, &
  754. F_QV,F_QC,F_QI,F_QS,t,p, &
  755. F_ICE_PHY,F_RAIN_PHY, &
  756. ids,ide, jds,jde, kds,kde, &
  757. ims,ime, jms,jme, kms,kme, &
  758. its,ite, jts,jte, kts,kte )
  759. ENDIF
  760. CASE DEFAULT
  761. IF ( PRESENT ( CLDFRA ) .AND. &
  762. PRESENT(F_QC) .AND. PRESENT ( F_QI ) ) THEN
  763. CALL cal_cldfra(CLDFRA,qc,qi,F_QC,F_QI, &
  764. ids,ide, jds,jde, kds,kde, &
  765. ims,ime, jms,jme, kms,kme, &
  766. its,ite, jts,jte, kts,kte )
  767. ENDIF
  768. END SELECT lwrad_cldfra_select
  769. lwrad_select: SELECT CASE(lw_physics)
  770. CASE (RRTMSCHEME)
  771. CALL wrf_debug (100, 'CALL rrtm')
  772. CALL RRTMLWRAD( &
  773. RTHRATEN=RTHRATEN,GLW=GLW,OLR=RLWTOA,EMISS=EMISS &
  774. ,QV3D=QV &
  775. ,QC3D=QC &
  776. ,QR3D=QR &
  777. ,QI3D=QI &
  778. ,QS3D=QS &
  779. ,QG3D=QG &
  780. ,P8W=p8w,P3D=p,PI3D=pi,DZ8W=dz8w,TSK=tsk,T3D=t &
  781. ,T8W=t8w,RHO3D=rho, CLDFRA3D=CLDFRA,R=R_d,G=G &
  782. ,F_QV=F_QV,F_QC=F_QC,F_QR=F_QR &
  783. ,F_QI=F_QI,F_QS=F_QS,F_QG=F_QG &
  784. ,ICLOUD=icloud,WARM_RAIN=warm_rain &
  785. ,IDS=ids,IDE=ide, JDS=jds,JDE=jde, KDS=kds,KDE=kde &
  786. ,IMS=ims,IME=ime, JMS=jms,JME=jme, KMS=kms,KME=kme &
  787. ,ITS=its,ITE=ite, JTS=jts,JTE=jte, KTS=kts,KTE=kte &
  788. )
  789. CASE (goddardlwscheme)
  790. CALL wrf_debug (100, 'CALL goddard longwave radiation scheme ')
  791. IF (itimestep.eq.1) then
  792. call wrf_message('running goddard lw radiation')
  793. ENDIF
  794. CALL goddardrad(sw_or_lw='lw' &
  795. ,rthraten=rthraten,gsf=glw,xlat=xlat,xlong=xlong &
  796. ,alb=albedo,t3d=t,p3d=p,p8w3d=p8w,pi3d=pi &
  797. ,dz8w=dz8w,rho_phy=rho,emiss=emiss &
  798. ,cldfra3d=cldfra &
  799. ,gmt=gmt,cp=cp,g=g,t8w=t8w &
  800. ,julday=julday,xtime=xtime &
  801. ,declin=declin,solcon=solcon &
  802. , center_lat = cen_lat &
  803. ,radfrq=radt,degrad=degrad &
  804. ,taucldi=taucldi,taucldc=taucldc &
  805. ,warm_rain=warm_rain &
  806. ,ids=ids,ide=ide, jds=jds,jde=jde, kds=kds,kde=kde &
  807. ,ims=ims,ime=ime, jms=jms,jme=jme, kms=kms,kme=kme &
  808. ,its=its,ite=ite, jts=jts,jte=jte, kts=kts,kte=kte &
  809. ! ,cosz_urb2d=cosz_urb2d ,omg_urb2d=omg_urb2d & !urban
  810. ,qv3d=qv &
  811. ,qc3d=qc &
  812. ,qr3d=qr &
  813. ,qi3d=qi &
  814. ,qs3d=qs &
  815. ,qg3d=qg &
  816. ,f_qv=f_qv,f_qc=f_qc,f_qr=f_qr &
  817. ,f_qi=f_qi,f_qs=f_qs,f_qg=f_qg &
  818. ,erbe_out=erbe_out & !optional
  819. )
  820. CASE (GFDLLWSCHEME)
  821. CALL wrf_debug (100, 'CALL gfdllw')
  822. IF ( PRESENT(F_QV) .AND. PRESENT(F_QC) .AND. &
  823. PRESENT(F_QS) .AND. PRESENT(qs) .AND. &
  824. PRESENT(qv) .AND. PRESENT(qc) ) THEN
  825. IF ( F_QV .AND. F_QC .AND. F_QS) THEN
  826. gfdl_lw = .true.
  827. CALL ETARA( &
  828. DT=dt,XLAND=xland &
  829. ,P8W=p8w,DZ8W=dz8w,RHO_PHY=rho,P_PHY=p,T=t &
  830. ,QV=qv,QW=qc_temp,QI=qi,QS=qs &
  831. ,TSK2D=tsk,GLW=GLW,RSWIN=SWDOWN,GSW=GSW &
  832. ,RSWINC=SWDOWNC,CLDFRA=CLDFRA,PI3D=pi &
  833. ,GLAT=glat,GLON=glon,HTOP=htop,HBOT=hbot &
  834. ,HBOTR=hbotr, HTOPR=htopr &
  835. ,ALBEDO=albedo,CUPPT=cuppt &
  836. ,VEGFRA=vegfra,SNOW=snow,G=g,GMT=gmt &
  837. ,NSTEPRA=stepra,NPHS=nphs,ITIMESTEP=itimestep &
  838. ,XTIME=xtime,JULIAN=julian &
  839. ,JULYR=julyr,JULDAY=julday &
  840. ,GFDL_LW=gfdl_lw,GFDL_SW=gfdl_sw &
  841. ,CFRACL=cfracl,CFRACM=cfracm,CFRACH=cfrach &
  842. ,ACFRST=acfrst,NCFRST=ncfrst &
  843. ,ACFRCV=acfrcv,NCFRCV=ncfrcv &
  844. ,RSWTOA=rswtoa,RLWTOA=rlwtoa,CZMEAN=czmean &
  845. ,THRATEN=rthraten,THRATENLW=rthratenlw &
  846. ,THRATENSW=rthratensw &
  847. ,IDS=ids,IDE=ide, JDS=jds,JDE=jde, KDS=kds,KDE=kde &
  848. ,IMS=ims,IME=ime, JMS=jms,JME=jme, KMS=kms,KME=kme &
  849. ,ITS=its,ITE=ite, JTS=jts,JTE=jte, KTS=kts,KTE=kte &
  850. )
  851. ELSE
  852. CALL wrf_error_fatal('Can not call ETARA (1a). Missing moisture fields.')
  853. ENDIF
  854. ELSE
  855. CALL wrf_error_fatal('Can not call ETARA (1b). Missing moisture fields.')
  856. ENDIF
  857. #ifdef HWRF
  858. CASE (HWRFLWSCHEME)
  859. CALL wrf_debug (100, 'CALL hwrflw')
  860. gfdl_lw = .true.
  861. CALL HWRFRA(DT=dt,thraten=RTHRATEN,thratenlw=RTHRATENLW,thratensw=RTHRATENSW,pi3d=pi, &
  862. XLAND=xland,P8w=p8w,DZ8w=dz8w,RHO_PHY=rho,P_PHY=p,T=t, &
  863. QV=qv,QW=qc_temp,QI=Qi, &
  864. TSK2D=tsk,GLW=GLW,GSW=GSW, &
  865. TOTSWDN=swdown,TOTLWDN=glw,RSWTOA=rswtoa,RLWTOA=rlwtoa,CZMEAN=czmean, & !Added
  866. GLAT=glat,GLON=glon,HTOP=htop,HBOT=hbot,htopr=htopr,hbotr=hbotr,ALBEDO=albedo,CUPPT=cuppt,&
  867. VEGFRA=vegfra,SNOW=snow,G=g,GMT=gmt, & !Modified
  868. NSTEPRA=stepra,NPHS=nphs,itimestep=itimestep, & !Modified
  869. julyr=julyr,julday=julday,gfdl_lw=gfdl_lw,gfdl_sw=gfdl_sw, &
  870. CFRACL=cfracl,CFRACM=cfracm,CFRACH=cfrach, & !Added
  871. ACFRST=acfrst,NCFRST=ncfrst,ACFRCV=acfrcv,NCFRCV=ncfrcv, & !Added
  872. ids=ids,ide=ide, jds=jds,jde=jde, kds=kds,kde=kde, &
  873. ims=ims,ime=ime, jms=jms,jme=jme, kms=kms,kme=kme, &
  874. its=its,ite=ite, jts=jts,jte=jte, kts=kts,kte=kte )
  875. #endif
  876. CASE (CAMLWSCHEME)
  877. CALL wrf_debug(100, 'CALL camrad lw')
  878. IF ( PRESENT( OZMIXM ) .AND. PRESENT( PIN ) .AND. &
  879. PRESENT(M_PS_1) .AND. PRESENT(M_PS_2) .AND. &
  880. PRESENT(M_HYBI0) .AND. PRESENT(AEROSOLC_1) &
  881. .AND. PRESENT(AEROSOLC_2).AND. PRESENT(ALSWVISDIR) ) THEN
  882. CALL CAMRAD(RTHRATENLW=RTHRATEN,RTHRATENSW=RTHRATENSW, &
  883. dolw=.true.,dosw=.false., &
  884. SWUPT=SWUPT,SWUPTC=SWUPTC, &
  885. SWDNT=SWDNT,SWDNTC=SWDNTC, &
  886. LWUPT=LWUPT,LWUPTC=LWUPTC, &
  887. LWDNT=LWDNT,LWDNTC=LWDNTC, &
  888. SWUPB=SWUPB,SWUPBC=SWUPBC, &
  889. SWDNB=SWDNB,SWDNBC=SWDNBC, &
  890. LWUPB=LWUPB,LWUPBC=LWUPBC, &
  891. LWDNB=LWDNB,LWDNBC=LWDNBC, &
  892. SWCF=SWCF,LWCF=LWCF,OLR=RLWTOA,CEMISS=CEMISS, &
  893. TAUCLDC=TAUCLDC,TAUCLDI=TAUCLDI,COSZR=COSZR, &
  894. GSW=GSW,GLW=GLW,XLAT=XLAT,XLONG=XLONG, &
  895. ALBEDO=ALBEDO,t_phy=t,TSK=TSK,EMISS=EMISS &
  896. ,QV3D=qv &
  897. ,QC3D=qc &
  898. ,QR3D=qr &
  899. ,QI3D=qi &
  900. ,QS3D=qs &
  901. ,QG3D=qg &
  902. ,ALSWVISDIR=alswvisdir ,ALSWVISDIF=alswvisdif & !fds ssib alb comp (06/2010)
  903. ,ALSWNIRDIR=alswnirdir ,ALSWNIRDIF=alswnirdif & !fds ssib alb comp (06/2010)
  904. ,SWVISDIR=swvisdir ,SWVISDIF=swvisdif & !fds ssib swr comp (06/2010)
  905. ,SWNIRDIR=swnirdir ,SWNIRDIF=swnirdif & !fds ssib swr comp (06/2010)
  906. ,SF_SURFACE_PHYSICS=sf_surface_physics & !fds
  907. ,F_QV=f_qv,F_QC=f_qc,F_QR=f_qr &
  908. ,F_QI=f_qi,F_QS=f_qs,F_QG=f_qg &
  909. ,f_ice_phy=f_ice_phy,f_rain_phy=f_rain_phy &
  910. ,p_phy=p,p8w=p8w,z=z,pi_phy=pi,rho_phy=rho, &
  911. dz8w=dz8w, &
  912. CLDFRA=CLDFRA,XLAND=XLAND,XICE=XICE,SNOW=SNOW, &
  913. ozmixm=ozmixm,pin0=pin,levsiz=levsiz, &
  914. num_months=n_ozmixm, &
  915. m_psp=m_ps_1,m_psn=m_ps_2,aerosolcp=aerosolc_1, &
  916. aerosolcn=aerosolc_2,m_hybi0=m_hybi0, &
  917. paerlev=paerlev, naer_c=n_aerosolc, &
  918. cam_abs_dim1=cam_abs_dim1, cam_abs_dim2=cam_abs_dim2, &
  919. GMT=GMT,JULDAY=JULDAY,JULIAN=JULIAN,YR=YR,DT=DT,XTIME=XTIME,DECLIN=DECLIN, &
  920. SOLCON=SOLCON,RADT=RADT,DEGRAD=DEGRAD,n_cldadv=3 &
  921. ,abstot_3d=abstot,absnxt_3d=absnxt,emstot_3d=emstot &
  922. ,doabsems=doabsems &
  923. ,IDS=ids,IDE=ide, JDS=jds,JDE=jde, KDS=kds,KDE=kde &
  924. ,IMS=ims,IME=ime, JMS=jms,JME=jme, KMS=kms,KME=kme &
  925. ,ITS=its,ITE=ite, JTS=jts,JTE=jte, KTS=kts,KTE=kte &
  926. )
  927. ELSE
  928. CALL wrf_error_fatal ( 'arguments not present for calling cam radiation' )
  929. ENDIF
  930. CASE (RRTMG_LWSCHEME)
  931. CALL wrf_debug (100, 'CALL rrtmg_lw')
  932. CALL RRTMG_LWRAD( &
  933. RTHRATENLW=RTHRATEN, &
  934. LWUPT=LWUPT,LWUPTC=LWUPTC, &
  935. LWDNT=LWDNT,LWDNTC=LWDNTC, &
  936. LWUPB=LWUPB,LWUPBC=LWUPBC, &
  937. LWDNB=LWDNB,LWDNBC=LWDNBC, &
  938. GLW=GLW,OLR=RLWTOA,LWCF=LWCF, &
  939. EMISS=EMISS, &
  940. P8W=p8w,P3D=p,PI3D=pi,DZ8W=dz8w,TSK=tsk,T3D=t, &
  941. T8W=t8w,RHO3D=rho,R=R_d,G=G, &
  942. ICLOUD=icloud,WARM_RAIN=warm_rain,CLDFRA3D=CLDFRA,&
  943. F_ICE_PHY=F_ICE_PHY,F_RAIN_PHY=F_RAIN_PHY, &
  944. XLAND=XLAND,XICE=XICE,SNOW=SNOW, &
  945. QV3D=QV,QC3D=QC,QR3D=QR, &
  946. QI3D=QI,QS3D=QS,QG3D=QG, &
  947. F_QV=F_QV,F_QC=F_QC,F_QR=F_QR, &
  948. F_QI=F_QI,F_QS=F_QS,F_QG=F_QG, &
  949. #ifdef WRF_CHEM
  950. TAUAERLW1=tauaerlw1,TAUAERLW2=tauaerlw2, & ! jcb
  951. TAUAERLW3=tauaerlw3,TAUAERLW4=tauaerlw4, & ! jcb
  952. TAUAERLW5=tauaerlw5,TAUAERLW6=tauaerlw6, & ! jcb
  953. TAUAERLW7=tauaerlw7,TAUAERLW8=tauaerlw8, & ! jcb
  954. TAUAERLW9=tauaerlw9,TAUAERLW10=tauaerlw10, & ! jcb
  955. TAUAERLW11=tauaerlw11,TAUAERLW12=tauaerlw12, & ! jcb
  956. TAUAERLW13=tauaerlw13,TAUAERLW14=tauaerlw14, & ! jcb
  957. TAUAERLW15=tauaerlw15,TAUAERLW16=tauaerlw16, & ! jcb

Large files files are truncated, but you can click here to view the full file