PageRenderTime 52ms CodeModel.GetById 24ms RepoModel.GetById 0ms app.codeStats 0ms

/activemq-cpp-library-3.4.1/m4/ac_doxygen.m4

#
m4 | 324 lines | 172 code | 31 blank | 121 comment | 0 complexity | b151c1ed786bbc162067efac37fd7fdc MD5 | raw file
Possible License(s): Apache-2.0
  1. #
  2. # Copyright 2007 Oren Ben-Kiki
  3. #
  4. # Licensed under the Apache License, Version 2.0 (the "License");
  5. # you may not use this file except in compliance with the License.
  6. # You may obtain a copy of the License at
  7. #
  8. # http://www.apache.org/licenses/LICENSE-2.0
  9. #
  10. # Unless required by applicable law or agreed to in writing,
  11. # software distributed under the License is distributed on an "AS IS" BASIS,
  12. # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or
  13. # implied. See the License for the specific language governing
  14. # permissions and limitations under the License.
  15. #
  16. # Generate automatic documentation using Doxygen. Works in concert with the
  17. # aminclude.m4 file and a compatible doxygen configuration file. Defines the
  18. # following public macros:
  19. #
  20. # DX_???_FEATURE(ON|OFF) - control the default setting fo a Doxygen feature.
  21. # Supported features are 'DOXYGEN' itself, 'DOT' for generating graphics,
  22. # 'HTML' for plain HTML, 'CHM' for compressed HTML help (for MS users), 'CHI'
  23. # for generating a seperate .chi file by the .chm file, and 'MAN', 'RTF',
  24. # 'XML', 'PDF' and 'PS' for the appropriate output formats. The environment
  25. # variable DOXYGEN_PAPER_SIZE may be specified to override the default 'a4wide'
  26. # paper size.
  27. #
  28. # By default, HTML, PDF and PS documentation is generated as this seems to be
  29. # the most popular and portable combination. MAN pages created by Doxygen are
  30. # usually problematic, though by picking an appropriate subset and doing some
  31. # massaging they might be better than nothing. CHM and RTF are specific for MS
  32. # (note that you can't generate both HTML and CHM at the same time). The XML is
  33. # rather useless unless you apply specialized post-processing to it.
  34. #
  35. # The macro mainly controls the default state of the feature. The use can
  36. # override the default by specifying --enable or --disable. The macros ensure
  37. # that contradictory flags are not given (e.g., --enable-doxygen-html and
  38. # --enable-doxygen-chm, --enable-doxygen-anything with --disable-doxygen, etc.)
  39. # Finally, each feature will be automatically disabled (with a warning) if the
  40. # required programs are missing.
  41. #
  42. # Once all the feature defaults have been specified, call DX_INIT_DOXYGEN with
  43. # the following parameters: a one-word name for the project for use as a
  44. # filename base etc., an optional configuration file name (the default is
  45. # 'Doxyfile', the same as Doxygen's default), and an optional output directory
  46. # name (the default is 'doxygen-doc').
  47. ## ----------##
  48. ## Defaults. ##
  49. ## ----------##
  50. DX_ENV=""
  51. AC_DEFUN([DX_FEATURE_doc], ON)
  52. AC_DEFUN([DX_FEATURE_dot], ON)
  53. AC_DEFUN([DX_FEATURE_man], OFF)
  54. AC_DEFUN([DX_FEATURE_html], ON)
  55. AC_DEFUN([DX_FEATURE_chm], OFF)
  56. AC_DEFUN([DX_FEATURE_chi], OFF)
  57. AC_DEFUN([DX_FEATURE_rtf], OFF)
  58. AC_DEFUN([DX_FEATURE_xml], OFF)
  59. AC_DEFUN([DX_FEATURE_pdf], ON)
  60. AC_DEFUN([DX_FEATURE_ps], ON)
  61. ## --------------- ##
  62. ## Private macros. ##
  63. ## --------------- ##
  64. # DX_ENV_APPEND(VARIABLE, VALUE)
  65. # ------------------------------
  66. # Append VARIABLE="VALUE" to DX_ENV for invoking doxygen.
  67. AC_DEFUN([DX_ENV_APPEND], [AC_SUBST([DX_ENV], ["$DX_ENV $1='$2'"])])
  68. # DX_DIRNAME_EXPR
  69. # ---------------
  70. # Expand into a shell expression prints the directory part of a path.
  71. AC_DEFUN([DX_DIRNAME_EXPR],
  72. [[expr ".$1" : '\(\.\)[^/]*$' \| "x$1" : 'x\(.*\)/[^/]*$']])
  73. # DX_IF_FEATURE(FEATURE, IF-ON, IF-OFF)
  74. # -------------------------------------
  75. # Expands according to the M4 (static) status of the feature.
  76. AC_DEFUN([DX_IF_FEATURE], [ifelse(DX_FEATURE_$1, ON, [$2], [$3])])
  77. # DX_REQUIRE_PROG(VARIABLE, PROGRAM)
  78. # ----------------------------------
  79. # Require the specified program to be found for the DX_CURRENT_FEATURE to work.
  80. AC_DEFUN([DX_REQUIRE_PROG], [
  81. AC_PATH_TOOL([$1], [$2])
  82. if test "$DX_FLAG_[]DX_CURRENT_FEATURE$$1" = 1; then
  83. AC_MSG_WARN([$2 not found - will not DX_CURRENT_DESCRIPTION])
  84. AC_SUBST([DX_FLAG_]DX_CURRENT_FEATURE, 0)
  85. fi
  86. ])
  87. # DX_TEST_FEATURE(FEATURE)
  88. # ------------------------
  89. # Expand to a shell expression testing whether the feature is active.
  90. AC_DEFUN([DX_TEST_FEATURE], [test "$DX_FLAG_$1" = 1])
  91. # DX_CHECK_DEPEND(REQUIRED_FEATURE, REQUIRED_STATE)
  92. # -------------------------------------------------
  93. # Verify that a required features has the right state before trying to turn on
  94. # the DX_CURRENT_FEATURE.
  95. AC_DEFUN([DX_CHECK_DEPEND], [
  96. test "$DX_FLAG_$1" = "$2" \
  97. || AC_MSG_ERROR([doxygen-DX_CURRENT_FEATURE ifelse([$2], 1,
  98. requires, contradicts) doxygen-DX_CURRENT_FEATURE])
  99. ])
  100. # DX_CLEAR_DEPEND(FEATURE, REQUIRED_FEATURE, REQUIRED_STATE)
  101. # ----------------------------------------------------------
  102. # Turn off the DX_CURRENT_FEATURE if the required feature is off.
  103. AC_DEFUN([DX_CLEAR_DEPEND], [
  104. test "$DX_FLAG_$1" = "$2" || AC_SUBST([DX_FLAG_]DX_CURRENT_FEATURE, 0)
  105. ])
  106. # DX_FEATURE_ARG(FEATURE, DESCRIPTION,
  107. # CHECK_DEPEND, CLEAR_DEPEND,
  108. # REQUIRE, DO-IF-ON, DO-IF-OFF)
  109. # --------------------------------------------
  110. # Parse the command-line option controlling a feature. CHECK_DEPEND is called
  111. # if the user explicitly turns the feature on (and invokes DX_CHECK_DEPEND),
  112. # otherwise CLEAR_DEPEND is called to turn off the default state if a required
  113. # feature is disabled (using DX_CLEAR_DEPEND). REQUIRE performs additional
  114. # requirement tests (DX_REQUIRE_PROG). Finally, an automake flag is set and
  115. # DO-IF-ON or DO-IF-OFF are called according to the final state of the feature.
  116. AC_DEFUN([DX_ARG_ABLE], [
  117. AC_DEFUN([DX_CURRENT_FEATURE], [$1])
  118. AC_DEFUN([DX_CURRENT_DESCRIPTION], [$2])
  119. AC_ARG_ENABLE(doxygen-$1,
  120. [AS_HELP_STRING(DX_IF_FEATURE([$1], [--disable-doxygen-$1],
  121. [--enable-doxygen-$1]),
  122. DX_IF_FEATURE([$1], [don't $2], [$2]))],
  123. [
  124. case "$enableval" in
  125. #(
  126. y|Y|yes|Yes|YES)
  127. AC_SUBST([DX_FLAG_$1], 1)
  128. $3
  129. ;; #(
  130. n|N|no|No|NO)
  131. AC_SUBST([DX_FLAG_$1], 0)
  132. ;; #(
  133. *)
  134. AC_MSG_ERROR([invalid value '$enableval' given to doxygen-$1])
  135. ;;
  136. esac
  137. ], [
  138. AC_SUBST([DX_FLAG_$1], [DX_IF_FEATURE([$1], 1, 0)])
  139. $4
  140. ])
  141. if DX_TEST_FEATURE([$1]); then
  142. $5
  143. :
  144. fi
  145. if DX_TEST_FEATURE([$1]); then
  146. AM_CONDITIONAL(DX_COND_$1, :)
  147. $6
  148. :
  149. else
  150. AM_CONDITIONAL(DX_COND_$1, false)
  151. $7
  152. :
  153. fi
  154. ])
  155. ## -------------- ##
  156. ## Public macros. ##
  157. ## -------------- ##
  158. # DX_XXX_FEATURE(DEFAULT_STATE)
  159. # -----------------------------
  160. AC_DEFUN([DX_DOXYGEN_FEATURE], [AC_DEFUN([DX_FEATURE_doc], [$1])])
  161. AC_DEFUN([DX_MAN_FEATURE], [AC_DEFUN([DX_FEATURE_man], [$1])])
  162. AC_DEFUN([DX_HTML_FEATURE], [AC_DEFUN([DX_FEATURE_html], [$1])])
  163. AC_DEFUN([DX_CHM_FEATURE], [AC_DEFUN([DX_FEATURE_chm], [$1])])
  164. AC_DEFUN([DX_CHI_FEATURE], [AC_DEFUN([DX_FEATURE_chi], [$1])])
  165. AC_DEFUN([DX_RTF_FEATURE], [AC_DEFUN([DX_FEATURE_rtf], [$1])])
  166. AC_DEFUN([DX_XML_FEATURE], [AC_DEFUN([DX_FEATURE_xml], [$1])])
  167. AC_DEFUN([DX_XML_FEATURE], [AC_DEFUN([DX_FEATURE_xml], [$1])])
  168. AC_DEFUN([DX_PDF_FEATURE], [AC_DEFUN([DX_FEATURE_pdf], [$1])])
  169. AC_DEFUN([DX_PS_FEATURE], [AC_DEFUN([DX_FEATURE_ps], [$1])])
  170. # DX_INIT_DOXYGEN(PROJECT, [CONFIG-FILE], [OUTPUT-DOC-DIR])
  171. # ---------------------------------------------------------
  172. # PROJECT also serves as the base name for the documentation files.
  173. # The default CONFIG-FILE is "Doxyfile" and OUTPUT-DOC-DIR is "doxygen-doc".
  174. AC_DEFUN([DX_INIT_DOXYGEN], [
  175. # Files:
  176. AC_SUBST([DX_PROJECT], [$1])
  177. AC_SUBST([DX_CONFIG], [ifelse([$2], [], Doxyfile, [$2])])
  178. AC_SUBST([DX_DOCDIR], [ifelse([$3], [], doxygen-doc, [$3])])
  179. # Environment variables used inside doxygen.cfg:
  180. DX_ENV_APPEND(SRCDIR, $srcdir)
  181. DX_ENV_APPEND(PROJECT, $DX_PROJECT)
  182. DX_ENV_APPEND(DOCDIR, $DX_DOCDIR)
  183. DX_ENV_APPEND(VERSION, $PACKAGE_VERSION)
  184. # Doxygen itself:
  185. DX_ARG_ABLE(doc, [generate any doxygen documentation],
  186. [],
  187. [],
  188. [DX_REQUIRE_PROG([DX_DOXYGEN], doxygen)
  189. DX_REQUIRE_PROG([DX_PERL], perl)],
  190. [DX_ENV_APPEND(PERL_PATH, $DX_PERL)])
  191. # Dot for graphics:
  192. DX_ARG_ABLE(dot, [generate graphics for doxygen documentation],
  193. [DX_CHECK_DEPEND(doc, 1)],
  194. [DX_CLEAR_DEPEND(doc, 1)],
  195. [DX_REQUIRE_PROG([DX_DOT], dot)],
  196. [DX_ENV_APPEND(HAVE_DOT, YES)
  197. DX_ENV_APPEND(DOT_PATH, [`DX_DIRNAME_EXPR($DX_DOT)`])],
  198. [DX_ENV_APPEND(HAVE_DOT, NO)])
  199. # Man pages generation:
  200. DX_ARG_ABLE(man, [generate doxygen manual pages],
  201. [DX_CHECK_DEPEND(doc, 1)],
  202. [DX_CLEAR_DEPEND(doc, 1)],
  203. [],
  204. [DX_ENV_APPEND(GENERATE_MAN, YES)],
  205. [DX_ENV_APPEND(GENERATE_MAN, NO)])
  206. # RTF file generation:
  207. DX_ARG_ABLE(rtf, [generate doxygen RTF documentation],
  208. [DX_CHECK_DEPEND(doc, 1)],
  209. [DX_CLEAR_DEPEND(doc, 1)],
  210. [],
  211. [DX_ENV_APPEND(GENERATE_RTF, YES)],
  212. [DX_ENV_APPEND(GENERATE_RTF, NO)])
  213. # XML file generation:
  214. DX_ARG_ABLE(xml, [generate doxygen XML documentation],
  215. [DX_CHECK_DEPEND(doc, 1)],
  216. [DX_CLEAR_DEPEND(doc, 1)],
  217. [],
  218. [DX_ENV_APPEND(GENERATE_XML, YES)],
  219. [DX_ENV_APPEND(GENERATE_XML, NO)])
  220. # (Compressed) HTML help generation:
  221. DX_ARG_ABLE(chm, [generate doxygen compressed HTML help documentation],
  222. [DX_CHECK_DEPEND(doc, 1)],
  223. [DX_CLEAR_DEPEND(doc, 1)],
  224. [DX_REQUIRE_PROG([DX_HHC], hhc)],
  225. [DX_ENV_APPEND(HHC_PATH, $DX_HHC)
  226. DX_ENV_APPEND(GENERATE_HTML, YES)
  227. DX_ENV_APPEND(GENERATE_HTMLHELP, YES)],
  228. [DX_ENV_APPEND(GENERATE_HTMLHELP, NO)])
  229. # Seperate CHI file generation.
  230. DX_ARG_ABLE(chi, [generate doxygen seperate compressed HTML help index file],
  231. [DX_CHECK_DEPEND(chm, 1)],
  232. [DX_CLEAR_DEPEND(chm, 1)],
  233. [],
  234. [DX_ENV_APPEND(GENERATE_CHI, YES)],
  235. [DX_ENV_APPEND(GENERATE_CHI, NO)])
  236. # Plain HTML pages generation:
  237. DX_ARG_ABLE(html, [generate doxygen plain HTML documentation],
  238. [DX_CHECK_DEPEND(doc, 1) DX_CHECK_DEPEND(chm, 0)],
  239. [DX_CLEAR_DEPEND(doc, 1) DX_CLEAR_DEPEND(chm, 0)],
  240. [],
  241. [DX_ENV_APPEND(GENERATE_HTML, YES)],
  242. [DX_TEST_FEATURE(chm) || DX_ENV_APPEND(GENERATE_HTML, NO)])
  243. # PostScript file generation:
  244. DX_ARG_ABLE(ps, [generate doxygen PostScript documentation],
  245. [DX_CHECK_DEPEND(doc, 1)],
  246. [DX_CLEAR_DEPEND(doc, 1)],
  247. [DX_REQUIRE_PROG([DX_LATEX], latex)
  248. DX_REQUIRE_PROG([DX_MAKEINDEX], makeindex)
  249. DX_REQUIRE_PROG([DX_DVIPS], dvips)
  250. DX_REQUIRE_PROG([DX_EGREP], egrep)])
  251. # PDF file generation:
  252. DX_ARG_ABLE(pdf, [generate doxygen PDF documentation],
  253. [DX_CHECK_DEPEND(doc, 1)],
  254. [DX_CLEAR_DEPEND(doc, 1)],
  255. [DX_REQUIRE_PROG([DX_PDFLATEX], pdflatex)
  256. DX_REQUIRE_PROG([DX_MAKEINDEX], makeindex)
  257. DX_REQUIRE_PROG([DX_EGREP], egrep)])
  258. # LaTeX generation for PS and/or PDF:
  259. if DX_TEST_FEATURE(ps) || DX_TEST_FEATURE(pdf); then
  260. AM_CONDITIONAL(DX_COND_latex, :)
  261. DX_ENV_APPEND(GENERATE_LATEX, YES)
  262. else
  263. AM_CONDITIONAL(DX_COND_latex, false)
  264. DX_ENV_APPEND(GENERATE_LATEX, NO)
  265. fi
  266. # Paper size for PS and/or PDF:
  267. AC_ARG_VAR(DOXYGEN_PAPER_SIZE,
  268. [a4wide (default), a4, letter, legal or executive])
  269. case "$DOXYGEN_PAPER_SIZE" in
  270. #(
  271. "")
  272. AC_SUBST(DOXYGEN_PAPER_SIZE, "")
  273. ;; #(
  274. a4wide|a4|letter|legal|executive)
  275. DX_ENV_APPEND(PAPER_SIZE, $DOXYGEN_PAPER_SIZE)
  276. ;; #(
  277. *)
  278. AC_MSG_ERROR([unknown DOXYGEN_PAPER_SIZE='$DOXYGEN_PAPER_SIZE'])
  279. ;;
  280. esac
  281. #For debugging:
  282. #echo DX_FLAG_doc=$DX_FLAG_doc
  283. #echo DX_FLAG_dot=$DX_FLAG_dot
  284. #echo DX_FLAG_man=$DX_FLAG_man
  285. #echo DX_FLAG_html=$DX_FLAG_html
  286. #echo DX_FLAG_chm=$DX_FLAG_chm
  287. #echo DX_FLAG_chi=$DX_FLAG_chi
  288. #echo DX_FLAG_rtf=$DX_FLAG_rtf
  289. #echo DX_FLAG_xml=$DX_FLAG_xml
  290. #echo DX_FLAG_pdf=$DX_FLAG_pdf
  291. #echo DX_FLAG_ps=$DX_FLAG_ps
  292. #echo DX_ENV=$DX_ENV
  293. ])