PageRenderTime 73ms CodeModel.GetById 2ms app.highlight 66ms RepoModel.GetById 1ms app.codeStats 1ms

/IronPython_Main/Runtime/Tests/LinqDlrTests/testenv/perl/lib/Cwd.pm

#
Perl | 456 lines | 368 code | 51 blank | 37 comment | 58 complexity | a79ea65a17b9494262dbb35fa32172a8 MD5 | raw file
  1package Cwd;
  2require 5.000;
  3
  4=head1 NAME
  5
  6Cwd - get pathname of current working directory
  7
  8=head1 SYNOPSIS
  9
 10    use Cwd;
 11    $dir = cwd;
 12
 13    use Cwd;
 14    $dir = getcwd;
 15
 16    use Cwd;
 17    $dir = fastcwd;
 18
 19    use Cwd;
 20    $dir = fastgetcwd;
 21
 22    use Cwd 'chdir';
 23    chdir "/tmp";
 24    print $ENV{'PWD'};
 25
 26    use Cwd 'abs_path';	    # aka realpath()
 27    print abs_path($ENV{'PWD'});
 28
 29    use Cwd 'fast_abs_path';
 30    print fast_abs_path($ENV{'PWD'});
 31
 32=head1 DESCRIPTION
 33
 34This module provides functions for determining the pathname of the
 35current working directory.  By default, it exports the functions
 36cwd(), getcwd(), fastcwd(), and fastgetcwd() into the caller's
 37namespace.  Each of these functions are called without arguments and
 38return the absolute path of the current working directory.  It is
 39recommended that cwd (or another *cwd() function) be used in I<all>
 40code to ensure portability.
 41
 42The cwd() is the most natural and safe form for the current
 43architecture. For most systems it is identical to `pwd` (but without
 44the trailing line terminator).
 45
 46The getcwd() function re-implements the getcwd(3) (or getwd(3)) functions
 47in Perl.
 48
 49The fastcwd() function looks the same as getcwd(), but runs faster.
 50It's also more dangerous because it might conceivably chdir() you out
 51of a directory that it can't chdir() you back into.  If fastcwd
 52encounters a problem it will return undef but will probably leave you
 53in a different directory.  For a measure of extra security, if
 54everything appears to have worked, the fastcwd() function will check
 55that it leaves you in the same directory that it started in. If it has
 56changed it will C<die> with the message "Unstable directory path,
 57current directory changed unexpectedly". That should never happen.
 58
 59The fastgetcwd() function is provided as a synonym for cwd().
 60
 61The abs_path() function takes a single argument and returns the
 62absolute pathname for that argument.  It uses the same algorithm as
 63getcwd().  (Actually, getcwd() is abs_path("."))  Symbolic links and
 64relative-path components ("." and "..") are resolved to return the
 65canonical pathname, just like realpath(3).  This function is also
 66callable as realpath().
 67
 68The fast_abs_path() function looks the same as abs_path() but runs
 69faster and, like fastcwd(), is more dangerous.
 70
 71If you ask to override your chdir() built-in function, then your PWD
 72environment variable will be kept up to date.  (See
 73L<perlsub/Overriding Builtin Functions>.) Note that it will only be
 74kept up to date if all packages which use chdir import it from Cwd.
 75
 76=cut
 77
 78use strict;
 79
 80use Carp;
 81
 82our $VERSION = '2.04';
 83
 84use base qw/ Exporter /;
 85our @EXPORT = qw(cwd getcwd fastcwd fastgetcwd);
 86our @EXPORT_OK = qw(chdir abs_path fast_abs_path realpath fast_realpath);
 87
 88
 89# The 'natural and safe form' for UNIX (pwd may be setuid root)
 90
 91sub _backtick_pwd {
 92    my $cwd = `pwd`;
 93    # `pwd` may fail e.g. if the disk is full
 94    chomp($cwd) if defined $cwd;
 95    $cwd;
 96}
 97
 98# Since some ports may predefine cwd internally (e.g., NT)
 99# we take care not to override an existing definition for cwd().
100
101unless(defined &cwd) {
102    # The pwd command is not available in some chroot(2)'ed environments
103    if($^O eq 'MacOS' || grep { -x "$_/pwd" } split(':', $ENV{PATH})) {
104	*cwd = \&_backtick_pwd;
105    }
106    else {
107	*cwd = \&getcwd;
108    }
109}
110
111# set a reasonable (and very safe) default for fastgetcwd, in case it
112# isn't redefined later (20001212 rspier)
113*fastgetcwd = \&cwd;
114
115# By Brandon S. Allbery
116#
117# Usage: $cwd = getcwd();
118
119sub getcwd
120{
121    abs_path('.');
122}
123
124# By John Bazik
125#
126# Usage: $cwd = &fastcwd;
127#
128# This is a faster version of getcwd.  It's also more dangerous because
129# you might chdir out of a directory that you can't chdir back into.
130    
131sub fastcwd {
132    my($odev, $oino, $cdev, $cino, $tdev, $tino);
133    my(@path, $path);
134    local(*DIR);
135
136    my($orig_cdev, $orig_cino) = stat('.');
137    ($cdev, $cino) = ($orig_cdev, $orig_cino);
138    for (;;) {
139	my $direntry;
140	($odev, $oino) = ($cdev, $cino);
141	CORE::chdir('..') || return undef;
142	($cdev, $cino) = stat('.');
143	last if $odev == $cdev && $oino == $cino;
144	opendir(DIR, '.') || return undef;
145	for (;;) {
146	    $direntry = readdir(DIR);
147	    last unless defined $direntry;
148	    next if $direntry eq '.';
149	    next if $direntry eq '..';
150
151	    ($tdev, $tino) = lstat($direntry);
152	    last unless $tdev != $odev || $tino != $oino;
153	}
154	closedir(DIR);
155	return undef unless defined $direntry; # should never happen
156	unshift(@path, $direntry);
157    }
158    $path = '/' . join('/', @path);
159    if ($^O eq 'apollo') { $path = "/".$path; }
160    # At this point $path may be tainted (if tainting) and chdir would fail.
161    # To be more useful we untaint it then check that we landed where we started.
162    $path = $1 if $path =~ /^(.*)\z/s;	# untaint
163    CORE::chdir($path) || return undef;
164    ($cdev, $cino) = stat('.');
165    die "Unstable directory path, current directory changed unexpectedly"
166	if $cdev != $orig_cdev || $cino != $orig_cino;
167    $path;
168}
169
170
171# Keeps track of current working directory in PWD environment var
172# Usage:
173#	use Cwd 'chdir';
174#	chdir $newdir;
175
176my $chdir_init = 0;
177
178sub chdir_init {
179    if ($ENV{'PWD'} and $^O ne 'os2' and $^O ne 'dos' and $^O ne 'MSWin32') {
180	my($dd,$di) = stat('.');
181	my($pd,$pi) = stat($ENV{'PWD'});
182	if (!defined $dd or !defined $pd or $di != $pi or $dd != $pd) {
183	    $ENV{'PWD'} = cwd();
184	}
185    }
186    else {
187	my $wd = cwd();
188	$wd = Win32::GetFullPathName($wd) if $^O eq 'MSWin32';
189	$ENV{'PWD'} = $wd;
190    }
191    # Strip an automounter prefix (where /tmp_mnt/foo/bar == /foo/bar)
192    if ($^O ne 'MSWin32' and $ENV{'PWD'} =~ m|(/[^/]+(/[^/]+/[^/]+))(.*)|s) {
193	my($pd,$pi) = stat($2);
194	my($dd,$di) = stat($1);
195	if (defined $pd and defined $dd and $di == $pi and $dd == $pd) {
196	    $ENV{'PWD'}="$2$3";
197	}
198    }
199    $chdir_init = 1;
200}
201
202sub chdir {
203    my $newdir = @_ ? shift : '';	# allow for no arg (chdir to HOME dir)
204    $newdir =~ s|///*|/|g unless $^O eq 'MSWin32';
205    chdir_init() unless $chdir_init;
206    my $newpwd;
207    if ($^O eq 'MSWin32') {
208	# get the full path name *before* the chdir()
209	$newpwd = Win32::GetFullPathName($newdir);
210    }
211
212    return 0 unless CORE::chdir $newdir;
213
214    if ($^O eq 'VMS') {
215	return $ENV{'PWD'} = $ENV{'DEFAULT'}
216    }
217    elsif ($^O eq 'MacOS') {
218	return $ENV{'PWD'} = cwd();
219    }
220    elsif ($^O eq 'MSWin32') {
221	$ENV{'PWD'} = $newpwd;
222	return 1;
223    }
224
225    if ($newdir =~ m#^/#s) {
226	$ENV{'PWD'} = $newdir;
227    } else {
228	my @curdir = split(m#/#,$ENV{'PWD'});
229	@curdir = ('') unless @curdir;
230	my $component;
231	foreach $component (split(m#/#, $newdir)) {
232	    next if $component eq '.';
233	    pop(@curdir),next if $component eq '..';
234	    push(@curdir,$component);
235	}
236	$ENV{'PWD'} = join('/',@curdir) || '/';
237    }
238    1;
239}
240
241# Taken from Cwd.pm It is really getcwd with an optional
242# parameter instead of '.'
243#
244
245sub abs_path
246{
247    my $start = @_ ? shift : '.';
248    my($dotdots, $cwd, @pst, @cst, $dir, @tst);
249
250    unless (@cst = stat( $start ))
251    {
252	carp "stat($start): $!";
253	return '';
254    }
255    $cwd = '';
256    $dotdots = $start;
257    do
258    {
259	$dotdots .= '/..';
260	@pst = @cst;
261	unless (opendir(PARENT, $dotdots))
262	{
263	    carp "opendir($dotdots): $!";
264	    return '';
265	}
266	unless (@cst = stat($dotdots))
267	{
268	    carp "stat($dotdots): $!";
269	    closedir(PARENT);
270	    return '';
271	}
272	if ($pst[0] == $cst[0] && $pst[1] == $cst[1])
273	{
274	    $dir = undef;
275	}
276	else
277	{
278	    do
279	    {
280		unless (defined ($dir = readdir(PARENT)))
281	        {
282		    carp "readdir($dotdots): $!";
283		    closedir(PARENT);
284		    return '';
285		}
286		$tst[0] = $pst[0]+1 unless (@tst = lstat("$dotdots/$dir"))
287	    }
288	    while ($dir eq '.' || $dir eq '..' || $tst[0] != $pst[0] ||
289		   $tst[1] != $pst[1]);
290	}
291	$cwd = (defined $dir ? "$dir" : "" ) . "/$cwd" ;
292	closedir(PARENT);
293    } while (defined $dir);
294    chop($cwd) unless $cwd eq '/'; # drop the trailing /
295    $cwd;
296}
297
298# added function alias for those of us more
299# used to the libc function.  --tchrist 27-Jan-00
300*realpath = \&abs_path;
301
302sub fast_abs_path {
303    my $cwd = getcwd();
304    my $path = @_ ? shift : '.';
305    CORE::chdir($path) || croak "Cannot chdir to $path:$!";
306    my $realpath = getcwd();
307    CORE::chdir($cwd)  || croak "Cannot chdir back to $cwd:$!";
308    $realpath;
309}
310
311# added function alias to follow principle of least surprise
312# based on previous aliasing.  --tchrist 27-Jan-00
313*fast_realpath = \&fast_abs_path;
314
315
316# --- PORTING SECTION ---
317
318# VMS: $ENV{'DEFAULT'} points to default directory at all times
319# 06-Mar-1996  Charles Bailey  bailey@newman.upenn.edu
320# Note: Use of Cwd::chdir() causes the logical name PWD to be defined
321#   in the process logical name table as the default device and directory
322#   seen by Perl. This may not be the same as the default device
323#   and directory seen by DCL after Perl exits, since the effects
324#   the CRTL chdir() function persist only until Perl exits.
325
326sub _vms_cwd {
327    return $ENV{'DEFAULT'};
328}
329
330sub _vms_abs_path {
331    return $ENV{'DEFAULT'} unless @_;
332    my $path = VMS::Filespec::pathify($_[0]);
333    croak("Invalid path name $_[0]") unless defined $path;
334    return VMS::Filespec::rmsexpand($path);
335}
336
337sub _os2_cwd {
338    $ENV{'PWD'} = `cmd /c cd`;
339    chop $ENV{'PWD'};
340    $ENV{'PWD'} =~ s:\\:/:g ;
341    return $ENV{'PWD'};
342}
343
344sub _win32_cwd {
345    $ENV{'PWD'} = Win32::GetCwd();
346    $ENV{'PWD'} =~ s:\\:/:g ;
347    return $ENV{'PWD'};
348}
349
350*_NT_cwd = \&_win32_cwd if (!defined &_NT_cwd && 
351                            defined &Win32::GetCwd);
352
353*_NT_cwd = \&_os2_cwd unless defined &_NT_cwd;
354
355sub _dos_cwd {
356    if (!defined &Dos::GetCwd) {
357        $ENV{'PWD'} = `command /c cd`;
358        chop $ENV{'PWD'};
359        $ENV{'PWD'} =~ s:\\:/:g ;
360    } else {
361        $ENV{'PWD'} = Dos::GetCwd();
362    }
363    return $ENV{'PWD'};
364}
365
366sub _qnx_cwd {
367    $ENV{'PWD'} = `/usr/bin/fullpath -t`;
368    chop $ENV{'PWD'};
369    return $ENV{'PWD'};
370}
371
372sub _qnx_abs_path {
373    my $path = @_ ? shift : '.';
374    my $realpath=`/usr/bin/fullpath -t $path`;
375    chop $realpath;
376    return $realpath;
377}
378
379sub _epoc_cwd {
380    $ENV{'PWD'} = EPOC::getcwd();
381    return $ENV{'PWD'};
382}
383
384{
385    no warnings;	# assignments trigger 'subroutine redefined' warning
386
387    if ($^O eq 'VMS') {
388        *cwd		= \&_vms_cwd;
389        *getcwd		= \&_vms_cwd;
390        *fastcwd	= \&_vms_cwd;
391        *fastgetcwd	= \&_vms_cwd;
392        *abs_path	= \&_vms_abs_path;
393        *fast_abs_path	= \&_vms_abs_path;
394    }
395    elsif ($^O eq 'NT' or $^O eq 'MSWin32') {
396        # We assume that &_NT_cwd is defined as an XSUB or in the core.
397        *cwd		= \&_NT_cwd;
398        *getcwd		= \&_NT_cwd;
399        *fastcwd	= \&_NT_cwd;
400        *fastgetcwd	= \&_NT_cwd;
401        *abs_path	= \&fast_abs_path;
402    }
403    elsif ($^O eq 'os2') {
404        # sys_cwd may keep the builtin command
405        *cwd		= defined &sys_cwd ? \&sys_cwd : \&_os2_cwd;
406        *getcwd		= \&cwd;
407        *fastgetcwd	= \&cwd;
408        *fastcwd	= \&cwd;
409        *abs_path	= \&fast_abs_path;
410    }
411    elsif ($^O eq 'dos') {
412        *cwd		= \&_dos_cwd;
413        *getcwd		= \&_dos_cwd;
414        *fastgetcwd	= \&_dos_cwd;
415        *fastcwd	= \&_dos_cwd;
416        *abs_path	= \&fast_abs_path;
417    }
418    elsif ($^O eq 'qnx') {
419        *cwd		= \&_qnx_cwd;
420        *getcwd		= \&_qnx_cwd;
421        *fastgetcwd	= \&_qnx_cwd;
422        *fastcwd	= \&_qnx_cwd;
423        *abs_path	= \&_qnx_abs_path;
424        *fast_abs_path	= \&_qnx_abs_path;
425    }
426    elsif ($^O eq 'cygwin') {
427        *getcwd	= \&cwd;
428        *fastgetcwd	= \&cwd;
429        *fastcwd	= \&cwd;
430        *abs_path	= \&fast_abs_path;
431    }
432    elsif ($^O eq 'epoc') {
433        *cwd            = \&_epoc_cwd;
434        *getcwd	        = \&_epoc_cwd;
435        *fastgetcwd	= \&_epoc_cwd;
436        *fastcwd	= \&_epoc_cwd;
437        *abs_path	= \&fast_abs_path;
438    }
439    elsif ($^O eq 'MacOS') {
440    	*getcwd     = \&cwd;
441    	*fastgetcwd = \&cwd;
442    	*fastcwd    = \&cwd;
443    	*abs_path   = \&fast_abs_path;
444    }
445}
446
447# package main; eval join('',<DATA>) || die $@;	# quick test
448
4491;
450
451__END__
452BEGIN { import Cwd qw(:DEFAULT chdir); }
453print join("\n", cwd, getcwd, fastcwd, "");
454chdir('..');
455print join("\n", cwd, getcwd, fastcwd, "");
456print "$ENV{PWD}\n";