/wrfv2_fire/phys/module_ra_gsfcsw.F
FORTRAN Legacy | 3138 lines | 1778 code | 504 blank | 856 comment | 46 complexity | 1aade0c232781669363b83e248af8e59 MD5 | raw file
Possible License(s): AGPL-1.0
Large files files are truncated, but you can click here to view the full file
- !Comment the following out to turn off aerosol-radiation
- !feedback between MOSAIC and GSFCSW. wig, 21-Feb-2005
- MODULE module_ra_gsfcsw
- REAL, PARAMETER, PRIVATE :: thresh=1.e-9
- REAL, SAVE :: center_lat
- ! Assign co2 and trace gases amount (units are parts/part by volumn)
- REAL, PARAMETER, PRIVATE :: co2 = 300.e-6
- CONTAINS
- SUBROUTINE GSFCSWRAD(rthraten,gsw,xlat,xlong &
- ,dz8w,rho_phy &
- ,alb,t3d,qv3d,qc3d,qr3d &
- ,qi3d,qs3d,qg3d,qndrop3d &
- ,p3d,p8w3d,pi3d,cldfra3d,rswtoa &
- ,gmt,cp,g,julday,xtime,declin,solcon &
- ,radfrq,degrad,taucldi,taucldc,warm_rain &
- ,tauaer300,tauaer400,tauaer600,tauaer999 & ! jcb
- ,gaer300,gaer400,gaer600,gaer999 & ! jcb
- ,waer300,waer400,waer600,waer999 & ! jcb
- ,aer_ra_feedback &
- ,f_qv,f_qc,f_qr,f_qi,f_qs,f_qg,f_qndrop &
- ,ids,ide, jds,jde, kds,kde &
- ,ims,ime, jms,jme, kms,kme &
- ,its,ite, jts,jte, kts,kte )
- !------------------------------------------------------------------
- IMPLICIT NONE
- !------------------------------------------------------------------
- INTEGER, PARAMETER :: np = 75
- INTEGER, INTENT(IN ) :: ids,ide, jds,jde, kds,kde, &
- ims,ime, jms,jme, kms,kme, &
- its,ite, jts,jte, kts,kte
- LOGICAL, INTENT(IN ) :: warm_rain
- INTEGER, INTENT(IN ) :: JULDAY
- REAL, INTENT(IN ) :: RADFRQ,DEGRAD, &
- XTIME,DECLIN,SOLCON
- !
- REAL, DIMENSION( ims:ime, kms:kme, jms:jme ), &
- INTENT(IN ) :: P3D, &
- P8W3D, &
- pi3D, &
- T3D, &
- dz8w, &
- rho_phy, &
- CLDFRA3D
- REAL, DIMENSION( ims:ime, kms:kme, jms:jme ), &
- INTENT(INOUT) :: RTHRATEN
- REAL, DIMENSION( ims:ime, kms:kme, jms:jme ), &
- OPTIONAL, &
- INTENT(INOUT) :: taucldi, &
- taucldc
- !
- REAL, DIMENSION( ims:ime, jms:jme ), &
- INTENT(IN ) :: XLAT, &
- XLONG, &
- ALB
- !
- REAL, DIMENSION( ims:ime, jms:jme ), &
- INTENT(INOUT) :: GSW, &
- RSWTOA
- !
- REAL, INTENT(IN ) :: GMT,CP,G
- !
- !
- ! Optional
- !
- REAL, DIMENSION( ims:ime, kms:kme, jms:jme ), OPTIONAL , &
- INTENT(IN ) :: tauaer300,tauaer400,tauaer600,tauaer999, & ! jcb
- gaer300,gaer400,gaer600,gaer999, & ! jcb
- waer300,waer400,waer600,waer999 ! jcb
- INTEGER, INTENT(IN ), OPTIONAL :: aer_ra_feedback
- REAL, DIMENSION( ims:ime, kms:kme, jms:jme ), &
- OPTIONAL, &
- INTENT(IN ) :: &
- QV3D, &
- QC3D, &
- QR3D, &
- QI3D, &
- QS3D, &
- QG3D, &
- QNDROP3D
- LOGICAL, OPTIONAL, INTENT(IN ) :: &
- F_QV,F_QC,F_QR,F_QI,F_QS,F_QG, &
- F_QNDROP
- ! LOCAL VARS
-
- REAL, DIMENSION( its:ite ) :: &
- ts, &
- cosz, &
- fp, &
- rsuvbm, &
- rsuvdf, &
- rsirbm, &
- rsirdf, &
- p400, &
- p700
- INTEGER, DIMENSION( its:ite ) :: &
- ict, &
- icb
- REAL, DIMENSION( its:ite, kts-1:kte, 2 ) :: taucld
- REAL, DIMENSION( its:ite, kts-1:kte+1 ) :: flx, &
- flxd
- !
- REAL, DIMENSION( its:ite, kts-1:kte ) :: O3
- !
- REAL, DIMENSION( its:ite, kts-1:kte, 11 ) :: &
- taual, &
- ssaal, &
- asyal
- REAL, DIMENSION( its:ite, kts-1:kte, 2 ) :: &
- reff, &
- cwc
- REAL, DIMENSION( its: ite, kts-1:kte+1 ) :: &
- P8W2D
- REAL, DIMENSION( its: ite, kts-1:kte ) :: &
- TTEN2D, &
- qndrop2d, &
- SH2D, &
- P2D, &
- T2D, &
- fcld2D
- REAL, DIMENSION( np, 5 ) :: pres, &
- ozone
- REAL, DIMENSION( np ) :: p
- LOGICAL :: cldwater,overcast, predicate
- !
- INTEGER :: i,j,K,NK,ib,kk,mix,mkx
- ! iprof = 1 : mid-latitude summer profile
- ! = 2 : mid-latitude winter profile
- ! = 3 : sub-arctic summer profile
- ! = 4 : sub-arctic winter profile
- ! = 5 : tropical profile
- !
- INTEGER :: iprof, &
- is_summer, &
- ie_summer, &
- lattmp
- !
- REAL :: XLAT0,XLONG0
- REAL :: fac,latrmp
- REAL :: xt24,tloctm,hrang,xxlat
- real, dimension(11) :: midbands ! jcb
- data midbands/.2,.235,.27,.2875,.3025,.305,.3625,.55,1.92,1.745,6.135/ ! jcb
- real :: ang,slope ! jcb
- character(len=200) :: msg !wig
- real pi, third, relconst, lwpmin, rhoh2o
- !
- !--------------------------------------------------------------------------------
- ! data set 1
- ! mid-latitude summer (75 levels) : p(mb) o3(g/g)
- ! surface temp = 294.0
- !
- data (pres(i,1),i=1,np)/ &
- 0.0006244, 0.0008759, 0.0012286, 0.0017234, 0.0024174, &
- 0.0033909, 0.0047565, 0.0066720, 0.0093589, 0.0131278, &
- 0.0184145, 0.0258302, 0.0362323, 0.0508234, 0.0712906, &
- 0.1000000, 0.1402710, 0.1967600, 0.2759970, 0.3871430, &
- 0.5430, 0.7617, 1.0685, 1.4988, 2.1024, 2.9490, &
- 4.1366, 5.8025, 8.1392, 11.4170, 16.0147, 22.4640, &
- 31.5105, 44.2001, 62.0000, 85.7750, 109.5500, 133.3250, &
- 157.1000, 180.8750, 204.6500, 228.4250, 252.2000, 275.9750, &
- 299.7500, 323.5250, 347.3000, 371.0750, 394.8500, 418.6250, &
- 442.4000, 466.1750, 489.9500, 513.7250, 537.5000, 561.2750, &
- 585.0500, 608.8250, 632.6000, 656.3750, 680.1500, 703.9250, &
- 727.7000, 751.4750, 775.2500, 799.0250, 822.8000, 846.5750, &
- 870.3500, 894.1250, 917.9000, 941.6750, 965.4500, 989.2250, &
- 1013.0000/
- !
- data (ozone(i,1),i=1,np)/ &
- 0.1793E-06, 0.2228E-06, 0.2665E-06, 0.3104E-06, 0.3545E-06, &
- 0.3989E-06, 0.4435E-06, 0.4883E-06, 0.5333E-06, 0.5786E-06, &
- 0.6241E-06, 0.6698E-06, 0.7157E-06, 0.7622E-06, 0.8557E-06, &
- 0.1150E-05, 0.1462E-05, 0.1793E-05, 0.2143E-05, 0.2512E-05, &
- 0.2902E-05, 0.3313E-05, 0.4016E-05, 0.5193E-05, 0.6698E-05, &
- 0.8483E-05, 0.9378E-05, 0.9792E-05, 0.1002E-04, 0.1014E-04, &
- 0.9312E-05, 0.7834E-05, 0.6448E-05, 0.5159E-05, 0.3390E-05, &
- 0.1937E-05, 0.1205E-05, 0.8778E-06, 0.6935E-06, 0.5112E-06, &
- 0.3877E-06, 0.3262E-06, 0.2770E-06, 0.2266E-06, 0.2020E-06, &
- 0.1845E-06, 0.1679E-06, 0.1519E-06, 0.1415E-06, 0.1317E-06, &
- 0.1225E-06, 0.1137E-06, 0.1055E-06, 0.1001E-06, 0.9487E-07, &
- 0.9016E-07, 0.8641E-07, 0.8276E-07, 0.7930E-07, 0.7635E-07, &
- 0.7347E-07, 0.7065E-07, 0.6821E-07, 0.6593E-07, 0.6368E-07, &
- 0.6148E-07, 0.5998E-07, 0.5859E-07, 0.5720E-07, 0.5582E-07, &
- 0.5457E-07, 0.5339E-07, 0.5224E-07, 0.5110E-07, 0.4999E-07/
- !--------------------------------------------------------------------------------
- ! data set 2
- ! mid-latitude winter (75 levels) : p(mb) o3(g/g)
- ! surface temp = 272.2
- !
- data (pres(i,2),i=1,np)/ &
- 0.0006244, 0.0008759, 0.0012286, 0.0017234, 0.0024174, &
- 0.0033909, 0.0047565, 0.0066720, 0.0093589, 0.0131278, &
- 0.0184145, 0.0258302, 0.0362323, 0.0508234, 0.0712906, &
- 0.1000000, 0.1402710, 0.1967600, 0.2759970, 0.3871430, &
- 0.5430, 0.7617, 1.0685, 1.4988, 2.1024, 2.9490, &
- 4.1366, 5.8025, 8.1392, 11.4170, 16.0147, 22.4640, &
- 31.5105, 44.2001, 62.0000, 85.9000, 109.8000, 133.7000, &
- 157.6000, 181.5000, 205.4000, 229.3000, 253.2000, 277.1000, &
- 301.0000, 324.9000, 348.8000, 372.7000, 396.6000, 420.5000, &
- 444.4000, 468.3000, 492.2000, 516.1000, 540.0000, 563.9000, &
- 587.8000, 611.7000, 635.6000, 659.5000, 683.4000, 707.3000, &
- 731.2000, 755.1000, 779.0000, 802.9000, 826.8000, 850.7000, &
- 874.6000, 898.5000, 922.4000, 946.3000, 970.2000, 994.1000, &
- 1018.0000/
- !
- data (ozone(i,2),i=1,np)/ &
- 0.2353E-06, 0.3054E-06, 0.3771E-06, 0.4498E-06, 0.5236E-06, &
- 0.5984E-06, 0.6742E-06, 0.7511E-06, 0.8290E-06, 0.9080E-06, &
- 0.9881E-06, 0.1069E-05, 0.1152E-05, 0.1319E-05, 0.1725E-05, &
- 0.2145E-05, 0.2581E-05, 0.3031E-05, 0.3497E-05, 0.3980E-05, &
- 0.4478E-05, 0.5300E-05, 0.6725E-05, 0.8415E-05, 0.1035E-04, &
- 0.1141E-04, 0.1155E-04, 0.1143E-04, 0.1093E-04, 0.1060E-04, &
- 0.9720E-05, 0.8849E-05, 0.7424E-05, 0.6023E-05, 0.4310E-05, &
- 0.2820E-05, 0.1990E-05, 0.1518E-05, 0.1206E-05, 0.9370E-06, &
- 0.7177E-06, 0.5450E-06, 0.4131E-06, 0.3277E-06, 0.2563E-06, &
- 0.2120E-06, 0.1711E-06, 0.1524E-06, 0.1344E-06, 0.1199E-06, &
- 0.1066E-06, 0.9516E-07, 0.8858E-07, 0.8219E-07, 0.7598E-07, &
- 0.6992E-07, 0.6403E-07, 0.5887E-07, 0.5712E-07, 0.5540E-07, &
- 0.5370E-07, 0.5214E-07, 0.5069E-07, 0.4926E-07, 0.4785E-07, &
- 0.4713E-07, 0.4694E-07, 0.4676E-07, 0.4658E-07, 0.4641E-07, &
- 0.4634E-07, 0.4627E-07, 0.4619E-07, 0.4612E-07, 0.4605E-07/
- !--------------------------------------------------------------------------------
- ! data set 3
- ! sub-arctic summer (75 levels) : p(mb) o3(g/g)
- ! surface temp = 287.0
- !
- data (pres(i,3),i=1,np)/ &
- 0.0006244, 0.0008759, 0.0012286, 0.0017234, 0.0024174, &
- 0.0033909, 0.0047565, 0.0066720, 0.0093589, 0.0131278, &
- 0.0184145, 0.0258302, 0.0362323, 0.0508234, 0.0712906, &
- 0.1000000, 0.1402710, 0.1967600, 0.2759970, 0.3871430, &
- 0.5430, 0.7617, 1.0685, 1.4988, 2.1024, 2.9490, &
- 4.1366, 5.8025, 8.1392, 11.4170, 16.0147, 22.4640, &
- 31.5105, 44.2001, 62.0000, 85.7000, 109.4000, 133.1000, &
- 156.8000, 180.5000, 204.2000, 227.9000, 251.6000, 275.3000, &
- 299.0000, 322.7000, 346.4000, 370.1000, 393.8000, 417.5000, &
- 441.2000, 464.9000, 488.6000, 512.3000, 536.0000, 559.7000, &
- 583.4000, 607.1000, 630.8000, 654.5000, 678.2000, 701.9000, &
- 725.6000, 749.3000, 773.0000, 796.7000, 820.4000, 844.1000, &
- 867.8000, 891.5000, 915.2000, 938.9000, 962.6000, 986.3000, &
- 1010.0000/
- !
- data (ozone(i,3),i=1,np)/ &
- 0.1728E-06, 0.2131E-06, 0.2537E-06, 0.2944E-06, 0.3353E-06, &
- 0.3764E-06, 0.4176E-06, 0.4590E-06, 0.5006E-06, 0.5423E-06, &
- 0.5842E-06, 0.6263E-06, 0.6685E-06, 0.7112E-06, 0.7631E-06, &
- 0.1040E-05, 0.1340E-05, 0.1660E-05, 0.2001E-05, 0.2362E-05, &
- 0.2746E-05, 0.3153E-05, 0.3762E-05, 0.4988E-05, 0.6518E-05, &
- 0.8352E-05, 0.9328E-05, 0.9731E-05, 0.8985E-05, 0.7632E-05, &
- 0.6814E-05, 0.6384E-05, 0.5718E-05, 0.4728E-05, 0.4136E-05, &
- 0.3033E-05, 0.2000E-05, 0.1486E-05, 0.1121E-05, 0.8680E-06, &
- 0.6474E-06, 0.5164E-06, 0.3921E-06, 0.2996E-06, 0.2562E-06, &
- 0.2139E-06, 0.1723E-06, 0.1460E-06, 0.1360E-06, 0.1267E-06, &
- 0.1189E-06, 0.1114E-06, 0.1040E-06, 0.9678E-07, 0.8969E-07, &
- 0.8468E-07, 0.8025E-07, 0.7590E-07, 0.7250E-07, 0.6969E-07, &
- 0.6694E-07, 0.6429E-07, 0.6208E-07, 0.5991E-07, 0.5778E-07, &
- 0.5575E-07, 0.5403E-07, 0.5233E-07, 0.5067E-07, 0.4904E-07, &
- 0.4721E-07, 0.4535E-07, 0.4353E-07, 0.4173E-07, 0.3997E-07/
- !--------------------------------------------------------------------------------
- ! data set 3
- ! sub-arctic winter (75 levels) : p(mb) o3(g/g)
- ! surface temp = 257.1
- !
- data (pres(i,4),i=1,np)/ &
- 0.0006244, 0.0008759, 0.0012286, 0.0017234, 0.0024174, &
- 0.0033909, 0.0047565, 0.0066720, 0.0093589, 0.0131278, &
- 0.0184145, 0.0258302, 0.0362323, 0.0508234, 0.0712906, &
- 0.1000000, 0.1402710, 0.1967600, 0.2759970, 0.3871430, &
- 0.5430, 0.7617, 1.0685, 1.4988, 2.1024, 2.9490, &
- 4.1366, 5.8025, 8.1392, 11.4170, 16.0147, 22.4640, &
- 31.5105, 44.2001, 62.0000, 85.7750, 109.5500, 133.3250, &
- 157.1000, 180.8750, 204.6500, 228.4250, 252.2000, 275.9750, &
- 299.7500, 323.5250, 347.3000, 371.0750, 394.8500, 418.6250, &
- 442.4000, 466.1750, 489.9500, 513.7250, 537.5000, 561.2750, &
- 585.0500, 608.8250, 632.6000, 656.3750, 680.1500, 703.9250, &
- 727.7000, 751.4750, 775.2500, 799.0250, 822.8000, 846.5750, &
- 870.3500, 894.1250, 917.9000, 941.6750, 965.4500, 989.2250, &
- 1013.0000/
- !
- data (ozone(i,4),i=1,np)/ &
- 0.2683E-06, 0.3562E-06, 0.4464E-06, 0.5387E-06, 0.6333E-06, &
- 0.7301E-06, 0.8291E-06, 0.9306E-06, 0.1034E-05, 0.1140E-05, &
- 0.1249E-05, 0.1360E-05, 0.1474E-05, 0.1855E-05, 0.2357E-05, &
- 0.2866E-05, 0.3383E-05, 0.3906E-05, 0.4437E-05, 0.4975E-05, &
- 0.5513E-05, 0.6815E-05, 0.8157E-05, 0.1008E-04, 0.1200E-04, &
- 0.1242E-04, 0.1250E-04, 0.1157E-04, 0.1010E-04, 0.9063E-05, &
- 0.8836E-05, 0.8632E-05, 0.8391E-05, 0.7224E-05, 0.6054E-05, &
- 0.4503E-05, 0.3204E-05, 0.2278E-05, 0.1833E-05, 0.1433E-05, &
- 0.9996E-06, 0.7440E-06, 0.5471E-06, 0.3944E-06, 0.2852E-06, &
- 0.1977E-06, 0.1559E-06, 0.1333E-06, 0.1126E-06, 0.9441E-07, &
- 0.7678E-07, 0.7054E-07, 0.6684E-07, 0.6323E-07, 0.6028E-07, &
- 0.5746E-07, 0.5468E-07, 0.5227E-07, 0.5006E-07, 0.4789E-07, &
- 0.4576E-07, 0.4402E-07, 0.4230E-07, 0.4062E-07, 0.3897E-07, &
- 0.3793E-07, 0.3697E-07, 0.3602E-07, 0.3506E-07, 0.3413E-07, &
- 0.3326E-07, 0.3239E-07, 0.3153E-07, 0.3069E-07, 0.2987E-07/
- !--------------------------------------------------------------------------------
- ! data set 4
- ! tropical (75 levels) : p(mb) o3(g/g)
- ! surface temp = 300.0
- !
- data (pres(i,5),i=1,np)/ &
- 0.0006244, 0.0008759, 0.0012286, 0.0017234, 0.0024174, &
- 0.0033909, 0.0047565, 0.0066720, 0.0093589, 0.0131278, &
- 0.0184145, 0.0258302, 0.0362323, 0.0508234, 0.0712906, &
- 0.1000000, 0.1402710, 0.1967600, 0.2759970, 0.3871430, &
- 0.5430, 0.7617, 1.0685, 1.4988, 2.1024, 2.9490, &
- 4.1366, 5.8025, 8.1392, 11.4170, 16.0147, 22.4640, &
- 31.5105, 44.2001, 62.0000, 85.7750, 109.5500, 133.3250, &
- 157.1000, 180.8750, 204.6500, 228.4250, 252.2000, 275.9750, &
- 299.7500, 323.5250, 347.3000, 371.0750, 394.8500, 418.6250, &
- 442.4000, 466.1750, 489.9500, 513.7250, 537.5000, 561.2750, &
- 585.0500, 608.8250, 632.6000, 656.3750, 680.1500, 703.9250, &
- 727.7000, 751.4750, 775.2500, 799.0250, 822.8000, 846.5750, &
- 870.3500, 894.1250, 917.9000, 941.6750, 965.4500, 989.2250, &
- 1013.0000/
- !
- data (ozone(i,5),i=1,np)/ &
- 0.1993E-06, 0.2521E-06, 0.3051E-06, 0.3585E-06, 0.4121E-06, &
- 0.4661E-06, 0.5203E-06, 0.5748E-06, 0.6296E-06, 0.6847E-06, &
- 0.7402E-06, 0.7959E-06, 0.8519E-06, 0.9096E-06, 0.1125E-05, &
- 0.1450E-05, 0.1794E-05, 0.2156E-05, 0.2538E-05, 0.2939E-05, &
- 0.3362E-05, 0.3785E-05, 0.4753E-05, 0.6005E-05, 0.7804E-05, &
- 0.9635E-05, 0.1023E-04, 0.1067E-04, 0.1177E-04, 0.1290E-04, &
- 0.1134E-04, 0.9223E-05, 0.6667E-05, 0.3644E-05, 0.1545E-05, &
- 0.5355E-06, 0.2523E-06, 0.2062E-06, 0.1734E-06, 0.1548E-06, &
- 0.1360E-06, 0.1204E-06, 0.1074E-06, 0.9707E-07, 0.8960E-07, &
- 0.8419E-07, 0.7962E-07, 0.7542E-07, 0.7290E-07, 0.7109E-07, &
- 0.6940E-07, 0.6786E-07, 0.6635E-07, 0.6500E-07, 0.6370E-07, &
- 0.6244E-07, 0.6132E-07, 0.6022E-07, 0.5914E-07, 0.5884E-07, &
- 0.5855E-07, 0.5823E-07, 0.5772E-07, 0.5703E-07, 0.5635E-07, &
- 0.5570E-07, 0.5492E-07, 0.5412E-07, 0.5335E-07, 0.5260E-07, &
- 0.5167E-07, 0.5063E-07, 0.4961E-07, 0.4860E-07, 0.4761E-07/
- !--------------------------------------------------------------------------------
- #ifdef WRF_CHEM
- IF ( aer_ra_feedback == 1) then
- IF ( .NOT. &
- ( PRESENT(tauaer300) .AND. &
- PRESENT(tauaer400) .AND. &
- PRESENT(tauaer600) .AND. &
- PRESENT(tauaer999) .AND. &
- PRESENT(gaer300) .AND. &
- PRESENT(gaer400) .AND. &
- PRESENT(gaer600) .AND. &
- PRESENT(gaer999) .AND. &
- PRESENT(waer300) .AND. &
- PRESENT(waer400) .AND. &
- PRESENT(waer600) .AND. &
- PRESENT(waer999) ) ) THEN
- CALL wrf_error_fatal ( 'Warning: missing fields required for aerosol radiation' )
- ENDIF
- ENDIF
- #endif
- cldwater = .true.
- overcast = .false.
- mix=ite-its+1
- mkx=kte-kts+1
- is_summer=80
- ie_summer=265
- ! testing, need to change iprof, which is function of lat and julian day
- ! iprof = 1 : mid-latitude summer profile
- ! = 2 : mid-latitude winter profile
- ! = 3 : sub-arctic summer profile
- ! = 4 : sub-arctic winter profile
- ! = 5 : tropical profile
- IF (abs(center_lat) .le. 30. ) THEN ! tropic
- iprof = 5
- ELSE
- IF (center_lat .gt. 0.) THEN
- IF (center_lat .gt. 60. ) THEN ! arctic
- IF (JULDAY .gt. is_summer .and. JULDAY .lt. ie_summer ) THEN
- ! arctic summer
- iprof = 3
- ELSE
- ! arctic winter
- iprof = 4
- ENDIF
- ELSE ! midlatitude
- IF (JULDAY .gt. is_summer .and. JULDAY .lt. ie_summer ) THEN
- ! north midlatitude summer
- iprof = 1
- ELSE
- ! north midlatitude winter
- iprof = 2
- ENDIF
- ENDIF
- ELSE
- IF (center_lat .lt. -60. ) THEN ! antarctic
- IF (JULDAY .lt. is_summer .or. JULDAY .gt. ie_summer ) THEN
- ! antarctic summer
- iprof = 3
- ELSE
- ! antarctic winter
- iprof = 4
- ENDIF
- ELSE ! midlatitude
- IF (JULDAY .lt. is_summer .or. JULDAY .gt. ie_summer ) THEN
- ! south midlatitude summer
- iprof = 1
- ELSE
- ! south midlatitude winter
- iprof = 2
- ENDIF
- ENDIF
- ENDIF
- ENDIF
- j_loop: DO J=jts,jte
- DO K=kts,kte
- DO I=its,ite
- cwc(i,k,1) = 0.
- cwc(i,k,2) = 0.
- ENDDO
- ENDDO
- DO K=1,np
- p(k)=pres(k,iprof)
- ENDDO
- ! reverse vars
- !
- DO K=kts,kte+1
- DO I=its,ite
- NK=kme-K+kms
- P8W2D(I,K)=p8w3d(i,nk,j)*0.01 ! P8w2D is in mb
- ENDDO
- ENDDO
- DO I=its,ite
- P8W2D(I,0)=.0
- ENDDO
- !
- DO K=kts,kte
- DO I=its,ite
- NK=kme-1-K+kms
- TTEN2D(I,K)=0.
- T2D(I,K)=T3D(I,NK,J)
- ! SH2D specific humidity
- SH2D(I,K)=QV3D(I,NK,J)/(1.+QV3D(I,NK,J))
- SH2D(I,K)=max(0.,SH2D(I,K))
- cwc(I,K,2)=QC3D(I,NK,J)
- cwc(I,K,2)=max(0.,cwc(I,K,2))
- P2D(I,K)=p3d(i,nk,j)*0.01 ! P2D is in mb
- fcld2D(I,K)=CLDFRA3D(I,NK,J)
- ENDDO
- ENDDO
- ! This logic is tortured because cannot test F_QI unless
- ! it is present, and order of evaluation of expressions
- ! is not specified in Fortran
- IF ( PRESENT ( F_QI ) ) THEN
- predicate = F_QI
- ELSE
- predicate = .FALSE.
- ENDIF
- IF (.NOT. warm_rain .AND. .NOT. predicate ) THEN
- DO K=kts,kte
- DO I=its,ite
- IF (T2D(I,K) .lt. 273.15) THEN
- cwc(I,K,1)=cwc(I,K,2)
- cwc(I,K,2)=0.
- ENDIF
- ENDDO
- ENDDO
- ENDIF
- IF ( PRESENT( F_QNDROP ) ) THEN
- IF ( F_QNDROP ) THEN
- DO K=kts,kte
- DO I=its,ite
- NK=kme-1-K+kms
- qndrop2d(I,K)=qndrop3d(I,NK,j)
- ENDDO
- ENDDO
- qndrop2d(:,kts-1)=0.
- END IF
- END IF
- DO I=its,ite
- TTEN2D(I,0)=0.
- T2D(I,0)=T2D(I,1)
- ! SH2D specific humidity
- SH2D(I,0)=0.5*SH2D(i,1)
- cwc(I,0,2)=0.
- cwc(I,0,1)=0.
- P2D(I,0)=0.5*(P8W2D(I,0)+P8W2D(I,1))
- fcld2D(I,0)=0.
- ENDDO
- !
- IF ( PRESENT( F_QI ) .AND. PRESENT( qi3d) ) THEN
- IF ( (F_QI) ) THEN
- DO K=kts,kte
- DO I=its,ite
- NK=kme-1-K+kms
- cwc(I,K,1)=QI3D(I,NK,J)
- cwc(I,K,1)=max(0.,cwc(I,K,1))
- ENDDO
- ENDDO
- ENDIF
- ENDIF
- !
- ! ... Vertical profiles for ozone
- !
- call o3prof (np, p, ozone(1,iprof), its, ite, kts-1, kte, P2D, O3)
- ! ... Vertical profiles for effective particle size
- !
- pi = 4.*atan(1.0)
- third=1./3.
- rhoh2o=1.e3
- relconst=3/(4.*pi*rhoh2o)
- ! minimun liquid water path to calculate rel
- ! corresponds to optical depth of 1.e-3 for radius 4 microns.
- lwpmin=3.e-5
- do k = kts-1, kte
- do i = its, ite
- reff(i,k,2) = 10.
- if( PRESENT( F_QNDROP ) ) then
- if( F_QNDROP ) then
- if ( cwc(i,k,2)*(P8W2D(I,K+1)-P8W2D(I,K)).gt.lwpmin.and. &
- qndrop2d(i,k).gt.1000. ) then
- reff(i,k,2)=(relconst*cwc(i,k,2)/qndrop2d(i,k))**third ! effective radius in m
- ! apply scaling from Martin et al., JAS 51, 1830.
- reff(i,k,2)=1.1*reff(i,k,2)
- reff(i,k,2)=reff(i,k,2)*1.e6 ! convert from m to microns
- reff(i,k,2)=max(reff(i,k,2),4.)
- reff(i,k,2)=min(reff(i,k,2),20.)
- end if
- end if
- end if
- reff(i,k,1) = 80.
- end do
- end do
- !
- ! ... Level indices separating high, middle and low clouds
- !
- do i = its, ite
- p400(i) = 1.e5
- p700(i) = 1.e5
- enddo
- do k = kts-1,kte+1
- do i = its, ite
- if (abs(P8W2D(i,k) - 400.) .lt. p400(i)) then
- p400(i) = abs(P8W2D(i,k) - 400.)
- ict(i) = k
- endif
- if (abs(P8W2D(i,k) - 700.) .lt. p700(i)) then
- p700(i) = abs(P8W2D(i,k) - 700.)
- icb(i) = k
- endif
- end do
- end do
- !wig beg
- ! ... Aerosol effects. Added aerosol feedbacks with MOSAIC, Dec. 2005.
- !
- do ib = 1, 11
- do k = kts-1,kte
- do i = its,ite
- taual(i,k,ib) = 0.
- ssaal(i,k,ib) = 0.
- asyal(i,k,ib) = 0.
- end do
- end do
- end do
- #ifdef WRF_CHEM
- IF ( AER_RA_FEEDBACK == 1) then
- !wig end
- do ib = 1, 11
- do k = kts-1,kte-1 !wig
- do i = its,ite
- ! taual(i,kte-k,ib) = 0.
- ! ssaal(i,kte-k,ib) = 0.
- ! asyal(i,kte-k,ib) = 0.
- !jcb beg
- ! convert optical properties at 300,400,600, and 999 to conform to the band wavelengths
- ! these are: 200,235,270,287.5,302.5,305,362.5,550,1920,1745,6135; why the emphasis on the UV?
- ! taual - use angstrom exponent
- if(tauaer300(i,k+1,j).gt.thresh .and. tauaer999(i,k+1,j).gt.thresh) then
- ang=log(tauaer300(i,k+1,j)/tauaer999(i,k+1,j))/log(999./300.)
- ! write(6,*)i,k,ang,tauaer300(i,k+1,j),tauaer999(i,k+1,j)
- taual(i,kte-k,ib)=tauaer400(i,k+1,j)*(0.4/midbands(ib))**ang ! notice reserved variable
- ! write(6,10001)i,k,ang,tauaer300(i,k+1,j),tauaer999(i,k+1,j),midbands(ib),taual(i,k,ib)
- !10001 format(i3,i3,5f12.6)
- ! ssa - linear interpolation; extrapolation
- slope=(waer600(i,k+1,j)-waer400(i,k+1,j))/.2
- ssaal(i,kte-k,ib) = slope*(midbands(ib)-.6)+waer600(i,k+1,j) ! notice reversed variables
- if(ssaal(i,kte-k,ib).lt.0.4) ssaal(i,kte-k,ib)=0.4
- if(ssaal(i,kte-k,ib).ge.1.0) ssaal(i,kte-k,ib)=1.0
- ! g - linear interpolation;extrapolation
- slope=(gaer600(i,k+1,j)-gaer400(i,k+1,j))/.2
- asyal(i,kte-k,ib) = slope*(midbands(ib)-.6)+gaer600(i,k+1,j) ! notice reversed varaibles
- if(asyal(i,kte-k,ib).lt.0.5) asyal(i,kte-k,ib)=0.5
- if(asyal(i,kte-k,ib).ge.1.0) asyal(i,kte-k,ib)=1.0
- endif
- !jcb end
- end do
- end do
- end do
- !wig beg
- do ib = 1, 11
- do i = its,ite
- slope = 0. !use slope as a sum holder
- do k = kts-1,kte
- slope = slope + taual(i,k,ib)
- end do
- if( slope < 0. ) then
- write(msg,'("ERROR: Negative total optical depth of ",f8.2," at point i,j,ib=",3i5)') slope,i,j,ib
- call wrf_error_fatal(msg)
- else if( slope > 5. ) then
- call wrf_message("-------------------------")
- write(msg,'("WARNING: Large total optical depth of ",f8.2," at point i,j,ib=",3i5)') slope,i,j,ib
- call wrf_message(msg)
- call wrf_message("Diagnostics 1: k, tauaer300, tauaer400, tauaer600, tauaer999")
- do k=kts,kte
- write(msg,'(i4,4f8.2)') k, tauaer300(i,k,j), tauaer400(i,k,j), &
- tauaer600(i,k,j), tauaer999(i,k,j)
- call wrf_message(msg)
- end do
- call wrf_message("Diagnostics 2: k, gaer300, gaer400, gaer600, gaer999")
- do k=kts,kte
- write(msg,'(i4,4f8.2)') k, gaer300(i,k,j), gaer400(i,k,j), &
- gaer600(i,k,j), gaer999(i,k,j)
- call wrf_message(msg)
- end do
- call wrf_message("Diagnostics 3: k, waer300, waer400, waer600, waer999")
- do k=kts,kte
- write(msg,'(i4,4f8.2)') k, waer300(i,k,j), waer400(i,k,j), &
- waer600(i,k,j), waer999(i,k,j)
- call wrf_message(msg)
- end do
- call wrf_message("Diagnostics 4: k, ssaal, asyal, taual")
- do k=kts-1,kte
- write(msg,'(i4,3f8.2)') k, ssaal(i,k,ib), asyal(i,k,ib), taual(i,k,ib)
- call wrf_message(msg)
- end do
- call wrf_message("-------------------------")
- end if
- end do
- end do
- !wig end
- endif
- #endif
- !
- ! ... Initialize output arrays
- !
- do ib = 1, 2
- do k = kts-1, kte
- do i = its, ite
- taucld(i,k,ib) = 0.
- end do
- end do
- end do
- !
- do k = kts-1,kte+1
- do i = its,ite
- flx(i,k) = 0.
- flxd(i,k) = 0.
- end do
- end do
- !
- ! ... Solar zenith angle
- !
- do i = its,ite
- xt24 = mod(xtime + radfrq * 0.5, 1440.)
- tloctm = GMT + xt24 / 60. + XLONG(i,j) / 15.
- hrang = 15. * (tloctm - 12.) * degrad
- xxlat = XLAT(i,j) * degrad
- cosz(i) = sin(xxlat) * sin(declin) + &
- cos(xxlat) * cos(declin) * cos(hrang)
- rsuvbm(i) = ALB(i,j)
- rsuvdf(i) = ALB(i,j)
- rsirbm(i) = ALB(i,j)
- rsirdf(i) = ALB(i,j)
- end do
-
- call sorad (mix,1,1,mkx+1,p8w2D,t2D,sh2D,o3, &
- overcast,cldwater,cwc,taucld,reff,fcld2D,ict,icb,&
- taual,ssaal,asyal, &
- cosz,rsuvbm,rsuvdf,rsirbm,rsirdf, &
- flx,flxd)
- !
- ! ... Convert the units of flx and flc from fraction to w/m^2
- !
- do k = kts, kte
- do i = its, ite
- nk=kme-1-k+kms
- if(present(taucldc)) taucldc(i,nk,j)=taucld(i,k,2)
- if(present(taucldi)) taucldi(i,nk,j)=taucld(i,k,1)
- enddo
- enddo
-
- do k = kts, kte+1
- do i = its, ite
- if (cosz(i) .lt. thresh) then
- flx(i,k) = 0.
- else
- flx(i,k) = flx(i,k) * SOLCON * cosz(i)
- endif
- end do
- end do
- !
- ! ... Calculate heating rate (deg/sec)
- !
- fac = .01 * g / Cp
- do k = kts, kte
- do i = its, ite
- if (cosz(i) .gt. thresh) then
- TTEN2D(i,k) = - fac * (flx(i,k) - flx(i,k+1))/ &
- (p8w2d(i,k)-p8w2d(i,k+1))
- endif
- end do
- end do
- ! upward top of atmosphere
- do i = its, ite
- if (cosz(i) .le. thresh) then
- RSWTOA(i,j) = 0.
- else
- RSWTOA(i,j) = flx(i,kts) - flxd(i,kts) * SOLCON * cosz(i)
- endif
- end do
- !
- ! ... Absorbed part in surface energy budget
- !
- do i = its, ite
- if (cosz(i) .le. thresh) then
- GSW(i,j) = 0.
- else
- GSW(i,j) = (1. - rsuvbm(i)) * flxd(i,kte+1) * SOLCON * cosz(i)
- endif
- end do
- DO K=kts,kte
- NK=kme-1-K+kms
- DO I=its,ite
- ! FIX FROM GODDARD FOR NEGATIVE VALUES
- TTEN2D(I,NK)=MAX(TTEN2D(I,NK),0.)
- RTHRATEN(I,K,J)=RTHRATEN(I,K,J)+TTEN2D(I,NK)/pi3D(I,K,J)
- ENDDO
- ENDDO
- !
- ENDDO j_loop
- END SUBROUTINE GSFCSWRAD
- !********************* Version Solar-6 (May 8, 1997) *****************
- subroutine sorad (m,n,ndim,np,pl,ta,wa,oa, &
- overcast,cldwater,cwc,taucld,reff,fcld,ict,icb, &
- taual,ssaal,asyal, &
- cosz,rsuvbm,rsuvdf,rsirbm,rsirdf, &
- flx,flxd)
- !************************************************************************
- !
- ! Version Solar-6 (May 8, 1997)
- !
- ! New feature of this version is:
- ! (1) An option is added for scaling the cloud optical thickness. If
- ! the fractional cloud cover, fcld, in an atmospheric model is alway
- ! either 1 or 0 (i.e. partly cloudy sky is not allowed), it does
- ! not require the scaling of cloud optical thickness, and the
- ! option "overcast" can be set to .true. Computation is faster
- ! with this option than with overcast=.false.
- !
- !**********************************************************************
- !
- ! Version Solar-5 (April 1997)
- !
- ! New features of this version are:
- ! (1) Cloud optical properties can be computed from cloud water/ice
- ! amount and the effective particle size.
- ! (2) Aerosol optical properties are functions of height and band.
- ! (3) A maximum-random cloud overlapping approximation is applied.
- !
- !*********************************************************************
- !
- ! This routine computes solar fluxes due to the absoption by water
- ! vapor, ozone, co2, o2, clouds, and aerosols and due to the
- ! scattering by clouds, aerosols, and gases.
- !
- ! The solar spectrum is divided into one UV+visible band and three IR
- ! bands separated by the wavelength 0.7 micron. The UV+visible band
- ! is further divided into eight sub-bands.
- !
- ! This is a vectorized code. It computes fluxes simultaneously for
- ! (m x n) soundings, which is a subset of (m x ndim) soundings.
- ! In a global climate model, m and ndim correspond to the numbers of
- ! grid boxes in the zonal and meridional directions, respectively.
- !
- ! Ice and liquid cloud particles are allowed to co-exist in a layer.
- !
- ! There is an option of providing either cloud ice/water mixing ratio
- ! (cwc) or thickness (taucld). If the former is provided, set
- ! cldwater=.true., and taucld will be computed from cwc and reff as a
- ! function of spectra band. Otherwise, set cldwater=.false., and
- ! specify taucld, independent of spectral band.
- !
- ! If no information is available for reff, a default value of
- ! 10 micron for liquid water and 75 micron for ice can be used.
- ! For a clear layer, reff can be set to any values except zero.
- !
- ! The maximum-random assumption is applied for treating cloud
- ! overlapping.
- ! Clouds are grouped into high, middle, and low clouds separated by
- ! the level indices ict and icb. For detail, see subroutine cldscale.
- !
- ! In a high spatial-resolution atmospheric model, fractional cloud cover
- ! might be computed to be either 0 or 1. In such a case, scaling of the
- ! cloud optical thickness is not necessary, and the computation can be
- ! made faster by setting overcast=.true. The option overcast=.false.
- ! can be applied to any values of the fractional cloud cover, but the
- ! computation is slower.
- !
- ! Aerosol optical thickness, single-scattering albaedo, and asymmtry
- ! factor can be specified as functions of height and spectral band.
- !
- !----- Input parameters:
- ! units size
- ! number of soundings in zonal direction (m) n/d 1
- ! number of soundings in meridional direction (n) n/d 1
- ! maximum number of soundings in n/d 1
- ! meridional direction (ndim>=n)
- ! number of atmospheric layers (np) n/d 1
- ! level pressure (pl) mb m*ndim*(np+1)
- ! layer temperature (ta) k m*ndim*np
- ! layer specific humidity (wa) gm/gm m*ndim*np
- ! layer ozone concentration (oa) gm/gm m*ndim*np
- ! co2 mixing ratio by volumn (co2) pppv 1
- ! option for scaling cloud optical thickness n/d 1
- ! overcast="true" if scaling is NOT required
- ! overcast="fasle" if scaling is required
- ! option for cloud optical thickness n/d 1
- ! cldwater="true" if cwc is provided
- ! cldwater="false" if taucld is provided
- ! cloud water mixing ratio (cwc) gm/gm m*ndim*np*2
- ! index 1 for ice particles
- ! index 2 for liquid drops
- ! cloud optical thickness (taucld) n/d m*ndim*np*2
- ! index 1 for ice particles
- ! index 2 for liquid drops
- ! effective cloud-particle size (reff) micrometer m*ndim*np*2
- ! index 1 for ice particles
- ! index 2 for liquid drops
- ! cloud amount (fcld) fraction m*ndim*np
- ! level index separating high and middle n/d 1
- ! clouds (ict)
- ! level index separating middle and low n/d 1
- ! clouds (icb)
- ! aerosol optical thickness (taual) n/d m*ndim*np*11
- ! aerosol single-scattering albedo (ssaal) n/d m*ndim*np*11
- ! aerosol asymmetry factor (asyal) n/d m*ndim*np*11
- ! in the uv region :
- ! index 1 for the 0.175-0.225 micron band
- ! index 2 for the 0.225-0.245; 0.260-0.280 micron band
- ! index 3 for the 0.245-0.260 micron band
- ! index 4 for the 0.280-0.295 micron band
- ! index 5 for the 0.295-0.310 micron band
- ! index 6 for the 0.310-0.320 micron band
- ! index 7 for the 0.325-0.400 micron band
- ! in the par region :
- ! index 8 for the 0.400-0.700 micron band
- ! in the infrared region :
- ! index 9 for the 0.700-1.220 micron band
- ! index 10 for the 1.220-2.270 micron band
- ! index 11 for the 2.270-10.00 micron band
- ! cosine of solar zenith angle (cosz) n/d m*ndim
- ! uv+visible sfc albedo for beam radiation
- ! for wavelengths<0.7 micron (rsuvbm) fraction m*ndim
- ! uv+visible sfc albedo for diffuse radiation
- ! for wavelengths<0.7 micron (rsuvdf) fraction m*ndim
- ! ir sfc albedo for beam radiation
- ! for wavelengths>0.7 micron (rsirbm) fraction m*ndim
- ! ir sfc albedo for diffuse radiation (rsirdf) fraction m*ndim
- !
- !----- Output parameters
- !
- ! all-sky flux (downward minus upward) (flx) fraction m*ndim*(np+1)
- ! clear-sky flux (downward minus upward) (flc) fraction m*ndim*(np+1)
- ! all-sky direct downward uv (0.175-0.4 micron)
- ! flux at the surface (fdiruv) fraction m*ndim
- ! all-sky diffuse downward uv flux at
- ! the surface (fdifuv) fraction m*ndim
- ! all-sky direct downward par (0.4-0.7 micron)
- ! flux at the surface (fdirpar) fraction m*ndim
- ! all-sky diffuse downward par flux at
- ! the surface (fdifpar) fraction m*ndim
- ! all-sky direct downward ir (0.7-10 micron)
- ! flux at the surface (fdirir) fraction m*ndim
- ! all-sky diffuse downward ir flux at
- ! the surface (fdifir) fraction m*ndim
- !
- !----- Notes:
- !
- ! (1) The unit of "flux" is fraction of the incoming solar radiation
- ! at the top of the atmosphere. Therefore, fluxes should
- ! be equal to "flux" multiplied by the extra-terrestrial solar
- ! flux and the cosine of solar zenith angle.
- ! (2) pl(i,j,1) is the pressure at the top of the model, and
- ! pl(i,j,np+1) is the surface pressure.
- ! (3) the pressure levels ict and icb correspond approximately
- ! to 400 and 700 mb.
- ! (4) if overcast='true', the clear-sky flux, flc, is not computed.
- !
- !**************************************************************************
- implicit none
- !**************************************************************************
- !-----input parameters
- integer m,n,ndim,np
- integer ict(m,ndim),icb(m,ndim)
- real pl(m,ndim,np+1),ta(m,ndim,np),wa(m,ndim,np),oa(m,ndim,np)
- real cwc(m,ndim,np,2),taucld(m,ndim,np,2),reff(m,ndim,np,2), &
- fcld(m,ndim,np)
- real taual(m,ndim,np,11),ssaal(m,ndim,np,11),asyal(m,ndim,np,11)
- real cosz(m,ndim),rsuvbm(m,ndim),rsuvdf(m,ndim), &
- rsirbm(m,ndim),rsirdf(m,ndim)
- logical overcast,cldwater
- !-----output parameters
- real flx(m,ndim,np+1),flc(m,ndim,np+1)
- real flxu(m,ndim,np+1),flxd(m,ndim,np+1)
- real fdiruv (m,ndim),fdifuv (m,ndim)
- real fdirpar(m,ndim),fdifpar(m,ndim)
- real fdirir (m,ndim),fdifir (m,ndim)
- !-----temporary array
-
- integer i,j,k
- real cwp(m,n,np,2)
- real dp(m,n,np),wh(m,n,np),oh(m,n,np),scal(m,n,np)
- real swh(m,n,np+1),so2(m,n,np+1),df(m,n,np+1)
- real sdf(m,n),sclr(m,n),csm(m,n),x
-
- do j= 1, n
- do i= 1, m
- if (pl(i,j,1) .eq. 0.0) then
- pl(i,j,1)=1.0e-4
- endif
- enddo
- enddo
- do j= 1, n
- do i= 1, m
- swh(i,j,1)=0.
- so2(i,j,1)=0.
- !-----csm is the effective secant of the solar zenith angle
- ! see equation (12) of Lacis and Hansen (1974, JAS)
-
- csm(i,j)=35./sqrt(1224.*cosz(i,j)*cosz(i,j)+1.)
- enddo
- enddo
- do k= 1, np
- do j= 1, n
- do i= 1, m
- !-----compute layer thickness and pressure-scaling function.
- ! indices for the surface level and surface layer
- ! are np+1 and np, respectively.
-
- dp(i,j,k)=pl(i,j,k+1)-pl(i,j,k)
- scal(i,j,k)=dp(i,j,k)*(.5*(pl(i,j,k)+pl(i,j,k+1))/300.)**.8
-
- !-----compute scaled water vapor amount, unit is g/cm**2
- ! note: the sign prior to the constant 0.00135 was incorrectly
- ! set to negative in the previous version
- wh(i,j,k)=1.02*wa(i,j,k)*scal(i,j,k)* &
- (1.+0.00135*(ta(i,j,k)-240.)) +1.e-11
- swh(i,j,k+1)=swh(i,j,k)+wh(i,j,k)
- !-----compute ozone amount, unit is (cm-atm)stp
- ! the number 466.7 is a conversion factor from g/cm**2 to (cm-atm)stp
-
- oh(i,j,k)=1.02*oa(i,j,k)*dp(i,j,k)*466.7 +1.e-11
- !-----compute layer cloud water amount (gm/m**2)
- ! the index is 1 for ice crystals and 2 for liquid drops
- cwp(i,j,k,1)=1.02*10000.*cwc(i,j,k,1)*dp(i,j,k)
- cwp(i,j,k,2)=1.02*10000.*cwc(i,j,k,2)*dp(i,j,k)
- enddo
- enddo
- enddo
- !-----initialize fluxes for all-sky (flx), clear-sky (flc), and
- ! flux reduction (df)
- do k=1, np+1
- do j=1, n
- do i=1, m
- flx(i,j,k)=0.
- flc(i,j,k)=0.
- flxu(i,j,k)=0.
- flxd(i,j,k)=0.
- df(i,j,k)=0.
- enddo
- enddo
- enddo
- !-----compute solar uv and par fluxes
- call soluv (m,n,ndim,np,oh,dp,overcast,cldwater, &
- cwp,taucld,reff,ict,icb,fcld,cosz, &
- taual,ssaal,asyal,csm,rsuvbm,rsuvdf, &
- flx,flc,flxu,flxd,fdiruv,fdifuv,fdirpar,fdifpar)
- !-----compute and update solar ir fluxes
- call solir (m,n,ndim,np,wh,overcast,cldwater, &
- cwp,taucld,reff,ict,icb,fcld,cosz, &
- taual,ssaal,asyal,csm,rsirbm,rsirdf, &
- flx,flc,flxu,flxd,fdirir,fdifir)
- !-----compute scaled o2 amount, unit is (cm-atm)stp.
- do k= 1, np
- do j= 1, n
- do i= 1, m
- so2(i,j,k+1)=so2(i,j,k)+165.22*scal(i,j,k)
- enddo
- enddo
- enddo
- !-----compute flux reduction due to oxygen following
- ! chou (J. climate, 1990). The fraction 0.0287 is the
- ! extraterrestrial solar flux in the o2 bands.
- do k= 2, np+1
- do j= 1, n
- do i= 1, m
- x=so2(i,j,k)*csm(i,j)
- df(i,j,k)=df(i,j,k)+0.0287*(1.-exp(-0.00027*sqrt(x)))
- enddo
- enddo
- enddo
- !-----compute scaled co2 amounts. unit is (cm-atm)stp.
- do k= 1, np
- do j= 1, n
- do i= 1, m
- so2(i,j,k+1)=so2(i,j,k)+co2*789.*scal(i,j,k)+1.e-11
- enddo
- enddo
- enddo
- !-----compute and update flux reduction due to co2 following
- ! chou (J. Climate, 1990)
- call flxco2(m,n,np,so2,swh,csm,df)
- !-----adjust for the effect of o2 cnd co2 on clear-sky fluxes.
- do k= 2, np+1
- do j= 1, n
- do i= 1, m
- flc(i,j,k)=flc(i,j,k)-df(i,j,k)
- enddo
- enddo
- enddo
- !-----adjust for the all-sky fluxes due to o2 and co2. It is
- ! assumed that o2 and co2 have no effects on solar radiation
- ! below clouds.
- do j=1,n
- do i=1,m
- sdf(i,j)=0.0
- sclr(i,j)=1.0
- enddo
- enddo
- do k=1,np
- do j=1,n
- do i=1,m
- !-----sclr is the fraction of clear sky.
- ! sdf is the flux reduction below clouds.
- if(fcld(i,j,k).gt.0.01) then
- sdf(i,j)=sdf(i,j)+df(i,j,k)*sclr(i,j)*fcld(i,j,k)
- sclr(i,j)=sclr(i,j)*(1.-fcld(i,j,k))
- endif
- flx(i,j,k+1)=flx(i,j,k+1)-sdf(i,j)-df(i,j,k+1)*sclr(i,j)
- flxu(i,j,k+1)=flxu(i,j,k+1)-sdf(i,j)-df(i,j,k+1)*sclr(i,j)
- flxd(i,j,k+1)=flxd(i,j,k+1)-sdf(i,j)-df(i,j,k+1)*sclr(i,j) ! SG: same as flux????
- enddo
- enddo
- enddo
- !-----adjustment for the direct downward ir flux.
- do j= 1, n
- do i= 1, m
- flc(i,j,np+1)=flc(i,j,np+1)+df(i,j,np+1)*rsirbm(i,j)
- flx(i,j,np+1)=flx(i,j,np+1)+(sdf(i,j)+ &
- df(i,j,np+1)*sclr(i,j))*rsirbm(i,j)
- flxu(i,j,np+1)=flxu(i,j,np+1)+(sdf(i,j)+ &
- df(i,j,np+1)*sclr(i,j))*rsirbm(i,j)
- flxd(i,j,np+1)=flxd(i,j,np+1)+(sdf(i,j)+ &
- df(i,j,np+1)*sclr(i,j))*rsirbm(i,j)
- fdirir(i,j)=fdirir(i,j)-(sdf(i,j)+df(i,j,np+1)*sclr(i,j))
- enddo
- enddo
- end subroutine sorad
- !************************************************************************
- subroutine soluv (m,n,ndim,np,oh,dp,overcast,cldwater, &
- cwp,taucld,reff,ict,icb,fcld,cosz, &
- taual,ssaal,asyal,csm,rsuvbm,rsuvdf, &
- flx,flc,flxu,flxd,fdiruv,fdifuv,fdirpar,fdifpar)
- !************************************************************************
- ! compute solar fluxes in the uv+par region. the spectrum is
- ! grouped into 8 bands:
- !
- ! Band Micrometer
- !
- ! UV-C 1. .175 - .225
- ! 2. .225 - .245
- ! .260 - .280
- ! 3. .245 - .260
- !
- ! UV-B 4. .280 - .295
- ! 5. .295 - .310
- ! 6. .310 - .320
- !
- ! UV-A 7. .320 - .400
- !
- ! PAR 8. .400 - .700
- !
- !----- Input parameters: units size
- !
- ! number of soundings in zonal direction (m) n/d 1
- ! number of soundings in meridional direction (n) n/d 1
- ! maximum number of soundings in n/d 1
- ! meridional direction (ndim)
- ! number of atmospheric layers (np) n/d 1
- ! layer ozone content (oh) (cm-atm)stp m*n*np
- ! layer pressure thickness (dp) mb m*n*np
- ! option for scaling cloud optical thickness n/d 1
- ! overcast="true" if scaling is NOT required
- ! overcast="fasle" if scaling is required
- ! input option for cloud optical thickness n/d 1
- ! cldwater="true" if taucld is provided
- ! cldwater="false" if cwp is provided
- ! cloud water amount (cwp) gm/m**2 m*n*np*2
- ! index 1 for ice particles
- ! index 2 for liquid drops
- ! cloud optical thickness (taucld) n/d m*ndim*np*2
- ! index 1 for ice paticles
- ! index 2 for liquid particles
- ! effective cloud-particle size (reff) micrometer m*ndim*np*2
- ! index 1 for ice paticles
- ! index 2 for liquid particles
- ! level indiex separating high and n/d m*n
- ! middle clouds (ict)
- ! level indiex separating middle and n/d m*n
- ! low clouds (icb)
- ! cloud amount (fcld) fraction m*ndim*np
- ! cosine of solar zenith angle (cosz) n/d m*ndim
- ! aerosol optical thickness (taual) n/d m*ndim*np*11
- ! aerosol single-scattering albedo (ssaal) n/d m*ndim*np*11
- ! aerosol asymmetry factor (asyal) n/d m*ndim*np*11
- ! cosecant of the solar zenith angle (csm) n/d m*n
- ! uv+par surface albedo for beam fraction m*ndim
- ! radiation (rsuvbm)
- ! uv+par surface albedo for diffuse fraction m*ndim
- ! radiation (rsuvdf)
- !
- !---- temporary array
- !
- ! scaled cloud optical thickness n/d m*n*np
- ! for beam radiation (tauclb)
- ! scaled cloud optical thickness n/d m*n*np
- ! for diffuse radiation (tauclf)
- !
- !----- output (updated) parameters:
- !
- ! all-sky net downward flux (flx) fraction m*ndim*(np+1)
- ! cl…
Large files files are truncated, but you can click here to view the full file