PageRenderTime 20ms CodeModel.GetById 13ms app.highlight 3ms RepoModel.GetById 1ms app.codeStats 0ms

/arch/powerpc/boot/zImage.ps3.lds.S

http://github.com/mirrors/linux
Assembly | 51 lines | 46 code | 5 blank | 0 comment | 0 complexity | 5c222829354bbbeac08d50c5d6e4f901 MD5 | raw file
 1/* SPDX-License-Identifier: GPL-2.0 */
 2OUTPUT_ARCH(powerpc:common)
 3ENTRY(_zimage_start)
 4EXTERN(_zimage_start)
 5SECTIONS
 6{
 7  _vmlinux_start =  .;
 8  .kernel:vmlinux.bin : { *(.kernel:vmlinux.bin) }
 9  _vmlinux_end =  .;
10
11  . = ALIGN(4096);
12  _dtb_start = .;
13  .kernel:dtb : { *(.kernel:dtb) }
14  _dtb_end = .;
15
16  . = ALIGN(4096);
17  _initrd_start =  .;
18  .kernel:initrd : { *(.kernel:initrd) }
19  _initrd_end =  .;
20
21  _start = .;
22  .text      :
23  {
24    *(.text)
25    *(.fixup)
26  }
27  _etext = .;
28  . = ALIGN(4096);
29  .data    :
30  {
31    *(.rodata*)
32    *(.data*)
33    *(.sdata*)
34    __got2_start = .;
35    *(.got2)
36    __got2_end = .;
37  }
38
39  . = ALIGN(4096);
40  _edata  =  .;
41
42  . = ALIGN(4096);
43  __bss_start = .;
44  .bss       :
45  {
46   *(.sbss)
47   *(.bss)
48  }
49  . = ALIGN(4096);
50  _end = . ;
51}