/Unittests/googletest/configure.ac

http://unladen-swallow.googlecode.com/ · m4 · 51 lines · 23 code · 9 blank · 19 comment · 0 complexity · c6d576fca92f694e3917885385c4ecf2 MD5 · raw file

  1. m4_include(m4/acx_pthread.m4)
  2. # At this point, the Xcode project assumes the version string will be three
  3. # integers separated by periods and surrounded by square brackets (e.g.
  4. # "[1.0.1]"). It also asumes that there won't be any closing parenthesis
  5. # between "AC_INIT(" and the closing ")" including comments and strings.
  6. AC_INIT([Google C++ Testing Framework],
  7. [1.4.0],
  8. [googletestframework@googlegroups.com],
  9. [gtest])
  10. # Provide various options to initialize the Autoconf and configure processes.
  11. AC_PREREQ([2.59])
  12. AC_CONFIG_SRCDIR([./COPYING])
  13. AC_CONFIG_AUX_DIR([build-aux])
  14. AC_CONFIG_HEADERS([build-aux/config.h])
  15. AC_CONFIG_FILES([Makefile])
  16. AC_CONFIG_FILES([scripts/gtest-config], [chmod +x scripts/gtest-config])
  17. # Initialize Automake with various options. We require at least v1.9, prevent
  18. # pedantic complaints about package files, and enable various distribution
  19. # targets.
  20. AM_INIT_AUTOMAKE([1.9 dist-bzip2 dist-zip foreign subdir-objects])
  21. # Check for programs used in building Google Test.
  22. AC_PROG_CC
  23. AC_PROG_CXX
  24. AC_LANG([C++])
  25. AC_PROG_LIBTOOL
  26. # TODO(chandlerc@google.com): Currently we aren't running the Python tests
  27. # against the interpreter detected by AM_PATH_PYTHON, and so we condition
  28. # HAVE_PYTHON by requiring "python" to be in the PATH, and that interpreter's
  29. # version to be >= 2.3. This will allow the scripts to use a "/usr/bin/env"
  30. # hashbang.
  31. PYTHON= # We *do not* allow the user to specify a python interpreter
  32. AC_PATH_PROG([PYTHON],[python],[:])
  33. AS_IF([test "$PYTHON" != ":"],
  34. [AM_PYTHON_CHECK_VERSION([$PYTHON],[2.3],[:],[PYTHON=":"])])
  35. AM_CONDITIONAL([HAVE_PYTHON],[test "$PYTHON" != ":"])
  36. # Check for pthreads.
  37. ACX_PTHREAD
  38. # TODO(chandlerc@google.com) Check for the necessary system headers.
  39. # TODO(chandlerc@google.com) Check the types, structures, and other compiler
  40. # and architecture characteristics.
  41. # Output the generated files. No further autoconf macros may be used.
  42. AC_OUTPUT