/board/evb64260/u-boot.lds

https://gitlab.com/veo-labs/u-boot · LD Script · 86 lines · 63 code · 12 blank · 11 comment · 0 complexity · 9452b85c60b48acb58ef014c87561f21 MD5 · raw file

  1. /*
  2. * (C) Copyright 2001
  3. * Josh Huber <huber@mclx.com>, Mission Critical Linux, Inc.
  4. *
  5. * SPDX-License-Identifier: GPL-2.0+
  6. */
  7. /*
  8. * u-boot.lds - linker script for U-Boot on the Galileo Eval Board.
  9. */
  10. OUTPUT_ARCH(powerpc)
  11. SECTIONS
  12. {
  13. /* Read-only sections, merged into text segment: */
  14. .text :
  15. {
  16. arch/powerpc/cpu/74xx_7xx/start.o (.text*)
  17. *(.text*)
  18. . = DEFINED(env_offset) ? env_offset : .;
  19. common/env_embedded.o (.ppcenv*)
  20. }
  21. _etext = .;
  22. PROVIDE (etext = .);
  23. .rodata :
  24. {
  25. *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
  26. }
  27. /* Read-write section, merged into data segment: */
  28. . = (. + 0x00FF) & 0xFFFFFF00;
  29. _erotext = .;
  30. PROVIDE (erotext = .);
  31. .reloc :
  32. {
  33. _GOT2_TABLE_ = .;
  34. KEEP(*(.got2))
  35. KEEP(*(.got))
  36. PROVIDE(_GLOBAL_OFFSET_TABLE_ = . + 4);
  37. _FIXUP_TABLE_ = .;
  38. KEEP(*(.fixup))
  39. }
  40. __got2_entries = ((_GLOBAL_OFFSET_TABLE_ - _GOT2_TABLE_) >> 2) - 1;
  41. __fixup_entries = (. - _FIXUP_TABLE_)>>2;
  42. .data :
  43. {
  44. *(.data*)
  45. *(.sdata*)
  46. }
  47. _edata = .;
  48. PROVIDE (edata = .);
  49. . = .;
  50. . = ALIGN(4);
  51. .u_boot_list : {
  52. KEEP(*(SORT(.u_boot_list*)));
  53. }
  54. . = .;
  55. __start___ex_table = .;
  56. __ex_table : { *(__ex_table) }
  57. __stop___ex_table = .;
  58. . = ALIGN(256);
  59. __init_begin = .;
  60. .text.init : { *(.text.init) }
  61. .data.init : { *(.data.init) }
  62. . = ALIGN(256);
  63. __init_end = .;
  64. __bss_start = .;
  65. .bss (NOLOAD) :
  66. {
  67. *(.bss*)
  68. *(.sbss*)
  69. *(COMMON)
  70. . = ALIGN(4);
  71. }
  72. __bss_end = . ;
  73. PROVIDE (end = .);
  74. }