/arch/s390/kernel/head.S

https://bitbucket.org/evzijst/gittest · Assembly · 772 lines · 718 code · 26 blank · 28 comment · 11 complexity · 936838501794c4f08b16b7e5e45738dc MD5 · raw file

  1. /*
  2. * arch/s390/kernel/head.S
  3. *
  4. * S390 version
  5. * Copyright (C) 1999,2000 IBM Deutschland Entwicklung GmbH, IBM Corporation
  6. * Author(s): Hartmut Penner (hp@de.ibm.com),
  7. * Martin Schwidefsky (schwidefsky@de.ibm.com),
  8. * Rob van der Heij (rvdhei@iae.nl)
  9. *
  10. * There are 5 different IPL methods
  11. * 1) load the image directly into ram at address 0 and do an PSW restart
  12. * 2) linload will load the image from address 0x10000 to memory 0x10000
  13. * and start the code thru LPSW 0x0008000080010000 (VM only, deprecated)
  14. * 3) generate the tape ipl header, store the generated image on a tape
  15. * and ipl from it
  16. * In case of SL tape you need to IPL 5 times to get past VOL1 etc
  17. * 4) generate the vm reader ipl header, move the generated image to the
  18. * VM reader (use option NOH!) and do a ipl from reader (VM only)
  19. * 5) direct call of start by the SALIPL loader
  20. * We use the cpuid to distinguish between VM and native ipl
  21. * params for kernel are pushed to 0x10400 (see setup.h)
  22. Changes:
  23. Okt 25 2000 <rvdheij@iae.nl>
  24. added code to skip HDR and EOF to allow SL tape IPL (5 retries)
  25. changed first CCW from rewind to backspace block
  26. */
  27. #include <linux/config.h>
  28. #include <asm/setup.h>
  29. #include <asm/lowcore.h>
  30. #include <asm/offsets.h>
  31. #include <asm/thread_info.h>
  32. #include <asm/page.h>
  33. #ifndef CONFIG_IPL
  34. .org 0
  35. .long 0x00080000,0x80000000+startup # Just a restart PSW
  36. #else
  37. #ifdef CONFIG_IPL_TAPE
  38. #define IPL_BS 1024
  39. .org 0
  40. .long 0x00080000,0x80000000+iplstart # The first 24 bytes are loaded
  41. .long 0x27000000,0x60000001 # by ipl to addresses 0-23.
  42. .long 0x02000000,0x20000000+IPL_BS # (a PSW and two CCWs).
  43. .long 0x00000000,0x00000000 # external old psw
  44. .long 0x00000000,0x00000000 # svc old psw
  45. .long 0x00000000,0x00000000 # program check old psw
  46. .long 0x00000000,0x00000000 # machine check old psw
  47. .long 0x00000000,0x00000000 # io old psw
  48. .long 0x00000000,0x00000000
  49. .long 0x00000000,0x00000000
  50. .long 0x00000000,0x00000000
  51. .long 0x000a0000,0x00000058 # external new psw
  52. .long 0x000a0000,0x00000060 # svc new psw
  53. .long 0x000a0000,0x00000068 # program check new psw
  54. .long 0x000a0000,0x00000070 # machine check new psw
  55. .long 0x00080000,0x80000000+.Lioint # io new psw
  56. .org 0x100
  57. #
  58. # subroutine for loading from tape
  59. # Paramters:
  60. # R1 = device number
  61. # R2 = load address
  62. .Lloader:
  63. st %r14,.Lldret
  64. la %r3,.Lorbread # r3 = address of orb
  65. la %r5,.Lirb # r5 = address of irb
  66. st %r2,.Lccwread+4 # initialize CCW data addresses
  67. lctl %c6,%c6,.Lcr6
  68. slr %r2,%r2
  69. .Lldlp:
  70. la %r6,3 # 3 retries
  71. .Lssch:
  72. ssch 0(%r3) # load chunk of IPL_BS bytes
  73. bnz .Llderr
  74. .Lw4end:
  75. bas %r14,.Lwait4io
  76. tm 8(%r5),0x82 # do we have a problem ?
  77. bnz .Lrecov
  78. slr %r7,%r7
  79. icm %r7,3,10(%r5) # get residual count
  80. lcr %r7,%r7
  81. la %r7,IPL_BS(%r7) # IPL_BS-residual=#bytes read
  82. ar %r2,%r7 # add to total size
  83. tm 8(%r5),0x01 # found a tape mark ?
  84. bnz .Ldone
  85. l %r0,.Lccwread+4 # update CCW data addresses
  86. ar %r0,%r7
  87. st %r0,.Lccwread+4
  88. b .Lldlp
  89. .Ldone:
  90. l %r14,.Lldret
  91. br %r14 # r2 contains the total size
  92. .Lrecov:
  93. bas %r14,.Lsense # do the sensing
  94. bct %r6,.Lssch # dec. retry count & branch
  95. b .Llderr
  96. #
  97. # Sense subroutine
  98. #
  99. .Lsense:
  100. st %r14,.Lsnsret
  101. la %r7,.Lorbsense
  102. ssch 0(%r7) # start sense command
  103. bnz .Llderr
  104. bas %r14,.Lwait4io
  105. l %r14,.Lsnsret
  106. tm 8(%r5),0x82 # do we have a problem ?
  107. bnz .Llderr
  108. br %r14
  109. #
  110. # Wait for interrupt subroutine
  111. #
  112. .Lwait4io:
  113. lpsw .Lwaitpsw
  114. .Lioint:
  115. c %r1,0xb8 # compare subchannel number
  116. bne .Lwait4io
  117. tsch 0(%r5)
  118. slr %r0,%r0
  119. tm 8(%r5),0x82 # do we have a problem ?
  120. bnz .Lwtexit
  121. tm 8(%r5),0x04 # got device end ?
  122. bz .Lwait4io
  123. .Lwtexit:
  124. br %r14
  125. .Llderr:
  126. lpsw .Lcrash
  127. .align 8
  128. .Lorbread:
  129. .long 0x00000000,0x0080ff00,.Lccwread
  130. .align 8
  131. .Lorbsense:
  132. .long 0x00000000,0x0080ff00,.Lccwsense
  133. .align 8
  134. .Lccwread:
  135. .long 0x02200000+IPL_BS,0x00000000
  136. .Lccwsense:
  137. .long 0x04200001,0x00000000
  138. .Lwaitpsw:
  139. .long 0x020a0000,0x80000000+.Lioint
  140. .Lirb: .long 0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
  141. .Lcr6: .long 0xff000000
  142. .align 8
  143. .Lcrash:.long 0x000a0000,0x00000000
  144. .Lldret:.long 0
  145. .Lsnsret: .long 0
  146. #endif /* CONFIG_IPL_TAPE */
  147. #ifdef CONFIG_IPL_VM
  148. #define IPL_BS 0x730
  149. .org 0
  150. .long 0x00080000,0x80000000+iplstart # The first 24 bytes are loaded
  151. .long 0x02000018,0x60000050 # by ipl to addresses 0-23.
  152. .long 0x02000068,0x60000050 # (a PSW and two CCWs).
  153. .fill 80-24,1,0x40 # bytes 24-79 are discarded !!
  154. .long 0x020000f0,0x60000050 # The next 160 byte are loaded
  155. .long 0x02000140,0x60000050 # to addresses 0x18-0xb7
  156. .long 0x02000190,0x60000050 # They form the continuation
  157. .long 0x020001e0,0x60000050 # of the CCW program started
  158. .long 0x02000230,0x60000050 # by ipl and load the range
  159. .long 0x02000280,0x60000050 # 0x0f0-0x730 from the image
  160. .long 0x020002d0,0x60000050 # to the range 0x0f0-0x730
  161. .long 0x02000320,0x60000050 # in memory. At the end of
  162. .long 0x02000370,0x60000050 # the channel program the PSW
  163. .long 0x020003c0,0x60000050 # at location 0 is loaded.
  164. .long 0x02000410,0x60000050 # Initial processing starts
  165. .long 0x02000460,0x60000050 # at 0xf0 = iplstart.
  166. .long 0x020004b0,0x60000050
  167. .long 0x02000500,0x60000050
  168. .long 0x02000550,0x60000050
  169. .long 0x020005a0,0x60000050
  170. .long 0x020005f0,0x60000050
  171. .long 0x02000640,0x60000050
  172. .long 0x02000690,0x60000050
  173. .long 0x020006e0,0x20000050
  174. .org 0xf0
  175. #
  176. # subroutine for loading cards from the reader
  177. #
  178. .Lloader:
  179. la %r3,.Lorb # r2 = address of orb into r2
  180. la %r5,.Lirb # r4 = address of irb
  181. la %r6,.Lccws
  182. la %r7,20
  183. .Linit:
  184. st %r2,4(%r6) # initialize CCW data addresses
  185. la %r2,0x50(%r2)
  186. la %r6,8(%r6)
  187. bct 7,.Linit
  188. lctl %c6,%c6,.Lcr6 # set IO subclass mask
  189. slr %r2,%r2
  190. .Lldlp:
  191. ssch 0(%r3) # load chunk of 1600 bytes
  192. bnz .Llderr
  193. .Lwait4irq:
  194. mvc __LC_IO_NEW_PSW(8),.Lnewpsw # set up IO interrupt psw
  195. lpsw .Lwaitpsw
  196. .Lioint:
  197. c %r1,0xb8 # compare subchannel number
  198. bne .Lwait4irq
  199. tsch 0(%r5)
  200. slr %r0,%r0
  201. ic %r0,8(%r5) # get device status
  202. chi %r0,8 # channel end ?
  203. be .Lcont
  204. chi %r0,12 # channel end + device end ?
  205. be .Lcont
  206. l %r0,4(%r5)
  207. s %r0,8(%r3) # r0/8 = number of ccws executed
  208. mhi %r0,10 # *10 = number of bytes in ccws
  209. lh %r3,10(%r5) # get residual count
  210. sr %r0,%r3 # #ccws*80-residual=#bytes read
  211. ar %r2,%r0
  212. br %r14 # r2 contains the total size
  213. .Lcont:
  214. ahi %r2,0x640 # add 0x640 to total size
  215. la %r6,.Lccws
  216. la %r7,20
  217. .Lincr:
  218. l %r0,4(%r6) # update CCW data addresses
  219. ahi %r0,0x640
  220. st %r0,4(%r6)
  221. ahi %r6,8
  222. bct 7,.Lincr
  223. b .Lldlp
  224. .Llderr:
  225. lpsw .Lcrash
  226. .align 8
  227. .Lorb: .long 0x00000000,0x0080ff00,.Lccws
  228. .Lirb: .long 0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
  229. .Lcr6: .long 0xff000000
  230. .Lloadp:.long 0,0
  231. .align 8
  232. .Lcrash:.long 0x000a0000,0x00000000
  233. .Lnewpsw:
  234. .long 0x00080000,0x80000000+.Lioint
  235. .Lwaitpsw:
  236. .long 0x020a0000,0x80000000+.Lioint
  237. .align 8
  238. .Lccws: .rept 19
  239. .long 0x02600050,0x00000000
  240. .endr
  241. .long 0x02200050,0x00000000
  242. #endif /* CONFIG_IPL_VM */
  243. iplstart:
  244. lh %r1,0xb8 # test if subchannel number
  245. bct %r1,.Lnoload # is valid
  246. l %r1,0xb8 # load ipl subchannel number
  247. la %r2,IPL_BS # load start address
  248. bas %r14,.Lloader # load rest of ipl image
  249. l %r12,.Lparm # pointer to parameter area
  250. st %r1,IPL_DEVICE-PARMAREA(%r12) # store ipl device number
  251. #
  252. # load parameter file from ipl device
  253. #
  254. .Lagain1:
  255. l %r2,INITRD_START-PARMAREA(%r12) # use ramdisk location as temp
  256. bas %r14,.Lloader # load parameter file
  257. ltr %r2,%r2 # got anything ?
  258. bz .Lnopf
  259. chi %r2,895
  260. bnh .Lnotrunc
  261. la %r2,895
  262. .Lnotrunc:
  263. l %r4,INITRD_START-PARMAREA(%r12)
  264. clc 0(3,%r4),.L_hdr # if it is HDRx
  265. bz .Lagain1 # skip dataset header
  266. clc 0(3,%r4),.L_eof # if it is EOFx
  267. bz .Lagain1 # skip dateset trailer
  268. la %r5,0(%r4,%r2)
  269. lr %r3,%r2
  270. .Lidebc:
  271. tm 0(%r5),0x80 # high order bit set ?
  272. bo .Ldocv # yes -> convert from EBCDIC
  273. ahi %r5,-1
  274. bct %r3,.Lidebc
  275. b .Lnocv
  276. .Ldocv:
  277. l %r3,.Lcvtab
  278. tr 0(256,%r4),0(%r3) # convert parameters to ascii
  279. tr 256(256,%r4),0(%r3)
  280. tr 512(256,%r4),0(%r3)
  281. tr 768(122,%r4),0(%r3)
  282. .Lnocv: la %r3,COMMAND_LINE-PARMAREA(%r12) # load adr. of command line
  283. mvc 0(256,%r3),0(%r4)
  284. mvc 256(256,%r3),256(%r4)
  285. mvc 512(256,%r3),512(%r4)
  286. mvc 768(122,%r3),768(%r4)
  287. slr %r0,%r0
  288. b .Lcntlp
  289. .Ldelspc:
  290. ic %r0,0(%r2,%r3)
  291. chi %r0,0x20 # is it a space ?
  292. be .Lcntlp
  293. ahi %r2,1
  294. b .Leolp
  295. .Lcntlp:
  296. brct %r2,.Ldelspc
  297. .Leolp:
  298. slr %r0,%r0
  299. stc %r0,0(%r2,%r3) # terminate buffer
  300. .Lnopf:
  301. #
  302. # load ramdisk from ipl device
  303. #
  304. .Lagain2:
  305. l %r2,INITRD_START-PARMAREA(%r12) # load adr. of ramdisk
  306. bas %r14,.Lloader # load ramdisk
  307. st %r2,INITRD_SIZE-PARMAREA(%r12) # store size of ramdisk
  308. ltr %r2,%r2
  309. bnz .Lrdcont
  310. st %r2,INITRD_START-PARMAREA(%r12) # no ramdisk found, null it
  311. .Lrdcont:
  312. l %r2,INITRD_START-PARMAREA(%r12)
  313. clc 0(3,%r2),.L_hdr # skip HDRx and EOFx
  314. bz .Lagain2
  315. clc 0(3,%r2),.L_eof
  316. bz .Lagain2
  317. #ifdef CONFIG_IPL_VM
  318. #
  319. # reset files in VM reader
  320. #
  321. stidp __LC_CPUID # store cpuid
  322. tm __LC_CPUID,0xff # running VM ?
  323. bno .Lnoreset
  324. la %r2,.Lreset
  325. lhi %r3,26
  326. .long 0x83230008
  327. .Lnoreset:
  328. #endif
  329. #
  330. # everything loaded, go for it
  331. #
  332. .Lnoload:
  333. l %r1,.Lstartup
  334. br %r1
  335. .Lparm: .long PARMAREA
  336. .Lstartup: .long startup
  337. .Lcvtab:.long _ebcasc # ebcdic to ascii table
  338. .Lreset:.byte 0xc3,0xc8,0xc1,0xd5,0xc7,0xc5,0x40,0xd9,0xc4,0xd9,0x40
  339. .byte 0xc1,0xd3,0xd3,0x40,0xd2,0xc5,0xc5,0xd7,0x40,0xd5,0xd6
  340. .byte 0xc8,0xd6,0xd3,0xc4 # "change rdr all keep nohold"
  341. .L_eof: .long 0xc5d6c600 /* C'EOF' */
  342. .L_hdr: .long 0xc8c4d900 /* C'HDR' */
  343. #endif /* CONFIG_IPL */
  344. #
  345. # SALIPL loader support. Based on a patch by Rob van der Heij.
  346. # This entry point is called directly from the SALIPL loader and
  347. # doesn't need a builtin ipl record.
  348. #
  349. .org 0x800
  350. .globl start
  351. start:
  352. stm %r0,%r15,0x07b0 # store registers
  353. basr %r12,%r0
  354. .base:
  355. l %r11,.parm
  356. l %r8,.cmd # pointer to command buffer
  357. ltr %r9,%r9 # do we have SALIPL parameters?
  358. bp .sk8x8
  359. mvc 0(64,%r8),0x00b0 # copy saved registers
  360. xc 64(240-64,%r8),0(%r8) # remainder of buffer
  361. tr 0(64,%r8),.lowcase
  362. b .gotr
  363. .sk8x8:
  364. mvc 0(240,%r8),0(%r9) # copy iplparms into buffer
  365. .gotr:
  366. l %r10,.tbl # EBCDIC to ASCII table
  367. tr 0(240,%r8),0(%r10)
  368. stidp __LC_CPUID # Are we running on VM maybe
  369. cli __LC_CPUID,0xff
  370. bnz .test
  371. .long 0x83300060 # diag 3,0,x'0060' - storage size
  372. b .done
  373. .test:
  374. mvc 0x68(8),.pgmnw # set up pgm check handler
  375. l %r2,.fourmeg
  376. lr %r3,%r2
  377. bctr %r3,%r0 # 4M-1
  378. .loop: iske %r0,%r3
  379. ar %r3,%r2
  380. .pgmx:
  381. sr %r3,%r2
  382. la %r3,1(%r3)
  383. .done:
  384. l %r1,.memsize
  385. st %r3,0(%r1)
  386. slr %r0,%r0
  387. st %r0,INITRD_SIZE-PARMAREA(%r11)
  388. st %r0,INITRD_START-PARMAREA(%r11)
  389. j startup # continue with startup
  390. .tbl: .long _ebcasc # translate table
  391. .cmd: .long COMMAND_LINE # address of command line buffer
  392. .parm: .long PARMAREA
  393. .memsize: .long memory_size
  394. .fourmeg: .long 0x00400000 # 4M
  395. .pgmnw: .long 0x00080000,.pgmx
  396. .lowcase:
  397. .byte 0x00,0x01,0x02,0x03,0x04,0x05,0x06,0x07
  398. .byte 0x08,0x09,0x0a,0x0b,0x0c,0x0d,0x0e,0x0f
  399. .byte 0x10,0x11,0x12,0x13,0x14,0x15,0x16,0x17
  400. .byte 0x18,0x19,0x1a,0x1b,0x1c,0x1d,0x1e,0x1f
  401. .byte 0x20,0x21,0x22,0x23,0x24,0x25,0x26,0x27
  402. .byte 0x28,0x29,0x2a,0x2b,0x2c,0x2d,0x2e,0x2f
  403. .byte 0x30,0x31,0x32,0x33,0x34,0x35,0x36,0x37
  404. .byte 0x38,0x39,0x3a,0x3b,0x3c,0x3d,0x3e,0x3f
  405. .byte 0x40,0x41,0x42,0x43,0x44,0x45,0x46,0x47
  406. .byte 0x48,0x49,0x4a,0x4b,0x4c,0x4d,0x4e,0x4f
  407. .byte 0x50,0x51,0x52,0x53,0x54,0x55,0x56,0x57
  408. .byte 0x58,0x59,0x5a,0x5b,0x5c,0x5d,0x5e,0x5f
  409. .byte 0x60,0x61,0x62,0x63,0x64,0x65,0x66,0x67
  410. .byte 0x68,0x69,0x6a,0x6b,0x6c,0x6d,0x6e,0x6f
  411. .byte 0x70,0x71,0x72,0x73,0x74,0x75,0x76,0x77
  412. .byte 0x78,0x79,0x7a,0x7b,0x7c,0x7d,0x7e,0x7f
  413. .byte 0x80,0x81,0x82,0x83,0x84,0x85,0x86,0x87
  414. .byte 0x88,0x89,0x8a,0x8b,0x8c,0x8d,0x8e,0x8f
  415. .byte 0x90,0x91,0x92,0x93,0x94,0x95,0x96,0x97
  416. .byte 0x98,0x99,0x9a,0x9b,0x9c,0x9d,0x9e,0x9f
  417. .byte 0xa0,0xa1,0xa2,0xa3,0xa4,0xa5,0xa6,0xa7
  418. .byte 0xa8,0xa9,0xaa,0xab,0xac,0xad,0xae,0xaf
  419. .byte 0xb0,0xb1,0xb2,0xb3,0xb4,0xb5,0xb6,0xb7
  420. .byte 0xb8,0xb9,0xba,0xbb,0xbc,0xbd,0xbe,0xbf
  421. .byte 0xc0,0x81,0x82,0x83,0x84,0x85,0x86,0x87 # .abcdefg
  422. .byte 0x88,0x89,0xca,0xcb,0xcc,0xcd,0xce,0xcf # hi
  423. .byte 0xd0,0x91,0x92,0x93,0x94,0x95,0x96,0x97 # .jklmnop
  424. .byte 0x98,0x99,0xda,0xdb,0xdc,0xdd,0xde,0xdf # qr
  425. .byte 0xe0,0xe1,0xa2,0xa3,0xa4,0xa5,0xa6,0xa7 # ..stuvwx
  426. .byte 0xa8,0xa9,0xea,0xeb,0xec,0xed,0xee,0xef # yz
  427. .byte 0xf0,0xf1,0xf2,0xf3,0xf4,0xf5,0xf6,0xf7
  428. .byte 0xf8,0xf9,0xfa,0xfb,0xfc,0xfd,0xfe,0xff
  429. #
  430. # startup-code at 0x10000, running in real mode
  431. # this is called either by the ipl loader or directly by PSW restart
  432. # or linload or SALIPL
  433. #
  434. .org 0x10000
  435. startup:basr %r13,0 # get base
  436. .LPG1: lctl %c0,%c15,.Lctl-.LPG1(%r13) # load control registers
  437. la %r12,_pstart-.LPG1(%r13) # pointer to parameter area
  438. # move IPL device to lowcore
  439. mvc __LC_IPLDEV(4),IPL_DEVICE-PARMAREA(%r12)
  440. #
  441. # clear bss memory
  442. #
  443. l %r2,.Lbss_bgn-.LPG1(%r13) # start of bss
  444. l %r3,.Lbss_end-.LPG1(%r13) # end of bss
  445. sr %r3,%r2 # length of bss
  446. sr %r4,%r4 #
  447. sr %r5,%r5 # set src,length and pad to zero
  448. sr %r0,%r0 #
  449. mvcle %r2,%r4,0 # clear mem
  450. jo .-4 # branch back, if not finish
  451. l %r2,.Lrcp-.LPG1(%r13) # Read SCP forced command word
  452. .Lservicecall:
  453. stosm .Lpmask-.LPG1(%r13),0x01 # authorize ext interrupts
  454. stctl %r0, %r0,.Lcr-.LPG1(%r13) # get cr0
  455. la %r1,0x200 # set bit 22
  456. o %r1,.Lcr-.LPG1(%r13) # or old cr0 with r1
  457. st %r1,.Lcr-.LPG1(%r13)
  458. lctl %r0, %r0,.Lcr-.LPG1(%r13) # load modified cr0
  459. mvc __LC_EXT_NEW_PSW(8),.Lpcext-.LPG1(%r13) # set postcall psw
  460. la %r1, .Lsclph-.LPG1(%r13)
  461. a %r1,__LC_EXT_NEW_PSW+4 # set handler
  462. st %r1,__LC_EXT_NEW_PSW+4
  463. la %r4,_pstart-.LPG1(%r13) # %r4 is our index for sccb stuff
  464. la %r1, .Lsccb-PARMAREA(%r4) # our sccb
  465. .insn rre,0xb2200000,%r2,%r1 # service call
  466. ipm %r1
  467. srl %r1,28 # get cc code
  468. xr %r3, %r3
  469. chi %r1,3
  470. be .Lfchunk-.LPG1(%r13) # leave
  471. chi %r1,2
  472. be .Lservicecall-.LPG1(%r13)
  473. lpsw .Lwaitsclp-.LPG1(%r13)
  474. .Lsclph:
  475. lh %r1,.Lsccbr-PARMAREA(%r4)
  476. chi %r1,0x10 # 0x0010 is the sucess code
  477. je .Lprocsccb # let's process the sccb
  478. chi %r1,0x1f0
  479. bne .Lfchunk-.LPG1(%r13) # unhandled error code
  480. c %r2, .Lrcp-.LPG1(%r13) # Did we try Read SCP forced
  481. bne .Lfchunk-.LPG1(%r13) # if no, give up
  482. l %r2, .Lrcp2-.LPG1(%r13) # try with Read SCP
  483. b .Lservicecall-.LPG1(%r13)
  484. .Lprocsccb:
  485. lh %r1,.Lscpincr1-PARMAREA(%r4) # use this one if != 0
  486. chi %r1,0x00
  487. jne .Lscnd
  488. l %r1,.Lscpincr2-PARMAREA(%r4) # otherwise use this one
  489. .Lscnd:
  490. xr %r3,%r3 # same logic
  491. ic %r3,.Lscpa1-PARMAREA(%r4)
  492. chi %r3,0x00
  493. jne .Lcompmem
  494. l %r3,.Lscpa2-PARMAREA(%r13)
  495. .Lcompmem:
  496. mr %r2,%r1 # mem in MB on 128-bit
  497. l %r1,.Lonemb-.LPG1(%r13)
  498. mr %r2,%r1 # mem size in bytes in %r3
  499. b .Lfchunk-.LPG1(%r13)
  500. .Lpmask:
  501. .byte 0
  502. .align 8
  503. .Lpcext:.long 0x00080000,0x80000000
  504. .Lcr:
  505. .long 0x00 # place holder for cr0
  506. .Lwaitsclp:
  507. .long 0x020A0000
  508. .long .Lsclph
  509. .Lrcp:
  510. .int 0x00120001 # Read SCP forced code
  511. .Lrcp2:
  512. .int 0x00020001 # Read SCP code
  513. .Lonemb:
  514. .int 0x100000
  515. .Lfchunk:
  516. #
  517. # find memory chunks.
  518. #
  519. lr %r9,%r3 # end of mem
  520. mvc __LC_PGM_NEW_PSW(8),.Lpcmem-.LPG1(%r13)
  521. la %r1,1 # test in increments of 128KB
  522. sll %r1,17
  523. l %r3,.Lmchunk-.LPG1(%r13) # get pointer to memory_chunk array
  524. slr %r4,%r4 # set start of chunk to zero
  525. slr %r5,%r5 # set end of chunk to zero
  526. slr %r6,%r6 # set access code to zero
  527. la %r10, MEMORY_CHUNKS # number of chunks
  528. .Lloop:
  529. tprot 0(%r5),0 # test protection of first byte
  530. ipm %r7
  531. srl %r7,28
  532. clr %r6,%r7 # compare cc with last access code
  533. be .Lsame-.LPG1(%r13)
  534. b .Lchkmem-.LPG1(%r13)
  535. .Lsame:
  536. ar %r5,%r1 # add 128KB to end of chunk
  537. bno .Lloop-.LPG1(%r13) # r1 < 0x80000000 -> loop
  538. .Lchkmem: # > 2GB or tprot got a program check
  539. clr %r4,%r5 # chunk size > 0?
  540. be .Lchkloop-.LPG1(%r13)
  541. st %r4,0(%r3) # store start address of chunk
  542. lr %r0,%r5
  543. slr %r0,%r4
  544. st %r0,4(%r3) # store size of chunk
  545. st %r6,8(%r3) # store type of chunk
  546. la %r3,12(%r3)
  547. l %r4,.Lmemsize-.LPG1(%r13) # address of variable memory_size
  548. st %r5,0(%r4) # store last end to memory size
  549. ahi %r10,-1 # update chunk number
  550. .Lchkloop:
  551. lr %r6,%r7 # set access code to last cc
  552. # we got an exception or we're starting a new
  553. # chunk , we must check if we should
  554. # still try to find valid memory (if we detected
  555. # the amount of available storage), and if we
  556. # have chunks left
  557. xr %r0,%r0
  558. clr %r0,%r9 # did we detect memory?
  559. je .Ldonemem # if not, leave
  560. chi %r10,0 # do we have chunks left?
  561. je .Ldonemem
  562. alr %r5,%r1 # add 128KB to end of chunk
  563. lr %r4,%r5 # potential new chunk
  564. clr %r5,%r9 # should we go on?
  565. jl .Lloop
  566. .Ldonemem:
  567. l %r12,.Lmflags-.LPG1(%r13) # get address of machine_flags
  568. #
  569. # find out if we are running under VM
  570. #
  571. stidp __LC_CPUID # store cpuid
  572. tm __LC_CPUID,0xff # running under VM ?
  573. bno .Lnovm-.LPG1(%r13)
  574. oi 3(%r12),1 # set VM flag
  575. .Lnovm:
  576. lh %r0,__LC_CPUID+4 # get cpu version
  577. chi %r0,0x7490 # running on a P/390 ?
  578. bne .Lnop390-.LPG1(%r13)
  579. oi 3(%r12),4 # set P/390 flag
  580. .Lnop390:
  581. #
  582. # find out if we have an IEEE fpu
  583. #
  584. mvc __LC_PGM_NEW_PSW(8),.Lpcfpu-.LPG1(%r13)
  585. efpc %r0,0 # test IEEE extract fpc instruction
  586. oi 3(%r12),2 # set IEEE fpu flag
  587. .Lchkfpu:
  588. #
  589. # find out if we have the CSP instruction
  590. #
  591. mvc __LC_PGM_NEW_PSW(8),.Lpccsp-.LPG1(%r13)
  592. la %r0,0
  593. lr %r1,%r0
  594. la %r2,4
  595. csp %r0,%r2 # Test CSP instruction
  596. oi 3(%r12),8 # set CSP flag
  597. .Lchkcsp:
  598. #
  599. # find out if we have the MVPG instruction
  600. #
  601. mvc __LC_PGM_NEW_PSW(8),.Lpcmvpg-.LPG1(%r13)
  602. sr %r0,%r0
  603. la %r1,0
  604. la %r2,0
  605. mvpg %r1,%r2 # Test CSP instruction
  606. oi 3(%r12),16 # set MVPG flag
  607. .Lchkmvpg:
  608. #
  609. # find out if we have the IDTE instruction
  610. #
  611. mvc __LC_PGM_NEW_PSW(8),.Lpcidte-.LPG1(%r13)
  612. .long 0xb2b10000 # store facility list
  613. tm 0xc8,0x08 # check bit for clearing-by-ASCE
  614. bno .Lchkidte-.LPG1(%r13)
  615. lhi %r1,2094
  616. lhi %r2,0
  617. .long 0xb98e2001
  618. oi 3(%r12),0x80 # set IDTE flag
  619. .Lchkidte:
  620. lpsw .Lentry-.LPG1(13) # jump to _stext in primary-space,
  621. # virtual and never return ...
  622. .align 8
  623. .Lentry:.long 0x00080000,0x80000000 + _stext
  624. .Lctl: .long 0x04b50002 # cr0: various things
  625. .long 0 # cr1: primary space segment table
  626. .long .Lduct # cr2: dispatchable unit control table
  627. .long 0 # cr3: instruction authorization
  628. .long 0 # cr4: instruction authorization
  629. .long 0xffffffff # cr5: primary-aste origin
  630. .long 0 # cr6: I/O interrupts
  631. .long 0 # cr7: secondary space segment table
  632. .long 0 # cr8: access registers translation
  633. .long 0 # cr9: tracing off
  634. .long 0 # cr10: tracing off
  635. .long 0 # cr11: tracing off
  636. .long 0 # cr12: tracing off
  637. .long 0 # cr13: home space segment table
  638. .long 0xc0000000 # cr14: machine check handling off
  639. .long 0 # cr15: linkage stack operations
  640. .Lpcmem:.long 0x00080000,0x80000000 + .Lchkmem
  641. .Lpcfpu:.long 0x00080000,0x80000000 + .Lchkfpu
  642. .Lpccsp:.long 0x00080000,0x80000000 + .Lchkcsp
  643. .Lpcmvpg:.long 0x00080000,0x80000000 + .Lchkmvpg
  644. .Lpcidte:.long 0x00080000,0x80000000 + .Lchkidte
  645. .Lmemsize:.long memory_size
  646. .Lmchunk:.long memory_chunk
  647. .Lmflags:.long machine_flags
  648. .Lbss_bgn: .long __bss_start
  649. .Lbss_end: .long _end
  650. .org PARMAREA-64
  651. .Lduct: .long 0,0,0,0,0,0,0,0
  652. .long 0,0,0,0,0,0,0,0
  653. #
  654. # params at 10400 (setup.h)
  655. #
  656. .org PARMAREA
  657. .global _pstart
  658. _pstart:
  659. .long 0,0 # IPL_DEVICE
  660. .long 0,RAMDISK_ORIGIN # INITRD_START
  661. .long 0,RAMDISK_SIZE # INITRD_SIZE
  662. .org COMMAND_LINE
  663. .byte "root=/dev/ram0 ro"
  664. .byte 0
  665. .org 0x11000
  666. .Lsccb:
  667. .hword 0x1000 # length, one page
  668. .byte 0x00,0x00,0x00
  669. .byte 0x80 # variable response bit set
  670. .Lsccbr:
  671. .hword 0x00 # response code
  672. .Lscpincr1:
  673. .hword 0x00
  674. .Lscpa1:
  675. .byte 0x00
  676. .fill 89,1,0
  677. .Lscpa2:
  678. .int 0x00
  679. .Lscpincr2:
  680. .quad 0x00
  681. .fill 3984,1,0
  682. .org 0x12000
  683. .global _pend
  684. _pend:
  685. #ifdef CONFIG_SHARED_KERNEL
  686. .org 0x100000
  687. #endif
  688. #
  689. # startup-code, running in virtual mode
  690. #
  691. .globl _stext
  692. _stext: basr %r13,0 # get base
  693. .LPG2:
  694. #
  695. # Setup stack
  696. #
  697. l %r15,.Linittu-.LPG2(%r13)
  698. mvc __LC_CURRENT(4),__TI_task(%r15)
  699. ahi %r15,1<<(PAGE_SHIFT+THREAD_ORDER) # init_task_union + THREAD_SIZE
  700. st %r15,__LC_KERNEL_STACK # set end of kernel stack
  701. ahi %r15,-96
  702. xc __SF_BACKCHAIN(4,%r15),__SF_BACKCHAIN(%r15) # clear backchain
  703. # check control registers
  704. stctl %c0,%c15,0(%r15)
  705. oi 2(%r15),0x20 # enable sigp external interrupts
  706. oi 0(%r15),0x10 # switch on low address protection
  707. lctl %c0,%c15,0(%r15)
  708. #
  709. lam 0,15,.Laregs-.LPG2(%r13) # load access regs needed by uaccess
  710. l %r14,.Lstart-.LPG2(%r13)
  711. basr %r14,%r14 # call start_kernel
  712. #
  713. # We returned from start_kernel ?!? PANIK
  714. #
  715. basr %r13,0
  716. lpsw .Ldw-.(%r13) # load disabled wait psw
  717. #
  718. .align 8
  719. .Ldw: .long 0x000a0000,0x00000000
  720. .Linittu: .long init_thread_union
  721. .Lstart: .long start_kernel
  722. .Laregs: .long 0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0