PageRenderTime 15ms CodeModel.GetById 8ms app.highlight 4ms RepoModel.GetById 2ms app.codeStats 0ms

/arch/powerpc/boot/zImage.ps3.lds.S

https://github.com/aicjofs/android_kernel_lge_v500_20d_f2fs
Assembly | 50 lines | 45 code | 5 blank | 0 comment | 0 complexity | 3e92f3c784e0c703c179496d60b1349d MD5 | raw file
 1OUTPUT_ARCH(powerpc:common)
 2ENTRY(_zimage_start)
 3EXTERN(_zimage_start)
 4SECTIONS
 5{
 6  _vmlinux_start =  .;
 7  .kernel:vmlinux.bin : { *(.kernel:vmlinux.bin) }
 8  _vmlinux_end =  .;
 9
10  . = ALIGN(4096);
11  _dtb_start = .;
12  .kernel:dtb : { *(.kernel:dtb) }
13  _dtb_end = .;
14
15  . = ALIGN(4096);
16  _initrd_start =  .;
17  .kernel:initrd : { *(.kernel:initrd) }
18  _initrd_end =  .;
19
20  _start = .;
21  .text      :
22  {
23    *(.text)
24    *(.fixup)
25  }
26  _etext = .;
27  . = ALIGN(4096);
28  .data    :
29  {
30    *(.rodata*)
31    *(.data*)
32    *(.sdata*)
33    __got2_start = .;
34    *(.got2)
35    __got2_end = .;
36  }
37
38  . = ALIGN(4096);
39  _edata  =  .;
40
41  . = ALIGN(4096);
42  __bss_start = .;
43  .bss       :
44  {
45   *(.sbss)
46   *(.bss)
47  }
48  . = ALIGN(4096);
49  _end = . ;
50}