/src/clj/clojure/template.clj

;   Copyright (c) Rich Hickey. All rights reserved.

;   The use and distribution terms for this software are covered by the

;   Eclipse Public License 1.0 (http://opensource.org/licenses/eclipse-1.0.php)

;   which can be found in the file epl-v10.html at the root of this distribution.

;   By using this software in any fashion, you are agreeing to be bound by

;   the terms of this license.

;   You must not remove this notice, or any other, from this software.



;;; template.clj - anonymous functions that pre-evaluate sub-expressions



;; By Stuart Sierra

;; June 23, 2009



;; CHANGE LOG

;;

;; June 23, 2009: complete rewrite, eliminated _1,_2,... argument

;; syntax

;;

;; January 20, 2009: added "template?" and checks for valid template

;; expressions.

;;

;; December 15, 2008: first version





(ns ^{:doc "Macros that expand to repeated copies of a template expression."

       :author "Stuart Sierra"}

  clojure.template

  (:require [clojure.walk :as walk]))



(defn apply-template

  "For use in macros.  argv is an argument list, as in defn.  expr is

  a quoted expression using the symbols in argv.  values is a sequence

  of values to be used for the arguments.



  apply-template will recursively replace argument symbols in expr

  with their corresponding values, returning a modified expr.



  Example: (apply-template '[x] '(+ x x) '[2])

           ;=> (+ 2 2)"

  [argv expr values]

  (assert (vector? argv))

  (assert (every? symbol? argv))

  (walk/prewalk-replace (zipmap argv values) expr))



(defmacro do-template

  "Repeatedly copies expr (in a do block) for each group of arguments

  in values.  values are automatically partitioned by the number of

  arguments in argv, an argument vector as in defn.



  Example: (macroexpand '(do-template [x y] (+ y x) 2 4 3 5))

           ;=> (do (+ 4 2) (+ 5 3))"

  [argv expr & values]

  (let [c (count argv)]

    `(do ~@(map (fn [a] (apply-template argv expr a)) 

                (partition c values)))))