PageRenderTime 72ms CodeModel.GetById 50ms app.highlight 1ms RepoModel.GetById 19ms app.codeStats 0ms

/js/lib/Socket.IO-node/support/expresso/deps/jscoverage/configure.ac

http://github.com/onedayitwillmake/RealtimeMultiplayerNodeJs
m4 | 88 lines | 57 code | 10 blank | 21 comment | 0 complexity | 482b951063e080218546ee069d705fe8 MD5 | raw file
 1#    configure.ac - configures jscoverage
 2#    Copyright (C) 2007, 2008 siliconforks.com
 3#
 4#    This program is free software; you can redistribute it and/or modify
 5#    it under the terms of the GNU General Public License as published by
 6#    the Free Software Foundation; either version 2 of the License, or
 7#    (at your option) any later version.
 8#
 9#    This program is distributed in the hope that it will be useful,
10#    but WITHOUT ANY WARRANTY; without even the implied warranty of
11#    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
12#    GNU General Public License for more details.
13#
14#    You should have received a copy of the GNU General Public License along
15#    with this program; if not, write to the Free Software Foundation, Inc.,
16#    51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
17
18AC_PREREQ(2.61)
19AC_INIT([jscoverage], [0.4])
20AM_INIT_AUTOMAKE([-Wall foreign])
21AC_CONFIG_SRCDIR([jscoverage.c])
22AC_CONFIG_HEADERS([config.h])
23AC_CANONICAL_HOST
24
25# Checks for programs.
26AC_PROG_CC
27AC_PROG_CC_C99
28AC_PROG_CXX
29
30# Checks for libraries.
31AM_ICONV
32
33# Checks for header files.
34AC_CHECK_HEADERS([pthread.h])
35AC_CHECK_HEADERS([iconv.h])
36AC_CHECK_HEADERS([windows.h])
37
38# Checks for typedefs, structures, and compiler characteristics.
39AC_C_BIGENDIAN
40
41# Checks for library functions.
42AC_CHECK_FUNCS([getaddrinfo gethostbyname_r inet_aton strndup vasprintf asprintf])
43AC_MSG_CHECKING([for MultiByteToWideChar])
44AC_LANG(C)
45AC_LINK_IFELSE(
46  [AC_LANG_PROGRAM([[#include <windows.h>]],[[MultiByteToWideChar(0,0,0,0,0,0);]])],
47  [AC_DEFINE([HAVE_MULTIBYTETOWIDECHAR], [1], [Define to 1 if you have the `MultiByteToWideChar' function.])
48   jscoverage_have_multibytetowidechar=yes
49   AC_MSG_RESULT([yes])],
50  [jscoverage_have_multibytetowidechar=no
51   AC_MSG_RESULT([no])])
52
53AC_SUBST([XP_DEF])
54case "$host_os" in
55  mingw*)
56    XP_DEF='-DXP_WIN'
57    ;;
58  *)
59    XP_DEF='-DXP_UNIX'
60    ;;
61esac
62
63AC_SUBST([EXTRA_SOCKET_LIBS])
64AC_SUBST([EXTRA_THREAD_LIBS])
65AC_SUBST([EXTRA_TIMER_LIBS])
66case "$host_os" in
67  mingw*)
68    EXTRA_SOCKET_LIBS='-lws2_32'
69    EXTRA_THREAD_LIBS=''
70    EXTRA_TIMER_LIBS='-lwinmm'
71    ;;
72  *)
73    EXTRA_SOCKET_LIBS=''
74    EXTRA_THREAD_LIBS='-lpthread'
75    EXTRA_TIMER_LIBS=''
76    ;;
77esac
78
79if test "$am_cv_func_iconv" != yes && test "$jscoverage_have_multibytetowidechar" != yes
80then
81  echo -ne '\033@<:@1;31m'
82  AC_MSG_WARN([neither iconv nor Windows character encoding conversion functions found])
83  AC_MSG_WARN([only ASCII will be supported])
84  echo -ne '\033@<:@0m'
85fi
86
87AC_CONFIG_FILES([Makefile make-dist.sh make-bin-dist.sh tests/Makefile])
88AC_OUTPUT