PageRenderTime 200ms CodeModel.GetById 93ms app.highlight 73ms RepoModel.GetById 27ms app.codeStats 1ms

/js/lib/Socket.IO-node/support/socket.io-client/lib/vendor/web-socket-js/flash-src/com/gsolo/encryption/MD5.as

http://github.com/onedayitwillmake/RealtimeMultiplayerNodeJs
ActionScript | 375 lines | 262 code | 39 blank | 74 comment | 30 complexity | b4c81fb8d38e2919158047c064f23dbb MD5 | raw file
  1package com.gsolo.encryption {	
  2	public class MD5 {
  3		/*
  4		 * A JavaScript implementation of the RSA Data Security, Inc. MD5 Message
  5		 * Digest Algorithm, as defined in RFC 1321.
  6		 * Version 2.2-alpha Copyright (C) Paul Johnston 1999 - 2005
  7		 * Other contributors: Greg Holt, Andrew Kepert, Ydnar, Lostinet
  8		 * Distributed under the BSD License
  9		 * See http://pajhome.org.uk/crypt/md5 for more info.
 10		 *
 11		 * Converted to AS3 By Geoffrey Williams
 12		 */
 13		
 14		/*
 15		 * Configurable variables. You may need to tweak these to be compatible with
 16		 * the server-side, but the defaults work in most cases.
 17		 */
 18		
 19		public static const HEX_FORMAT_LOWERCASE:uint = 0;
 20		public static const HEX_FORMAT_UPPERCASE:uint = 1;
 21		 
 22		public static const BASE64_PAD_CHARACTER_DEFAULT_COMPLIANCE:String = "";
 23		public static const BASE64_PAD_CHARACTER_RFC_COMPLIANCE:String = "=";
 24		 
 25		public static var hexcase:uint = 0;   /* hex output format. 0 - lowercase; 1 - uppercase        */
 26		public static var b64pad:String  = ""; /* base-64 pad character. "=" for strict RFC compliance   */
 27		
 28		public static function encrypt (string:String):String {
 29			return hex_md5 (string);
 30		}
 31		
 32		/*
 33		 * These are the functions you'll usually want to call
 34		 * They take string arguments and return either hex or base-64 encoded strings
 35		 */
 36		public static function hex_md5 (string:String):String {
 37			return rstr2hex (rstr_md5 (str2rstr_utf8 (string)));
 38		}
 39		
 40		public static function b64_md5 (string:String):String {
 41			return rstr2b64 (rstr_md5 (str2rstr_utf8 (string)));
 42		}
 43		
 44		public static function any_md5 (string:String, encoding:String):String {
 45			return rstr2any (rstr_md5 (str2rstr_utf8 (string)), encoding);
 46		}
 47		public static function hex_hmac_md5 (key:String, data:String):String {
 48			return rstr2hex (rstr_hmac_md5 (str2rstr_utf8 (key), str2rstr_utf8 (data)));
 49		}
 50		public static function b64_hmac_md5 (key:String, data:String):String {
 51			return rstr2b64 (rstr_hmac_md5 (str2rstr_utf8 (key), str2rstr_utf8 (data)));
 52		}
 53		public static function any_hmac_md5 (key:String, data:String, encoding:String):String {
 54			return rstr2any(rstr_hmac_md5(str2rstr_utf8(key), str2rstr_utf8(data)), encoding);
 55		}
 56		
 57		/*
 58		 * Perform a simple self-test to see if the VM is working
 59		 */
 60		public static function md5_vm_test ():Boolean {
 61		  return hex_md5 ("abc") == "900150983cd24fb0d6963f7d28e17f72";
 62		}
 63		
 64		/*
 65		 * Calculate the MD5 of a raw string
 66		 */
 67		public static function rstr_md5 (string:String):String {
 68		  return binl2rstr (binl_md5 (rstr2binl (string), string.length * 8));
 69		}
 70		
 71		/*
 72		 * Calculate the HMAC-MD5, of a key and some data (raw strings)
 73		 */
 74		public static function rstr_hmac_md5 (key:String, data:String):String {
 75		  var bkey:Array = rstr2binl (key);
 76		  if (bkey.length > 16) bkey = binl_md5 (bkey, key.length * 8);
 77		
 78		  var ipad:Array = new Array(16), opad:Array = new Array(16);
 79		  for(var i:Number = 0; i < 16; i++) {
 80		    ipad[i] = bkey[i] ^ 0x36363636;
 81		    opad[i] = bkey[i] ^ 0x5C5C5C5C;
 82		  }
 83		
 84		  var hash:Array = binl_md5 (ipad.concat (rstr2binl (data)), 512 + data.length * 8);
 85		  return binl2rstr (binl_md5 (opad.concat (hash), 512 + 128));
 86		}
 87		
 88		/*
 89		 * Convert a raw string to a hex string
 90		 */
 91		public static function rstr2hex (input:String):String {
 92		  var hex_tab:String = hexcase ? "0123456789ABCDEF" : "0123456789abcdef";
 93		  var output:String = "";
 94		  var x:Number;
 95		  for(var i:Number = 0; i < input.length; i++) {
 96		  	x = input.charCodeAt(i);
 97		    output += hex_tab.charAt((x >>> 4) & 0x0F)
 98		           +  hex_tab.charAt( x        & 0x0F);
 99		  }
100		  return output;
101		}
102		
103		/*
104		 * Convert a raw string to a base-64 string
105		 */
106		public static function rstr2b64 (input:String):String {
107		  var tab:String = "ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz0123456789+/";
108		  var output:String = "";
109		  var len:Number = input.length;
110		  for(var i:Number = 0; i < len; i += 3) {
111		    var triplet:Number = (input.charCodeAt(i) << 16)
112		                | (i + 1 < len ? input.charCodeAt(i+1) << 8 : 0)
113		                | (i + 2 < len ? input.charCodeAt(i+2)      : 0);
114		    for(var j:Number = 0; j < 4; j++) {
115		      if(i * 8 + j * 6 > input.length * 8) output += b64pad;
116		      else output += tab.charAt((triplet >>> 6*(3-j)) & 0x3F);
117		    }
118		  }
119		  return output;
120		}
121		
122		/*
123		 * Convert a raw string to an arbitrary string encoding
124		 */
125		public static function rstr2any(input:String, encoding:String):String {
126		  var divisor:Number = encoding.length;
127		  var remainders:Array = [];
128		  var i:Number, q:Number, x:Number, quotient:Array;
129		
130		  /* Convert to an array of 16-bit big-endian values, forming the dividend */
131		  var dividend:Array = new Array(input.length / 2);
132		  for(i = 0; i < dividend.length; i++) {
133		    dividend[i] = (input.charCodeAt(i * 2) << 8) | input.charCodeAt(i * 2 + 1);
134		  }
135		
136		  /*
137		   * Repeatedly perform a long division. The binary array forms the dividend,
138		   * the length of the encoding is the divisor. Once computed, the quotient
139		   * forms the dividend for the next step. We stop when the dividend is zero.
140		   * All remainders are stored for later use.
141		   */
142		  while(dividend.length > 0) {
143		    quotient = [];
144		    x = 0;
145		    for(i = 0; i < dividend.length; i++) {
146		      x = (x << 16) + dividend[i];
147		      q = Math.floor(x / divisor);
148		      x -= q * divisor;
149		      if(quotient.length > 0 || q > 0)
150		        quotient[quotient.length] = q;
151		    }
152		    remainders[remainders.length] = x;
153		    dividend = quotient;
154		  }
155		
156		  /* Convert the remainders to the output string */
157		  var output:String = "";
158		  for(i = remainders.length - 1; i >= 0; i--)
159		    output += encoding.charAt (remainders[i]);
160		
161		  return output;
162		}
163		
164		/*
165		 * Encode a string as utf-8.
166		 * For efficiency, this assumes the input is valid utf-16.
167		 */
168		public static function str2rstr_utf8 (input:String):String {
169		  var output:String = "";
170		  var i:Number = -1;
171		  var x:Number, y:Number;
172		
173		  while(++i < input.length) {
174		    /* Decode utf-16 surrogate pairs */
175		    x = input.charCodeAt(i);
176		    y = i + 1 < input.length ? input.charCodeAt(i + 1) : 0;
177		    if(0xD800 <= x && x <= 0xDBFF && 0xDC00 <= y && y <= 0xDFFF) {
178		      x = 0x10000 + ((x & 0x03FF) << 10) + (y & 0x03FF);
179		      i++;
180		    }
181		
182		    /* Encode output as utf-8 */
183		    if(x <= 0x7F)
184		      output += String.fromCharCode(x);
185		    else if(x <= 0x7FF)
186		      output += String.fromCharCode(0xC0 | ((x >>> 6 ) & 0x1F),
187		                                    0x80 | ( x         & 0x3F));
188		    else if(x <= 0xFFFF)
189		      output += String.fromCharCode(0xE0 | ((x >>> 12) & 0x0F),
190		                                    0x80 | ((x >>> 6 ) & 0x3F),
191		                                    0x80 | ( x         & 0x3F));
192		    else if(x <= 0x1FFFFF)
193		      output += String.fromCharCode(0xF0 | ((x >>> 18) & 0x07),
194		                                    0x80 | ((x >>> 12) & 0x3F),
195		                                    0x80 | ((x >>> 6 ) & 0x3F),
196		                                    0x80 | ( x         & 0x3F));
197		  }
198		  return output;
199		}
200		
201		/*
202		 * Encode a string as utf-16
203		 */
204		public static function str2rstr_utf16le (input:String):String {
205		  var output:String = "";
206		  for(var i:Number = 0; i < input.length; i++)
207		    output += String.fromCharCode( input.charCodeAt(i)        & 0xFF,
208		                                  (input.charCodeAt(i) >>> 8) & 0xFF);
209		  return output;
210		}
211		
212		public static function str2rstr_utf16be (input:String):String {
213		  var output:String = "";
214		  for(var i:Number = 0; i < input.length; i++)
215		    output += String.fromCharCode((input.charCodeAt(i) >>> 8) & 0xFF,
216		                                   input.charCodeAt(i)        & 0xFF);
217		  return output;
218		}
219		
220		/*
221		 * Convert a raw string to an array of little-endian words
222		 * Characters >255 have their high-byte silently ignored.
223		 */
224		public static function rstr2binl (input:String):Array {
225		  var output:Array = new Array(input.length >> 2);
226		  for(var i:Number = 0; i < output.length; i++)
227		    output[i] = 0;
228		  for(i = 0; i < input.length * 8; i += 8)
229		    output[i>>5] |= (input.charCodeAt(i / 8) & 0xFF) << (i%32);
230		  return output;
231		}
232		
233		/*
234		 * Convert an array of little-endian words to a string
235		 */
236		public static function binl2rstr (input:Array):String {
237		  var output:String = "";
238		  for(var i:Number = 0; i < input.length * 32; i += 8)
239		    output += String.fromCharCode((input[i>>5] >>> (i % 32)) & 0xFF);
240		  return output;
241		}
242		
243		/*
244		 * Calculate the MD5 of an array of little-endian words, and a bit length.
245		 */
246		public static function binl_md5 (x:Array, len:Number):Array {
247		  /* append padding */
248		  x[len >> 5] |= 0x80 << ((len) % 32);
249		  x[(((len + 64) >>> 9) << 4) + 14] = len;
250		
251		  var a:Number =  1732584193;
252		  var b:Number = -271733879;
253		  var c:Number = -1732584194;
254		  var d:Number =  271733878;
255		
256		  for(var i:Number = 0; i < x.length; i += 16) {
257		    var olda:Number = a;
258		    var oldb:Number = b;
259		    var oldc:Number = c;
260		    var oldd:Number = d;
261		
262		    a = md5_ff(a, b, c, d, x[i+ 0], 7 , -680876936);
263		    d = md5_ff(d, a, b, c, x[i+ 1], 12, -389564586);
264		    c = md5_ff(c, d, a, b, x[i+ 2], 17,  606105819);
265		    b = md5_ff(b, c, d, a, x[i+ 3], 22, -1044525330);
266		    a = md5_ff(a, b, c, d, x[i+ 4], 7 , -176418897);
267		    d = md5_ff(d, a, b, c, x[i+ 5], 12,  1200080426);
268		    c = md5_ff(c, d, a, b, x[i+ 6], 17, -1473231341);
269		    b = md5_ff(b, c, d, a, x[i+ 7], 22, -45705983);
270		    a = md5_ff(a, b, c, d, x[i+ 8], 7 ,  1770035416);
271		    d = md5_ff(d, a, b, c, x[i+ 9], 12, -1958414417);
272		    c = md5_ff(c, d, a, b, x[i+10], 17, -42063);
273		    b = md5_ff(b, c, d, a, x[i+11], 22, -1990404162);
274		    a = md5_ff(a, b, c, d, x[i+12], 7 ,  1804603682);
275		    d = md5_ff(d, a, b, c, x[i+13], 12, -40341101);
276		    c = md5_ff(c, d, a, b, x[i+14], 17, -1502002290);
277		    b = md5_ff(b, c, d, a, x[i+15], 22,  1236535329);
278		
279		    a = md5_gg(a, b, c, d, x[i+ 1], 5 , -165796510);
280		    d = md5_gg(d, a, b, c, x[i+ 6], 9 , -1069501632);
281		    c = md5_gg(c, d, a, b, x[i+11], 14,  643717713);
282		    b = md5_gg(b, c, d, a, x[i+ 0], 20, -373897302);
283		    a = md5_gg(a, b, c, d, x[i+ 5], 5 , -701558691);
284		    d = md5_gg(d, a, b, c, x[i+10], 9 ,  38016083);
285		    c = md5_gg(c, d, a, b, x[i+15], 14, -660478335);
286		    b = md5_gg(b, c, d, a, x[i+ 4], 20, -405537848);
287		    a = md5_gg(a, b, c, d, x[i+ 9], 5 ,  568446438);
288		    d = md5_gg(d, a, b, c, x[i+14], 9 , -1019803690);
289		    c = md5_gg(c, d, a, b, x[i+ 3], 14, -187363961);
290		    b = md5_gg(b, c, d, a, x[i+ 8], 20,  1163531501);
291		    a = md5_gg(a, b, c, d, x[i+13], 5 , -1444681467);
292		    d = md5_gg(d, a, b, c, x[i+ 2], 9 , -51403784);
293		    c = md5_gg(c, d, a, b, x[i+ 7], 14,  1735328473);
294		    b = md5_gg(b, c, d, a, x[i+12], 20, -1926607734);
295		
296		    a = md5_hh(a, b, c, d, x[i+ 5], 4 , -378558);
297		    d = md5_hh(d, a, b, c, x[i+ 8], 11, -2022574463);
298		    c = md5_hh(c, d, a, b, x[i+11], 16,  1839030562);
299		    b = md5_hh(b, c, d, a, x[i+14], 23, -35309556);
300		    a = md5_hh(a, b, c, d, x[i+ 1], 4 , -1530992060);
301		    d = md5_hh(d, a, b, c, x[i+ 4], 11,  1272893353);
302		    c = md5_hh(c, d, a, b, x[i+ 7], 16, -155497632);
303		    b = md5_hh(b, c, d, a, x[i+10], 23, -1094730640);
304		    a = md5_hh(a, b, c, d, x[i+13], 4 ,  681279174);
305		    d = md5_hh(d, a, b, c, x[i+ 0], 11, -358537222);
306		    c = md5_hh(c, d, a, b, x[i+ 3], 16, -722521979);
307		    b = md5_hh(b, c, d, a, x[i+ 6], 23,  76029189);
308		    a = md5_hh(a, b, c, d, x[i+ 9], 4 , -640364487);
309		    d = md5_hh(d, a, b, c, x[i+12], 11, -421815835);
310		    c = md5_hh(c, d, a, b, x[i+15], 16,  530742520);
311		    b = md5_hh(b, c, d, a, x[i+ 2], 23, -995338651);
312		
313		    a = md5_ii(a, b, c, d, x[i+ 0], 6 , -198630844);
314		    d = md5_ii(d, a, b, c, x[i+ 7], 10,  1126891415);
315		    c = md5_ii(c, d, a, b, x[i+14], 15, -1416354905);
316		    b = md5_ii(b, c, d, a, x[i+ 5], 21, -57434055);
317		    a = md5_ii(a, b, c, d, x[i+12], 6 ,  1700485571);
318		    d = md5_ii(d, a, b, c, x[i+ 3], 10, -1894986606);
319		    c = md5_ii(c, d, a, b, x[i+10], 15, -1051523);
320		    b = md5_ii(b, c, d, a, x[i+ 1], 21, -2054922799);
321		    a = md5_ii(a, b, c, d, x[i+ 8], 6 ,  1873313359);
322		    d = md5_ii(d, a, b, c, x[i+15], 10, -30611744);
323		    c = md5_ii(c, d, a, b, x[i+ 6], 15, -1560198380);
324		    b = md5_ii(b, c, d, a, x[i+13], 21,  1309151649);
325		    a = md5_ii(a, b, c, d, x[i+ 4], 6 , -145523070);
326		    d = md5_ii(d, a, b, c, x[i+11], 10, -1120210379);
327		    c = md5_ii(c, d, a, b, x[i+ 2], 15,  718787259);
328		    b = md5_ii(b, c, d, a, x[i+ 9], 21, -343485551);
329		
330		    a = safe_add(a, olda);
331		    b = safe_add(b, oldb);
332		    c = safe_add(c, oldc);
333		    d = safe_add(d, oldd);
334		  }
335		  return [a, b, c, d];
336		}
337		
338		/*
339		 * These functions implement the four basic operations the algorithm uses.
340		 */
341		public static function md5_cmn (q:Number, a:Number, b:Number, x:Number, s:Number, t:Number):Number {
342		  return safe_add (bit_rol (safe_add (safe_add (a, q), safe_add(x, t)), s), b);
343		}
344		public static function md5_ff (a:Number, b:Number, c:Number, d:Number, x:Number, s:Number, t:Number):Number {
345		  return md5_cmn ((b & c) | ((~b) & d), a, b, x, s, t);
346		}
347		public static function md5_gg (a:Number, b:Number, c:Number, d:Number, x:Number, s:Number, t:Number):Number {
348		  return md5_cmn ((b & d) | (c & (~d)), a, b, x, s, t);
349		}
350		public static function md5_hh (a:Number, b:Number, c:Number, d:Number, x:Number, s:Number, t:Number):Number {
351		  return md5_cmn (b ^ c ^ d, a, b, x, s, t);
352		}
353		public static function md5_ii (a:Number, b:Number, c:Number, d:Number, x:Number, s:Number, t:Number):Number {
354		  return md5_cmn (c ^ (b | (~d)), a, b, x, s, t);
355		}
356		
357		/*
358		 * Add integers, wrapping at 2^32. This uses 16-bit operations internally
359		 * to work around bugs in some JS interpreters.
360		 */
361		public static function safe_add (x:Number, y:Number):Number {
362		  var lsw:Number = (x & 0xFFFF) + (y & 0xFFFF);
363		  var msw:Number = (x >> 16) + (y >> 16) + (lsw >> 16);
364		  return (msw << 16) | (lsw & 0xFFFF);
365		}
366		
367		/*
368		 * Bitwise rotate a 32-bit number to the left.
369		 */
370		public static function bit_rol (num:Number, cnt:Number):Number {
371		  return (num << cnt) | (num >>> (32 - cnt));
372		}
373				
374	}
375}