/wrfv2_fire/phys/module_mp_lin.F
FORTRAN Legacy | 2701 lines | 1365 code | 245 blank | 1091 comment | 91 complexity | 8ed673c9633037adad62d5d18307c8af MD5 | raw file
Possible License(s): AGPL-1.0
Large files files are truncated, but you can click here to view the full file
- !WRF:MODEL_LAYER:PHYSICS
- !
- MODULE module_mp_lin
- USE module_wrf_error
- !
- REAL , PARAMETER, PRIVATE :: RH = 1.0
- ! REAL , PARAMETER, PRIVATE :: episp0 = 0.622*611.21
- REAL , PARAMETER, PRIVATE :: xnor = 8.0e6
- REAL , PARAMETER, PRIVATE :: xnos = 3.0e6
- ! Lin
- ! REAL , PARAMETER, PRIVATE :: xnog = 4.0e4
- ! REAL , PARAMETER, PRIVATE :: rhograul = 917.
- ! Hobbs
- REAL , PARAMETER, PRIVATE :: xnog = 4.0e6
- REAL , PARAMETER, PRIVATE :: rhograul = 400.
- !
- REAL , PARAMETER, PRIVATE :: &
- qi0 = 1.0e-3, ql0 = 7.0e-4, qs0 = 6.0E-4, &
- xmi50 = 4.8e-10, xmi40 = 2.46e-10, &
- constb = 0.8, constd = 0.25, &
- o6 = 1./6., cdrag = 0.6, &
- avisc = 1.49628e-6, adiffwv = 8.7602e-5, &
- axka = 1.4132e3, di50 = 1.0e-4, xmi = 4.19e-13, &
- cw = 4.187e3, vf1s = 0.78, vf2s = 0.31, &
- xni0 = 1.0e-2, xmnin = 1.05e-18, bni = 0.5, &
- ci = 2.093e3
- CONTAINS
- !-------------------------------------------------------------------
- ! Lin et al., 1983, JAM, 1065-1092, and
- ! Rutledge and Hobbs, 1984, JAS, 2949-2972
- ! May 2009 - Changes and corrections from P. Blossey (U. Washington)
- !-------------------------------------------------------------------
- SUBROUTINE lin_et_al(th &
- ,qv, ql, qr &
- ,qi, qs &
- ,rho, pii, p &
- ,dt_in &
- ,z,ht, dz8w &
- ,grav, cp, Rair, rvapor &
- ,XLS, XLV, XLF, rhowater, rhosnow &
- ,EP2,SVP1,SVP2,SVP3,SVPT0 &
- , RAINNC, RAINNCV &
- , SNOWNC, SNOWNCV &
- , GRAUPELNC, GRAUPELNCV, SR &
- ,ids,ide, jds,jde, kds,kde &
- ,ims,ime, jms,jme, kms,kme &
- ,its,ite, jts,jte, kts,kte &
- ! Optional
- ,qlsink, precr, preci, precs, precg &
- , F_QG,F_QNDROP &
- , qg, qndrop &
- )
- !-------------------------------------------------------------------
- IMPLICIT NONE
- !-------------------------------------------------------------------
- !
- ! Shuhua 12/17/99
- !
- INTEGER, INTENT(IN ) :: ids,ide, jds,jde, kds,kde , &
- ims,ime, jms,jme, kms,kme , &
- its,ite, jts,jte, kts,kte
- REAL, DIMENSION( ims:ime , kms:kme , jms:jme ), &
- INTENT(INOUT) :: &
- th, &
- qv, &
- ql, &
- qr
- !
- REAL, DIMENSION( ims:ime , kms:kme , jms:jme ), &
- INTENT(IN ) :: &
- rho, &
- pii, &
- p, &
- dz8w
- REAL, DIMENSION( ims:ime , kms:kme , jms:jme ), &
- INTENT(IN ) :: z
- REAL , DIMENSION( ims:ime , jms:jme ) , INTENT(IN) :: ht
- REAL, INTENT(IN ) :: dt_in, &
- grav, &
- Rair, &
- rvapor, &
- cp, &
- XLS, &
- XLV, &
- XLF, &
- rhowater, &
- rhosnow
- REAL, INTENT(IN ) :: EP2,SVP1,SVP2,SVP3,SVPT0
- REAL, DIMENSION( ims:ime , jms:jme ), &
- INTENT(INOUT) :: RAINNC, &
- RAINNCV, &
- SR
- ! Optional
- REAL, DIMENSION( ims:ime , jms:jme ), &
- OPTIONAL, &
- INTENT(INOUT) :: SNOWNC, &
- SNOWNCV, &
- GRAUPELNC, &
- GRAUPELNCV
- REAL, DIMENSION( ims:ime , kms:kme , jms:jme ), &
- OPTIONAL, &
- INTENT(INOUT) :: &
- qi, &
- qs, &
- qg, &
- qndrop
- REAL, DIMENSION( ims:ime , kms:kme , jms:jme ), &
- OPTIONAL, INTENT(OUT ) :: &
- qlsink, & ! cloud water conversion to rain (/s)
- precr, & ! rain precipitation rate at all levels (kg/m2/s)
- preci, & ! ice precipitation rate at all levels (kg/m2/s)
- precs, & ! snow precipitation rate at all levels (kg/m2/s)
- precg ! graupel precipitation rate at all levels (kg/m2/s)
- LOGICAL, INTENT(IN), OPTIONAL :: F_QG, F_QNDROP
- ! LOCAL VAR
- INTEGER :: min_q, max_q
- REAL, DIMENSION( its:ite , jts:jte ) &
- :: rain, snow, graupel,ice
- REAL, DIMENSION( kts:kte ) :: qvz, qlz, qrz, &
- qiz, qsz, qgz, &
- thz, &
- tothz, rhoz, &
- orhoz, sqrhoz, &
- prez, zz, &
- precrz, preciz, precsz, precgz, &
- qndropz, &
- dzw, preclw
- LOGICAL :: flag_qg, flag_qndrop
- !
- REAL :: dt, pptrain, pptsnow, pptgraul, rhoe_s, &
- gindex, pptice
- real :: qndropconst
- INTEGER :: i,j,k
- !
- flag_qg = .false.
- flag_qndrop = .false.
- IF ( PRESENT ( f_qg ) ) flag_qg = f_qg
- IF ( PRESENT ( f_qndrop ) ) flag_qndrop = f_qndrop
- !
- dt=dt_in
- rhoe_s=1.29
- qndropconst=100.e6 !sg
- gindex=1.0
- IF (.not.flag_qg) gindex=0.
- j_loop: DO j = jts, jte
- i_loop: DO i = its, ite
- !
- !- write data from 3-D to 1-D
- !
- DO k = kts, kte
- qvz(k)=qv(i,k,j)
- qlz(k)=ql(i,k,j)
- qrz(k)=qr(i,k,j)
- thz(k)=th(i,k,j)
- !
- rhoz(k)=rho(i,k,j)
- orhoz(k)=1./rhoz(k)
- prez(k)=p(i,k,j)
- sqrhoz(k)=sqrt(rhoe_s*orhoz(k))
- tothz(k)=pii(i,k,j)
- zz(k)=z(i,k,j)
- dzw(k)=dz8w(i,k,j)
- END DO
- IF (flag_qndrop .AND. PRESENT( qndrop )) THEN
- DO k = kts, kte
- qndropz(k)=qndrop(i,k,j)
- ENDDO
- ELSE
- DO k = kts, kte
- qndropz(k)=qndropconst
- ENDDO
- ENDIF
- DO k = kts, kte
- qiz(k)=qi(i,k,j)
- qsz(k)=qs(i,k,j)
- ENDDO
- IF ( flag_qg .AND. PRESENT( qg ) ) THEN
- DO k = kts, kte
- qgz(k)=qg(i,k,j)
- ENDDO
- ELSE
- DO k = kts, kte
- qgz(k)=0.
- ENDDO
- ENDIF
- !
- pptrain=0.
- pptsnow=0.
- pptgraul=0.
- pptice=0.
- CALL clphy1d( dt, qvz, qlz, qrz, qiz, qsz, qgz, &
- qndropz,flag_qndrop, &
- thz, tothz, rhoz, orhoz, sqrhoz, &
- prez, zz, dzw, ht(I,J), preclw, &
- precrz, preciz, precsz, precgz, &
- pptrain, pptsnow, pptgraul, pptice, &
- grav, cp, Rair, rvapor, gindex, &
- XLS, XLV, XLF, rhowater, rhosnow, &
- EP2,SVP1,SVP2,SVP3,SVPT0, &
- kts, kte, i, j )
- !
- ! Precipitation from cloud microphysics -- only for one time step
- !
- ! unit is transferred from m to mm
- !
- rain(i,j)=pptrain
- snow(i,j)=pptsnow
- graupel(i,j)=pptgraul
- ice(i,j)=pptice
- sr(i,j)=(pptice+pptsnow+pptgraul)/(pptice+pptsnow+pptgraul+pptrain+1.e-12)
- !
- RAINNCV(i,j)= pptrain + pptsnow + pptgraul + pptice
- RAINNC(i,j)=RAINNC(i,j) + pptrain + pptsnow + pptgraul + pptice
- IF(PRESENT(SNOWNCV))SNOWNCV(i,j)= pptsnow + pptice
- IF(PRESENT(SNOWNC))SNOWNC(i,j)=SNOWNC(i,j) + pptsnow + pptice
- IF(PRESENT(GRAUPELNCV))GRAUPELNCV(i,j)= pptgraul
- IF(PRESENT(GRAUPELNC))GRAUPELNC(i,j)=GRAUPELNC(i,j) + pptgraul
- !
- !- update data from 1-D back to 3-D
- !
- !
- IF ( present(qlsink) .and. present(precr) ) THEN !sg beg
- DO k = kts, kte
- if(ql(i,k,j)>1.e-20) then
- qlsink(i,k,j)=-preclw(k)/ql(i,k,j)
- else
- qlsink(i,k,j)=0.
- endif
- precr(i,k,j)=precrz(k)
- END DO
- END IF !sg end
- DO k = kts, kte
- qv(i,k,j)=qvz(k)
- ql(i,k,j)=qlz(k)
- qr(i,k,j)=qrz(k)
- th(i,k,j)=thz(k)
- END DO
- !
- IF ( flag_qndrop .AND. PRESENT( qndrop ) ) THEN !sg beg
- DO k = kts, kte
- qndrop(i,k,j)=qndropz(k)
- ENDDO
- END IF !sg end
- DO k = kts, kte
- qi(i,k,j)=qiz(k)
- qs(i,k,j)=qsz(k)
- ENDDO
- IF ( present(preci) ) THEN !sg beg
- DO k = kts, kte
- preci(i,k,j)=preciz(k)
- ENDDO
- END IF
-
- IF ( present(precs) ) THEN
- DO k = kts, kte
- precs(i,k,j)=precsz(k)
- ENDDO
- END IF !sg end
-
- IF ( flag_qg .AND. PRESENT( qg ) ) THEN
- DO k = kts, kte
- qg(i,k,j)=qgz(k)
- ENDDO
- IF ( present(precg) ) THEN !sg beg
- DO k = kts, kte
- precg(i,k,j)=precgz(k)
- ENDDO !sg end
- END IF
- ELSE !sg beg
- IF ( present(precg) ) precg(i,:,j)=0. !sg end
- ENDIF
- !
- ENDDO i_loop
- ENDDO j_loop
- END SUBROUTINE lin_et_al
- !-----------------------------------------------------------------------
- SUBROUTINE clphy1d(dt, qvz, qlz, qrz, qiz, qsz, qgz, &
- qndropz,flag_qndrop, &
- thz, tothz, rho, orho, sqrho, &
- prez, zz, dzw, zsfc, preclw, &
- precrz, preciz, precsz, precgz, &
- pptrain, pptsnow, pptgraul, &
- pptice, grav, cp, Rair, rvapor, gindex, &
- XLS, XLV, XLF, rhowater, rhosnow, &
- EP2,SVP1,SVP2,SVP3,SVPT0, &
- kts, kte, i, j )
- !-----------------------------------------------------------------------
- IMPLICIT NONE
- !-----------------------------------------------------------------------
- ! This program handles the vertical 1-D cloud micphysics
- !-----------------------------------------------------------------------
- ! avisc: constant in empirical formular for dynamic viscosity of air
- ! =1.49628e-6 [kg/m/s] = 1.49628e-5 [g/cm/s]
- ! adiffwv: constant in empirical formular for diffusivity of water
- ! vapor in air
- ! = 8.7602e-5 [kgm/s3] = 8.7602 [gcm/s3]
- ! axka: constant in empirical formular for thermal conductivity of air
- ! = 1.4132e3 [m2/s2/K] = 1.4132e7 [cm2/s2/K]
- ! qi0: mixing ratio threshold for cloud ice aggregation [kg/kg]
- ! xmi50: mass of a 50 micron ice crystal
- ! = 4.8e-10 [kg] =4.8e-7 [g]
- ! xmi40: mass of a 40 micron ice crystal
- ! = 2.46e-10 [kg] = 2.46e-7 [g]
- ! di50: diameter of a 50 micro (radius) ice crystal
- ! =1.0e-4 [m]
- ! xmi: mass of one cloud ice crystal
- ! =4.19e-13 [kg] = 4.19e-10 [g]
- ! oxmi=1.0/xmi
- !
- ! xni0=1.0e-2 [m-3] The value given in Lin et al. is wrong.(see
- ! Hsie et al.(1980) and Rutledge and Hobbs(1983) )
- ! bni=0.5 [K-1]
- ! xmnin: mass of a natural ice nucleus
- ! = 1.05e-18 [kg] = 1.05e-15 [g] This values is suggested by
- ! Hsie et al. (1980)
- ! = 1.0e-12 [kg] suggested by Rutlegde and Hobbs (1983)
- ! rhowater: density of water=1.0 g/cm3=1000.0 kg/m3
- ! consta: constant in empirical formular for terminal
- ! velocity of raindrop
- ! =2115.0 [cm**(1-b)/s] = 2115.0*0.01**(1-b) [m**(1-b)/s]
- ! constb: constant in empirical formular for terminal
- ! velocity of raindrop
- ! =0.8
- ! xnor: intercept parameter of the raindrop size distribution
- ! = 0.08 cm-4 = 8.0e6 m-4
- ! araut: time sacle for autoconversion of cloud water to raindrops
- ! =1.0e-3 [s-1]
- ! ql0: mixing ratio threshold for cloud watercoalescence [kg/kg]
- ! vf1r: ventilation factors for rain =0.78
- ! vf2r: ventilation factors for rain =0.31
- ! rhosnow: density of snow=0.1 g/cm3=100.0 kg/m3
- ! constc: constant in empirical formular for terminal
- ! velocity of snow
- ! =152.93 [cm**(1-d)/s] = 152.93*0.01**(1-d) [m**(1-d)/s]
- ! constd: constant in empirical formular for terminal
- ! velocity of snow
- ! =0.25
- ! xnos: intercept parameter of the snowflake size distribution
- ! vf1s: ventilation factors for snow =0.78
- ! vf2s: ventilation factors for snow =0.31
- !
- !----------------------------------------------------------------------
- INTEGER, INTENT(IN ) :: kts, kte, i, j
- REAL, DIMENSION( kts:kte ), &
- INTENT(INOUT) :: qvz, qlz, qrz, qiz, qsz, &
- qndropz, &
- qgz, thz
- REAL, DIMENSION( kts:kte ), &
- INTENT(IN ) :: tothz, rho, orho, sqrho, &
- prez, zz, dzw
- REAL, INTENT(IN ) :: dt, grav, cp, Rair, rvapor, &
- XLS, XLV, XLF, rhowater, &
- rhosnow,EP2,SVP1,SVP2,SVP3,SVPT0
- REAL, DIMENSION( kts:kte ), INTENT(OUT) :: preclw, &
- precrz, preciz, precsz, precgz
- REAL, INTENT(INOUT) :: pptrain, pptsnow, pptgraul, pptice
- REAL, INTENT(IN ) :: zsfc
- logical, intent(in) :: flag_qndrop !sg
- ! local vars
- REAL :: obp4, bp3, bp5, bp6, odp4, &
- dp3, dp5, dp5o2
- ! temperary vars
- REAL :: tmp, tmp0, tmp1, tmp2,tmp3, &
- tmp4,delta2,delta3, delta4, &
- tmpa,tmpb,tmpc,tmpd,alpha1, &
- qic, abi,abr, abg, odtberg, &
- vti50,eiw,eri,esi,esr, esw, &
- erw,delrs,term0,term1,araut, &
- constg2, vf1r, vf2r,alpha2, &
- Ap, Bp, egw, egi, egs, egr, &
- constg, gdelta4, g1sdelt4, &
- factor, tmp_r, tmp_s,tmp_g, &
- qlpqi, rsat, a1, a2, xnin
- INTEGER :: k
- !
- REAL, DIMENSION( kts:kte ) :: oprez, tem, temcc, theiz, qswz, &
- qsiz, qvoqswz, qvoqsiz, qvzodt, &
- qlzodt, qizodt, qszodt, qrzodt, &
- qgzodt
- REAL, DIMENSION( kts:kte ) :: psnow, psaut, psfw, psfi, praci, &
- piacr, psaci, psacw, psdep, pssub, &
- pracs, psacr, psmlt, psmltevp, &
- prain, praut, pracw, prevp, pvapor, &
- pclw, pladj, pcli, pimlt, pihom, &
- pidw, piadj, pgraupel, pgaut, &
- pgfr, pgacw, pgaci, pgacr, pgacs, &
- pgacip,pgacrp,pgacsp,pgwet, pdry, &
- pgsub, pgdep, pgmlt, pgmltevp, &
- qschg, qgchg
- !
- REAL, DIMENSION( kts:kte ) :: qvsbar, rs0, viscmu, visc, diffwv, &
- schmidt, xka
- REAL, DIMENSION( kts:kte ) :: vtr, vts, vtg, &
- vtrold, vtsold, vtgold, vtiold, &
- xlambdar, xlambdas, xlambdag, &
- olambdar, olambdas, olambdag
- REAL :: episp0k, dtb, odtb, pi, pio4, &
- pio6, oxLf, xLvocp, xLfocp, consta, &
- constc, ocdrag, gambp4, gamdp4, &
- gam4pt5, Cpor, oxmi, gambp3, gamdp3,&
- gambp6, gam3pt5, gam2pt75, gambp5o2,&
- gamdp5o2, cwoxlf, ocp, xni50, es
- !
- REAL :: qvmin=1.e-20
- REAL :: gindex
- REAL :: temc1,save1,save2,xni50mx
- ! for terminal velocity flux
- INTEGER :: min_q, max_q
- REAL :: t_del_tv, del_tv, flux, fluxin, fluxout ,tmpqrz
- LOGICAL :: notlast
- !
- REAL :: tmp_tem, tmp_temcc !bloss
- !
- real :: liqconc, dis, beta, kappa, p0, xc, capn,rhocgs
- !sg: begin
- ! liqconc = liquid water content (g cm^-3)
- ! capn = droplet number concentration (# cm^-3)
- ! dis = relative dispersion (dimensionless) between 0.2 and 1.
- ! Written by Yangang Liu based on Liu et al., GRL 32, 2005.
- ! Autoconversion rate p = p0 * (threshold function)
- ! p0 = "base" autoconversion rate (g cm^-3 s^-1)
- ! kappa = constant in Long kernel = [kappa2 * (3/(4*pi*rhow))^3] in Liu papers
- ! beta = Condensation rate constant = (beta6)^6 in Liu papers
- ! xc = Normalized critical mass
- ! ***********************************************************
- if(flag_qndrop)then
- dis = 0.5 ! droplet dispersion, set to 0.5 per SG 8-Nov-2006
- ! Give empirical constants
- kappa=1.1d10
- ! Calculate Condensation rate constant
- beta = (1.0d0+3.0d0*dis**2)*(1.0d0+4.0d0*dis**2)* &
- (1.0d0+5.0d0*dis**2)/((1.0d0+dis**2)*(1.0d0+2.0d0*dis**2))
- endif
- !sg: end
- dtb=dt
- odtb=1./dtb
- pi=acos(-1.)
- pio4=acos(-1.)/4.
- pio6=acos(-1.)/6.
- ocp=1./cp
- oxLf=1./xLf
- xLvocp=xLv/cp
- xLfocp=xLf/cp
- consta=2115.0*0.01**(1-constb)
- constc=152.93*0.01**(1-constd)
- ocdrag=1./Cdrag
- ! episp0k=RH*episp0
- episp0k=RH*ep2*1000.*svp1
- !
- gambp4=ggamma(constb+4.)
- gamdp4=ggamma(constd+4.)
- gam4pt5=ggamma(4.5)
- Cpor=cp/Rair
- oxmi=1.0/xmi
- gambp3=ggamma(constb+3.)
- gamdp3=ggamma(constd+3.)
- gambp6=ggamma(constb+6)
- gam3pt5=ggamma(3.5)
- gam2pt75=ggamma(2.75)
- gambp5o2=ggamma((constb+5.)/2.)
- gamdp5o2=ggamma((constd+5.)/2.)
- cwoxlf=cw/xlf
- delta2=0.
- delta3=0.
- delta4=0.
- !
- !-----------------------------------------------------------------------
- ! oprez 1./prez ( prez : pressure)
- ! qsw saturated mixing ratio on water surface
- ! qsi saturated mixing ratio on ice surface
- ! episp0k RH*e*saturated pressure at 273.15 K
- ! qvoqsw qv/qsw
- ! qvoqsi qv/qsi
- ! qvzodt qv/dt
- ! qlzodt ql/dt
- ! qizodt qi/dt
- ! qszodt qs/dt
- ! qrzodt qr/dt
- ! qgzodt qg/dt
- !
- ! temcc temperature in dregee C
- !
- obp4=1.0/(constb+4.0)
- bp3=constb+3.0
- bp5=constb+5.0
- bp6=constb+6.0
- odp4=1.0/(constd+4.0)
- dp3=constd+3.0
- dp5=constd+5.0
- dp5o2=0.5*(constd+5.0)
- !
- do k=kts,kte
- oprez(k)=1./prez(k)
- enddo
- do k=kts,kte
- qlz(k)=amax1( 0.0,qlz(k) )
- qiz(k)=amax1( 0.0,qiz(k) )
- qvz(k)=amax1( qvmin,qvz(k) )
- qsz(k)=amax1( 0.0,qsz(k) )
- qrz(k)=amax1( 0.0,qrz(k) )
- qgz(k)=amax1( 0.0,qgz(k) )
- qndropz(k)=amax1( 0.0,qndropz(k) ) !sg
- !
- tem(k)=thz(k)*tothz(k)
- temcc(k)=tem(k)-273.15
- !
- ! qswz(k)=episp0k*oprez(k)* &
- ! exp( svp2*temcc(k)/(tem(k)-svp3) )
- es=1000.*svp1*exp( svp2*temcc(k)/(tem(k)-svp3) )
- qswz(k)=ep2*es/(prez(k)-es)
- if (tem(k) .lt. 273.15 ) then
- ! qsiz(k)=episp0k*oprez(k)* &
- ! exp( 21.8745584*(tem(k)-273.16)/(tem(k)-7.66) )
- es=1000.*svp1*exp( 21.8745584*(tem(k)-273.16)/(tem(k)-7.66) )
- qsiz(k)=ep2*es/(prez(k)-es)
- if (temcc(k) .lt. -40.0) qswz(k)=qsiz(k)
- else
- qsiz(k)=qswz(k)
- endif
- !
- qvoqswz(k)=qvz(k)/qswz(k)
- qvoqsiz(k)=qvz(k)/qsiz(k)
- theiz(k)=thz(k)+(xlvocp*qvz(k)-xlfocp*qiz(k))/tothz(k)
- enddo
- !
- !
- !-----------------------------------------------------------------------
- ! In this simple stable cloud parameterization scheme, only five
- ! forms of water substance (water vapor, cloud water, cloud ice,
- ! rain and snow are considered. The prognostic variables are total
- ! water (qp),cloud water (ql), and cloud ice (qi). Rain and snow are
- ! diagnosed following Nagata and Ogura, 1991, MWR, 1309-1337. Eq (A7).
- ! the micro physics are based on (1) Hsie et al.,1980, JAM, 950-977 ;
- ! (2) Lin et al., 1983, JAM, 1065-1092 ; (3) Rutledge and Hobbs, 1983,
- ! JAS, 1185-1206 ; (4) Rutledge and Hobbs, 1984, JAS, 2949-2972.
- !-----------------------------------------------------------------------
- !
- ! rhowater: density of water=1.0 g/cm3=1000.0 kg/m3
- ! rhosnow: density of snow=0.1 g/cm3=100.0 kg/m3
- ! xnor: intercept parameter of the raindrop size distribution
- ! = 0.08 cm-4 = 8.0e6 m-4
- ! xnos: intercept parameter of the snowflake size distribution
- ! = 0.03 cm-4 = 3.0e6 m-4
- ! xnog: intercept parameter of the graupel size distribution
- ! = 4.0e-4 cm-4 = 4.0e4 m-4
- ! consta: constant in empirical formular for terminal
- ! velocity of raindrop
- ! =2115.0 [cm**(1-b)/s] = 2115.0*0.01**(1-b) [m**(1-b)/s]
- ! constb: constant in empirical formular for terminal
- ! velocity of raindrop
- ! =0.8
- ! constc: constant in empirical formular for terminal
- ! velocity of snow
- ! =152.93 [cm**(1-d)/s] = 152.93*0.01**(1-d) [m**(1-d)/s]
- ! constd: constant in empirical formular for terminal
- ! velocity of snow
- ! =0.25
- ! avisc: constant in empirical formular for dynamic viscosity of air
- ! =1.49628e-6 [kg/m/s] = 1.49628e-5 [g/cm/s]
- ! adiffwv: constant in empirical formular for diffusivity of water
- ! vapor in air
- ! = 8.7602e-5 [kgm/s3] = 8.7602 [gcm/s3]
- ! axka: constant in empirical formular for thermal conductivity of air
- ! = 1.4132e3 [m2/s2/K] = 1.4132e7 [cm2/s2/K]
- ! qi0: mixing ratio threshold for cloud ice aggregation [kg/kg]
- ! = 1.0e-3 g/g = 1.0e-3 kg/gk
- ! ql0: mixing ratio threshold for cloud watercoalescence [kg/kg]
- ! = 2.0e-3 g/g = 2.0e-3 kg/gk
- ! qs0: mixing ratio threshold for snow aggregation
- ! = 6.0e-4 g/g = 6.0e-4 kg/gk
- ! xmi50: mass of a 50 micron ice crystal
- ! = 4.8e-10 [kg] =4.8e-7 [g]
- ! xmi40: mass of a 40 micron ice crystal
- ! = 2.46e-10 [kg] = 2.46e-7 [g]
- ! di50: diameter of a 50 micro (radius) ice crystal
- ! =1.0e-4 [m]
- ! xmi: mass of one cloud ice crystal
- ! =4.19e-13 [kg] = 4.19e-10 [g]
- ! oxmi=1.0/xmi
- !
- ! if gindex=1.0 include graupel
- ! if gindex=0. no graupel
- !
- !
- do k=kts,kte
- psnow(k)=0.0
- psaut(k)=0.0
- psfw(k)=0.0
- psfi(k)=0.0
- praci(k)=0.0
- piacr(k)=0.0
- psaci(k)=0.0
- psacw(k)=0.0
- psdep(k)=0.0
- pssub(k)=0.0
- pracs(k)=0.0
- psacr(k)=0.0
- psmlt(k)=0.0
- psmltevp(k)=0.0
- !
- prain(k)=0.0
- praut(k)=0.0
- pracw(k)=0.0
- prevp(k)=0.0
- !
- pvapor(k)=0.0
- !
- pclw(k)=0.0
- preclw(k)=0.0 !sg
- pladj(k)=0.0
- !
- pcli(k)=0.0
- pimlt(k)=0.0
- pihom(k)=0.0
- pidw(k)=0.0
- piadj(k)=0.0
- enddo
- !
- !!! graupel
- !
- do k=kts,kte
- pgraupel(k)=0.0
- pgaut(k)=0.0
- pgfr(k)=0.0
- pgacw(k)=0.0
- pgaci(k)=0.0
- pgacr(k)=0.0
- pgacs(k)=0.0
- pgacip(k)=0.0
- pgacrP(k)=0.0
- pgacsp(k)=0.0
- pgwet(k)=0.0
- pdry(k)=0.0
- pgsub(k)=0.0
- pgdep(k)=0.0
- pgmlt(k)=0.0
- pgmltevp(k)=0.0
- qschg(k)=0.
- qgchg(k)=0.
- enddo
- !
- !
- ! Set rs0=episp0*oprez(k)
- ! episp0=e*saturated pressure at 273.15 K
- ! e = 0.622
- !
- DO k=kts,kte
- rs0(k)=ep2*1000.*svp1/(prez(k)-1000.*svp1)
- END DO
- !
- !***********************************************************************
- ! Calculate precipitation fluxes due to terminal velocities.
- !***********************************************************************
- !
- !- Calculate termianl velocity (vt?) of precipitation q?z
- !- Find maximum vt? to determine the small delta t
- !
- !-- rain
- !
- t_del_tv=0.
- del_tv=dtb
- notlast=.true.
- DO while (notlast)
- !
- min_q=kte
- max_q=kts-1
- !
- do k=kts,kte-1
- if (qrz(k) .gt. 1.0e-8) then
- min_q=min0(min_q,k)
- max_q=max0(max_q,k)
- tmp1=sqrt(pi*rhowater*xnor/rho(k)/qrz(k))
- tmp1=sqrt(tmp1)
- vtrold(k)=o6*consta*gambp4*sqrho(k)/tmp1**constb
- if (k .eq. 1) then
- del_tv=amin1(del_tv,0.9*(zz(k)-zsfc)/vtrold(k))
- else
- del_tv=amin1(del_tv,0.9*(zz(k)-zz(k-1))/vtrold(k))
- endif
- else
- vtrold(k)=0.
- endif
- enddo
- if (max_q .ge. min_q) then
- !
- !- Check if the summation of the small delta t >= big delta t
- ! (t_del_tv) (del_tv) (dtb)
- t_del_tv=t_del_tv+del_tv
- !
- if ( t_del_tv .ge. dtb ) then
- notlast=.false.
- del_tv=dtb+del_tv-t_del_tv
- endif
- !
- fluxin=0.
- do k=max_q,min_q,-1
- fluxout=rho(k)*vtrold(k)*qrz(k)
- flux=(fluxin-fluxout)/rho(k)/dzw(k)
- tmpqrz=qrz(k)
- qrz(k)=qrz(k)+del_tv*flux
- fluxin=fluxout
- enddo
- if (min_q .eq. 1) then
- pptrain=pptrain+fluxin*del_tv
- else
- qrz(min_q-1)=qrz(min_q-1)+del_tv* &
- fluxin/rho(min_q-1)/dzw(min_q-1)
- endif
- !
- else
- notlast=.false.
- endif
- ENDDO
- !
- !-- snow
- !
- t_del_tv=0.
- del_tv=dtb
- notlast=.true.
- DO while (notlast)
- !
- min_q=kte
- max_q=kts-1
- !
- do k=kts,kte-1
- if (qsz(k) .gt. 1.0e-8) then
- min_q=min0(min_q,k)
- max_q=max0(max_q,k)
- tmp1=sqrt(pi*rhosnow*xnos/rho(k)/qsz(k))
- tmp1=sqrt(tmp1)
- vtsold(k)=o6*constc*gamdp4*sqrho(k)/tmp1**constd
- if (k .eq. 1) then
- del_tv=amin1(del_tv,0.9*(zz(k)-zsfc)/vtsold(k))
- else
- del_tv=amin1(del_tv,0.9*(zz(k)-zz(k-1))/vtsold(k))
- endif
- else
- vtsold(k)=0.
- endif
- enddo
- if (max_q .ge. min_q) then
- !
- !
- !- Check if the summation of the small delta t >= big delta t
- ! (t_del_tv) (del_tv) (dtb)
- t_del_tv=t_del_tv+del_tv
- if ( t_del_tv .ge. dtb ) then
- notlast=.false.
- del_tv=dtb+del_tv-t_del_tv
- endif
- !
- fluxin=0.
- do k=max_q,min_q,-1
- fluxout=rho(k)*vtsold(k)*qsz(k)
- flux=(fluxin-fluxout)/rho(k)/dzw(k)
- qsz(k)=qsz(k)+del_tv*flux
- qsz(k)=amax1(0.,qsz(k))
- fluxin=fluxout
- enddo
- if (min_q .eq. 1) then
- pptsnow=pptsnow+fluxin*del_tv
- else
- qsz(min_q-1)=qsz(min_q-1)+del_tv* &
- fluxin/rho(min_q-1)/dzw(min_q-1)
- endif
- !
- else
- notlast=.false.
- endif
- ENDDO
- !
- !-- grauupel
- !
- t_del_tv=0.
- del_tv=dtb
- notlast=.true.
- !
- DO while (notlast)
- !
- min_q=kte
- max_q=kts-1
- !
- do k=kts,kte-1
- if (qgz(k) .gt. 1.0e-8) then
- min_q=min0(min_q,k)
- max_q=max0(max_q,k)
- tmp1=sqrt(pi*rhograul*xnog/rho(k)/qgz(k))
- tmp1=sqrt(tmp1)
- term0=sqrt(4.*grav*rhograul*0.33334/rho(k)/cdrag)
- vtgold(k)=o6*gam4pt5*term0*sqrt(1./tmp1)
- if (k .eq. 1) then
- del_tv=amin1(del_tv,0.9*(zz(k)-zsfc)/vtgold(k))
- else
- del_tv=amin1(del_tv,0.9*(zz(k)-zz(k-1))/vtgold(k))
- endif
- else
- vtgold(k)=0.
- endif
- enddo
- if (max_q .ge. min_q) then
- !
- !
- !- Check if the summation of the small delta t >= big delta t
- ! (t_del_tv) (del_tv) (dtb)
- t_del_tv=t_del_tv+del_tv
- if ( t_del_tv .ge. dtb ) then
- notlast=.false.
- del_tv=dtb+del_tv-t_del_tv
- endif
- !
- fluxin=0.
- do k=max_q,min_q,-1
- fluxout=rho(k)*vtgold(k)*qgz(k)
- flux=(fluxin-fluxout)/rho(k)/dzw(k)
- qgz(k)=qgz(k)+del_tv*flux
- qgz(k)=amax1(0.,qgz(k))
- fluxin=fluxout
- enddo
- if (min_q .eq. 1) then
- pptgraul=pptgraul+fluxin*del_tv
- else
- qgz(min_q-1)=qgz(min_q-1)+del_tv* &
- fluxin/rho(min_q-1)/dzw(min_q-1)
- endif
- !
- else
- notlast=.false.
- endif
- !
- ENDDO
- !
- !-- cloud ice (03/21/02) follow Vaughan T.J. Phillips at GFDL
- !
- t_del_tv=0.
- del_tv=dtb
- notlast=.true.
- !
- DO while (notlast)
- !
- min_q=kte
- max_q=kts-1
- !
- do k=kts,kte-1
- if (qiz(k) .gt. 1.0e-8) then
- min_q=min0(min_q,k)
- max_q=max0(max_q,k)
- vtiold(k)= 3.29 * (rho(k)* qiz(k))** 0.16 ! Heymsfield and Donner
- if (k .eq. 1) then
- del_tv=amin1(del_tv,0.9*(zz(k)-zsfc)/vtiold(k))
- else
- del_tv=amin1(del_tv,0.9*(zz(k)-zz(k-1))/vtiold(k))
- endif
- else
- vtiold(k)=0.
- endif
- enddo
- if (max_q .ge. min_q) then
- !
- !
- !- Check if the summation of the small delta t >= big delta t
- ! (t_del_tv) (del_tv) (dtb)
- t_del_tv=t_del_tv+del_tv
- if ( t_del_tv .ge. dtb ) then
- notlast=.false.
- del_tv=dtb+del_tv-t_del_tv
- endif
- fluxin=0.
- do k=max_q,min_q,-1
- fluxout=rho(k)*vtiold(k)*qiz(k)
- flux=(fluxin-fluxout)/rho(k)/dzw(k)
- qiz(k)=qiz(k)+del_tv*flux
- qiz(k)=amax1(0.,qiz(k))
- fluxin=fluxout
- enddo
- if (min_q .eq. 1) then
- pptice=pptice+fluxin*del_tv
- else
- qiz(min_q-1)=qiz(min_q-1)+del_tv* &
- fluxin/rho(min_q-1)/dzw(min_q-1)
- endif
- !
- else
- notlast=.false.
- endif
- !
- ENDDO
- do k=kts,kte-1 !sg beg
- precrz(k)=rho(k)*vtrold(k)*qrz(k)
- preciz(k)=rho(k)*vtiold(k)*qiz(k)
- precsz(k)=rho(k)*vtsold(k)*qsz(k)
- precgz(k)=rho(k)*vtgold(k)*qgz(k)
- enddo !sg end
- precrz(kte)=0. !wig - top level never set for vtXold vars
- preciz(kte)=0. !wig
- precsz(kte)=0. !wig
- precgz(kte)=0. !wig
-
- ! Microphysics processes
- !
- DO 2000 k=kts,kte
- !
- qvzodt(k)=amax1( 0.0,odtb*qvz(k) )
- qlzodt(k)=amax1( 0.0,odtb*qlz(k) )
- qizodt(k)=amax1( 0.0,odtb*qiz(k) )
- qszodt(k)=amax1( 0.0,odtb*qsz(k) )
- qrzodt(k)=amax1( 0.0,odtb*qrz(k) )
- qgzodt(k)=amax1( 0.0,odtb*qgz(k) )
- !***********************************************************************
- !***** diagnose mixing ratios (qrz,qsz), terminal *****
- !***** velocities (vtr,vts), and slope parameters in size *****
- !***** distribution(xlambdar,xlambdas) of rain and snow *****
- !***** follows Nagata and Ogura, 1991, MWR, 1309-1337. Eq (A7) *****
- !***********************************************************************
- !
- !**** assuming no cloud water can exist in the top two levels due to
- !**** radiation consideration
- !
- !! if
- !! unsaturated,
- !! no cloud water, rain, ice, snow and graupel
- !! then
- !! skip these processes and jump to line 2000
- !
- !
- tmp=qiz(k)+qlz(k)+qsz(k)+qrz(k)+qgz(k)*gindex
- if( qvz(k)+qlz(k)+qiz(k) .lt. qsiz(k) &
- .and. tmp .eq. 0.0 ) go to 2000
- !! calculate terminal velocity of rain
- !
- if (qrz(k) .gt. 1.0e-8) then
- tmp1=sqrt(pi*rhowater*xnor*orho(k)/qrz(k))
- xlambdar(k)=sqrt(tmp1)
- olambdar(k)=1.0/xlambdar(k)
- vtrold(k)=o6*consta*gambp4*sqrho(k)*olambdar(k)**constb
- else
- vtrold(k)=0.
- olambdar(k)=0.
- endif
- !
- ! if (qrz(k) .gt. 1.0e-12) then
- if (qrz(k) .gt. 1.0e-8) then
- tmp1=sqrt(pi*rhowater*xnor*orho(k)/qrz(k))
- xlambdar(k)=sqrt(tmp1)
- olambdar(k)=1.0/xlambdar(k)
- vtr(k)=o6*consta*gambp4*sqrho(k)*olambdar(k)**constb
- else
- vtr(k)=0.
- olambdar(k)=0.
- endif
- !
- !! calculate terminal velocity of snow
- !
- if (qsz(k) .gt. 1.0e-8) then
- tmp1=sqrt(pi*rhosnow*xnos*orho(k)/qsz(k))
- xlambdas(k)=sqrt(tmp1)
- olambdas(k)=1.0/xlambdas(k)
- vtsold(k)=o6*constc*gamdp4*sqrho(k)*olambdas(k)**constd
- else
- vtsold(k)=0.
- olambdas(k)=0.
- endif
- !
- ! if (qsz(k) .gt. 1.0e-12) then
- if (qsz(k) .gt. 1.0e-8) then
- tmp1=sqrt(pi*rhosnow*xnos*orho(k)/qsz(k))
- xlambdas(k)=sqrt(tmp1)
- olambdas(k)=1.0/xlambdas(k)
- vts(k)=o6*constc*gamdp4*sqrho(k)*olambdas(k)**constd
- else
- vts(k)=0.
- olambdas(k)=0.
- endif
- !
- !! calculate terminal velocity of graupel
- !
- if (qgz(k) .gt. 1.0e-8) then
- tmp1=sqrt( pi*rhograul*xnog*orho(k)/qgz(k))
- xlambdag(k)=sqrt(tmp1)
- olambdag(k)=1.0/xlambdag(k)
- term0=sqrt(4.*grav*rhograul*0.33334*orho(k)*ocdrag)
- vtgold(k)=o6*gam4pt5*term0*sqrt(olambdag(k))
- else
- vtgold(k)=0.
- olambdag(k)=0.
- endif
- !
- ! if (qgz(k) .gt. 1.0e-12) then
- if (qgz(k) .gt. 1.0e-8) then
- tmp1=sqrt( pi*rhograul*xnog*orho(k)/qgz(k))
- xlambdag(k)=sqrt(tmp1)
- olambdag(k)=1.0/xlambdag(k)
- term0=sqrt(4.*grav*rhograul*0.33334*orho(k)*ocdrag)
- vtg(k)=o6*gam4pt5*term0*sqrt(olambdag(k))
- else
- vtg(k)=0.
- olambdag(k)=0.
- endif
- !
- !***********************************************************************
- !***** compute viscosity,difusivity,thermal conductivity, and ******
- !***** Schmidt number ******
- !***********************************************************************
- !c------------------------------------------------------------------
- !c viscmu: dynamic viscosity of air kg/m/s
- !c visc: kinematic viscosity of air = viscmu/rho (m2/s)
- !c avisc=1.49628e-6 kg/m/s=1.49628e-5 g/cm/s
- !c viscmu=1.718e-5 kg/m/s in RH
- !c diffwv: Diffusivity of water vapor in air
- !c adiffwv = 8.7602e-5 (8.794e-5 in MM5) kgm/s3
- !c = 8.7602 (8.794 in MM5) gcm/s3
- !c diffwv(k)=2.26e-5 m2/s
- !c schmidt: Schmidt number=visc/diffwv
- !c xka: thermal conductivity of air J/m/s/K (Kgm/s3/K)
- !c xka(k)=2.43e-2 J/m/s/K in RH
- !c axka=1.4132e3 (1.414e3 in MM5) m2/s2/k = 1.4132e7 cm2/s2/k
- !c------------------------------------------------------------------
- viscmu(k)=avisc*tem(k)**1.5/(tem(k)+120.0)
- visc(k)=viscmu(k)*orho(k)
- diffwv(k)=adiffwv*tem(k)**1.81*oprez(k)
- schmidt(k)=visc(k)/diffwv(k)
- xka(k)=axka*viscmu(k)
- if (tem(k) .lt. 273.15) then
- !
- !***********************************************************************
- !********* snow production processes for T < 0 C **********
- !***********************************************************************
- !c
- !c (1) ICE CRYSTAL AGGREGATION TO SNOW (Psaut): Lin (21)
- !c! psaut=alpha1*(qi-qi0)
- !c! alpha1=1.0e-3*exp(0.025*(T-T0))
- !c
- ! alpha1=1.0e-3*exp( 0.025*temcc(k) )
- alpha1=1.0e-3*exp( 0.025*temcc(k) )
- !
- if(temcc(k) .lt. -20.0) then
- tmp1=-7.6+4.0*exp( -0.2443e-3*(abs(temcc(k))-20)**2.455 )
- qic=1.0e-3*exp(tmp1)*orho(k)
- else
- qic=qi0
- end if
- !testing
- ! tmp1=amax1( 0.0,alpha1*(qiz(k)-qic) )
- ! psaut(k)=amin1( tmp1,qizodt(k) )
- tmp1=odtb*(qiz(k)-qic)*(1.0-exp(-alpha1*dtb))
- psaut(k)=amax1( 0.0,tmp1 )
- !c
- !c (2) BERGERON PROCESS TRANSFER OF CLOUD WATER TO SNOW (Psfw)
- !c this process only considered when -31 C < T < 0 C
- !c Lin (33) and Hsie (17)
- !c
- !c!
- !c! parama1 and parama2 functions must be user supplied
- !c!
- ! testing
- if( qlz(k) .gt. 1.0e-10 ) then
- temc1=amax1(-30.99,temcc(k))
- ! print*,'temc1',temc1,qlz(k)
- a1=parama1( temc1 )
- a2=parama2( temc1 )
- tmp1=1.0-a2
- !! change unit from cgs to mks
- a1=a1*0.001**tmp1
- !c! dtberg is the time needed for a crystal to grow from 40 to 50 um
- !c ! odtberg=1.0/dtberg
- odtberg=(a1*tmp1)/(xmi50**tmp1-xmi40**tmp1)
- !
- !c! compute terminal velocity of a 50 micron ice cystal
- !
- vti50=constc*di50**constd*sqrho(k)
- !
- eiw=1.0
- save1=a1*xmi50**a2
- save2=0.25*pi*eiw*rho(k)*di50*di50*vti50
- !
- tmp2=( save1 + save2*qlz(k) )
- !
- !! maximum number of 50 micron crystals limited by the amount
- !! of supercool water
- !
- xni50mx=qlzodt(k)/tmp2
- !
- !! number of 50 micron crystals produced
- !
- !
- xni50=qiz(k)*( 1.0-exp(-dtb*odtberg) )/xmi50
- xni50=amin1(xni50,xni50mx)
- !
- tmp3=odtb*tmp2/save2*( 1.0-exp(-save2*xni50*dtb) )
- psfw(k)=amin1( tmp3,qlzodt(k) )
- !testing
- ! psfw(k)=0.
- !0915 if( temcc(k).gt.-30.99 ) then
- !0915 a1=parama1( temcc(k) )
- !0915 a2=parama2( temcc(k) )
- !0915 tmp1=1.0-a2
- !! change unit from cgs to mks
- !0915 a1=a1*0.001**tmp1
- !c! dtberg is the time needed for a crystal to grow from 40 to 50 um
- !c! odtberg=1.0/dtberg
- !0915 odtberg=(a1*tmp1)/(xmi50**tmp1-xmi40**tmp1)
- !c! number of 50 micron crystals produced
- !0915 xni50=qiz(k)*dtb*odtberg/xmi50
- !c! need to calculate the terminal velocity of a 50 micron
- !c! ice cystal
- !0915 vti50=constc*di50**constd*sqrho(k)
- !0915 eiw=1.0
- !0915 tmp2=xni50*( a1*xmi50**a2 + &
- !0915 0.25*qlz(k)*pi*eiw*rho(k)*di50*di50*vti50 )
- !0915 psfw(k)=amin1( tmp2,qlzodt(k) )
- !0915 psfw(k)=0.
- !c
- !c (3) REDUCTION OF CLOUD ICE BY BERGERON PROCESS (Psfi): Lin (34)
- !c this process only considered when -31 C < T < 0 C
- !c
- tmp1=xni50*xmi50-psfw(k)
- psfi(k)=amin1(tmp1,qizodt(k))
- ! testing
- ! psfi(k)=0.
- end if
- !
- !0915 tmp1=qiz(k)*odtberg
- !0915 psfi(k)=amin1(tmp1,qizodt(k))
- ! testing
- !0915 psfi(k)=0.
- !0915 end if
- !
- if(qrz(k) .le. 0.0) go to 1000
- !
- ! Processes (4) and (5) only need when qrz > 0.0
- !
- !c
- !c (4) CLOUD ICE ACCRETION BY RAIN (Praci): Lin (25)
- !c may produce snow or graupel
- !c
- eri=1.0
- !0915 tmp1=qiz(k)*pio4*eri*xnor*consta*sqrho(k)
- !0915 tmp2=tmp1*gambp3*olambdar(k)**bp3
- !0915 praci(k)=amin1( tmp2,qizodt(k) )
- save1=pio4*eri*xnor*consta*sqrho(k)
- tmp1=save1*gambp3*olambdar(k)**bp3
- praci(k)=qizodt(k)*( 1.0-exp(-tmp1*dtb) )
- !c
- !c (5) RAIN ACCRETION BY CLOUD ICE (Piacr): Lin (26)
- !c
- !0915 tmp2=tmp1*rho(k)*pio6*rhowater*gambp6*oxmi* &
- !0915 olambdar(k)**bp6
- !0915 piacr(k)=amin1( tmp2,qrzodt(k) )
- tmp2=qiz(k)*save1*rho(k)*pio6*rhowater*gambp6*oxmi* &
- olambdar(k)**bp6
- piacr(k)=amin1( tmp2,qrzodt(k) )
- !
- 1000 continue
- !
- if(qsz(k) .le. 0.0) go to 1200
- !
- ! Compute the following processes only when qsz > 0.0
- !
- !c
- !c (6) ICE CRYSTAL ACCRETION BY SNOW (Psaci): Lin (22)
- !c
- esi=exp( 0.025*temcc(k) )
- save1=pio4*xnos*constc*gamdp3*sqrho(k)* &
- olambdas(k)**dp3
- tmp1=esi*save1
- psaci(k)=qizodt(k)*( 1.0-exp(-tmp1*dtb) )
- !0915 tmp1=pio4*xnos*constc*gamdp3*sqrho(k)* &
- !0915 olambdas(k)**dp3
- !0915 tmp2=qiz(k)*esi*tmp1
- !0915 psaci(k)=amin1( tmp2,qizodt(k) )
- !c
- !c (7) CLOUD WATER ACCRETION BY SNOW (Psacw): Lin (24)
- !c
- esw=1.0
- tmp1=esw*save1
- psacw(k)=qlzodt(K)*( 1.0-exp(-tmp1*dtb) )
- !0915 tmp2=qlz(k)*esw*tmp1
- !0915 psacw(k)=amin1( tmp2,qlzodt(k) )
- !c
- !c (8) DEPOSITION/SUBLIMATION OF SNOW (Psdep/Pssub): Lin (31)
- !c includes consideration of ventilation effect
- !c
- !c abi=2*pi*(Si-1)/rho/(A"+B")
- !c
- tmpa=rvapor*xka(k)*tem(k)*tem(k)
- tmpb=xls*xls*rho(k)*qsiz(k)*diffwv(k)
- tmpc=tmpa*qsiz(k)*diffwv(k)
- abi=2.0*pi*(qvoqsiz(k)-1.0)*tmpc/(tmpa+tmpb)
- !
- !c vf1s,vf2s=ventilation factors for snow
- !c vf1s=0.78,vf2s=0.31 in LIN
- !
- tmp1=constc*sqrho(k)*olambdas(k)**dp5/visc(k)
- tmp2=abi*xnos*( vf1s*olambdas(k)*olambdas(k)+ &
- vf2s*schmidt(k)**0.33334*gamdp5o2*sqrt(tmp1) )
- tmp3=odtb*( qvz(k)-qsiz(k) )
- !
- !bloss: BEGIN
- !the old implementation would give the wrong results if olambdas(k) ==0
- !which can lead to positive pssub, i.e. tmp2=0 but tmp3> 0
- ! if( tmp2 .le. 0.0) then
- if( tmp3 .le. 0.0) then
- tmp2=amax1( tmp2,tmp3)
- pssub(k)=amin1(0.,amax1( tmp2,-qszodt(k) ))
- !bloss: END
- psdep(k)=0.0
- else
- psdep(k)=amin1( tmp2,tmp3 )
- pssub(k)=0.0
- end if
- !0915 psdep(k)=amax1(0.0,tmp2)
- !0915 pssub(k)=amin1(0.0,tmp2)
- !0915 pssub(k)=amax1( pssub(k),-qszodt(k) )
- !
- if(qrz(k) .le. 0.0) go to 1200
- !
- ! Compute processes (9) and (10) only when qsz > 0.0 and qrz > 0.0
- !
- !c
- !c (9) ACCRETION OF SNOW BY RAIN (Pracs): Lin (27)
- !c
- esr=1.0
- tmpa=olambdar(k)*olambdar(k)
- tmpb=olambdas(k)*olambdas(k)
- tmpc=olambdar(k)*olambdas(k)
- tmp1=pi*pi*esr*xnor*xnos*abs( vtr(k)-vts(k) )*orho(k)
- tmp2=tmpb*tmpb*olambdar(k)*(5.0*tmpb+2.0*tmpc+0.5*tmpa)
- tmp3=tmp1*rhosnow*tmp2
- pracs(k)=amin1( tmp3,qszodt(k) )
- !c
- !c (10) ACCRETION OF RAIN BY SNOW (Psacr): Lin (28)
- !c
- tmp3=tmpa*tmpa*olambdas(k)*(5.0*tmpa+2.0*tmpc+0.5*tmpb)
- tmp4=tmp1*rhowater*tmp3
- psacr(k)=amin1( tmp4,qrzodt(k) )
- !
- 1200 continue
- !
- else
- !
- !***********************************************************************
- !********* snow production processes for T > 0 C **********
- !***********************************************************************
- !
- if (qsz(k) .le. 0.0) go to 1400
- !c
- !c (1) CLOUD WATER ACCRETION BY SNOW (Psacw): Lin (24)
- !c
- esw=1.0
- tmp1=esw*pio4*xnos*constc*gamdp3*sqrho(k)* &
- olambdas(k)**dp3
- psacw(k)=qlzodt(k)*( 1.0-exp(-tmp1*dtb) )
- !0915 tmp1=pio4*xnos*constc*gamdp3*sqrho(k)* &
- !0915 olambdas(k)**dp3
- !0915 tmp2=qlz(k)*esw*tmp1
- !0915 psacw(k)=amin1( tmp2,qlzodt(k) )
- !c
- !c (2) ACCRETION OF RAIN BY SNOW (Psacr): Lin (28)
- !c
- esr=1.0
- tmpa=olambdar(k)*olambdar(k)
- tmpb=olambdas(k)*olambdas(k)
- tmpc=olambdar(k)*olambdas(k)
- tmp1=pi*pi*esr*xnor*xnos*abs( vtr(k)-vts(k) )*orho(k)
- tmp2=tmpa*tmpa*olambdas(k)*(5.0*tmpa+2.0*tmpc+0.5*tmpb)
- tmp3=tmp1*rhowater*tmp2
- psacr(k)=amin1( tmp3,qrzodt(k) )
- !c
- !c (3) MELTING OF SNOW (Psmlt): Lin (32)
- !c Psmlt is negative value
- !
- delrs=rs0(k)-qvz(k)
- term1=2.0*pi*orho(k)*( xlv*diffwv(k)*rho(k)*delrs- &
- xka(k)*temcc(k) )
- tmp1=constc*sqrho(k)*olambdas(k)**dp5/visc(k)
- tmp2=xnos*( vf1s*olambdas(k)*olambdas(k)+ &
- vf2s*schmidt(k)**0.33334*gamdp5o2*sqrt(tmp1) )
- tmp3=term1*oxlf*tmp2-cwoxlf*temcc(k)*( psacw(k)+psacr(k) )
- tmp4=amin1(0.0,tmp3)
- psmlt(k)=amax1( tmp4,-qszodt(k) )
- !c
- !c (4) EVAPORATION OF MELTING SNOW (Psmltevp): HR (A27)
- !c but use Lin et al. coefficience
- !c Psmltevp is a negative value
- !c
- tmpa=rvapor*xka(k)*tem(k)*tem(k)
- tmpb=xlv*xlv*rho(k)*qswz(k)*diffwv(k)
- tmpc=tmpa*qswz(k)*diffwv(k)
- tmpd=amin1( 0.0,(qvoqswz(k)-0.90)*qswz(k)*odtb )
- ! abr=2.0*pi*(qvoqswz(k)-1.0)*tmpc/(tmpa+tmpb)
- abr=2.0*pi*(qvoqswz(k)-0.90)*tmpc/(tmpa+tmpb)
- !
- !**** allow evaporation to occur when RH less than 90%
- !**** here not using 100% because the evaporation cooling
- !**** of temperature is not taking into account yet; hence,
- !**** the qsw value is a little bit larger. This will avoid
- !**** evaporation can generate cloud.
- !
- !c vf1s,vf2s=ventilation factors for snow
- !c vf1s=0.78,vf2s=0.31 in LIN
- !
- tmp1=constc*sqrho(k)*olambdas(k)**dp5/visc(k)
- tmp2=abr*xnos*( vf1s*olambdas(k)*olambdas(k)+ &
- vf2s*schmidt(k)**0.33334*gamdp5o2*sqrt(tmp1) )
- tmp3=amin1(0.0,tmp2)
- tmp3=amax1( tmp3,tmpd )
- psmltevp(k)=amax1( tmp3,-qszodt(k) )
- 1400 continue
- !
- end if
- !***********************************************************************
- !********* rain production processes **********
- !***********************************************************************
- !
- !c
- !c (1) AUTOCONVERSION OF RAIN (Praut): RH
- !sg: begin
- if(flag_qndrop)then
- if( qndropz(k) >= 1. ) then
- ! Liu et al. autoconversion scheme
- rhocgs=rho(k)*1.e-3
- liqconc=rhocgs*qlz(k) ! (kg/kg) to (g/cm3)
- capn=1.0e-3*rhocgs*qndropz(k) ! (#/kg) to (#/cm3)
- ! rate function
- if(liqconc.gt.1.e-10)then
- p0=(kappa*beta/capn)*(liqconc*liqconc*liqconc)
- xc=9.7d-17*capn*sqrt(capn)/(liqconc*liqconc)
- ! Calculate autoconversion rate (g/g/s)
- if(xc.lt.10.)then
- praut(k)=(p0/rhocgs) * ( 0.5d0*(xc*xc+2*xc+2.0d0)* &
- (1.0d0+xc)*exp(-2.0d0*xc) )
- endif
- endif
- endif
- else
- !sg: end
- !c araut=afa*rho
- !c afa=0.001 Rate coefficient for autoconvergence
- !c
- !c araut=1.0e-3
- !c
- araut=0.001
- !testing
- ! tmp1=amax1( 0.0,araut*(qlz(k)-ql0) )
- ! praut(k)=amin1( tmp1,qlzodt(k) )
- tmp1=odtb*(qlz(k)-ql0)*( 1.0-exp(-araut*dtb) )
- praut(k)=amax1( 0.0,tmp1 )
- endif !sg
- !c
- !c (2) ACCRETION OF CLOUD WATER BY RAIN (Pracw): Lin (51)
- !c
- erw=1.0
- ! tmp1=qlz(k)*pio4*erw*xnor*consta*sqrho(k)
- ! tmp2=tmp1*gambp3*olambdar(k)**bp3
- ! pracw(k)=amin1( tmp2,qlzodt(k) )
- tmp1=pio4*erw*xnor*consta*sqrho(k)* &
- gambp3*olambdar(k)**bp3
- pracw(k)=qlzodt(k)*( 1.0-exp(-tmp1*dtb) )
- !c
- !c (3) EVAPORATION OF RAIN (Prevp): Lin (52)
- !c Prevp is negative value
- !c
- !c Sw=qvoqsw : saturation ratio
- !c
- tmpa=rvapor*xka(k)*tem(k)*tem(k)
- tmpb=xlv*xlv*rho(k)*qswz(k)*diffwv(k)
- tmpc=tmpa*qswz(k)*diffwv(k)
- !bloss: BEGIN
- ! tmpd=amin1(0.0,(qvoqswz(k)-0.90)*qswz(k)*odtb)
- ! set max allowed evaporation to 90% of the amount that
- ! would induce saturation wrt liquid in a single step.
- tmpd = qswz(k)*xlv/(rvapor*tem(k)**2) ! d(qsat_liq)/dT
- tmpd = min( 0., 0.9*odtb*(qvz(k) + qlz(k) - qswz(k)) &
- / (1. + xlvocp * tmpd) )
- abr=2.0*pi*(qvoqswz(k)-1.0)*tmpc/(tmpa+tmpb)
- ! abr=2.0*pi*(qvoqswz(k)-0.90)…
Large files files are truncated, but you can click here to view the full file