/samples/custom_shader/noise.html
HTML | 250 lines | 204 code | 46 blank | 0 comment | 0 complexity | 2b0bfcb0df99349780e08d0bbbd446ff MD5 | raw file
- <!DOCTYPE html PUBLIC "-//W3C//DTD HTML 4.01//EN">
- <html>
-
- <head>
- <title>
- CubicVR.js: Custom Material Shader using GLSL perlin noise by Stefan Gustavson
- </title>
- <script src="../../CubicVR.js" type="text/javascript">
- </script>
- <script id="vs" type="x-shader/x-vertex">
- uniform float myTimer;
-
- void main(void)
- {
- vertexTexCoordOut = cubicvr_texCoord();
-
- gl_Position = matrixProjection * matrixModelView * cubicvr_transform();
- vertexNormalOut = matrixNormal * cubicvr_normal();
- cubicvr_lighting();
- }
- </script>
- <script id="fs" type="x-shader/x-fragment">
- uniform float myTimer;
- //
- // GLSL textureless classic 3D noise "cnoise",
- // with an RSL-style periodic variant "pnoise".
- // Author: Stefan Gustavson (stefan.gustavson@liu.se)
- // Version: 2011-08-22
- //
- // Many thanks to Ian McEwan of Ashima Arts for the
- // ideas for permutation and gradient selection.
- //
- // Copyright (c) 2011 Stefan Gustavson. All rights reserved.
- // Distributed under the MIT license. See LICENSE file.
- // https://github.com/ashima/webgl-noise
- //
- vec4 mod289(vec4 x)
- {
- return x - floor(x * (1.0 / 289.0)) * 289.0;
- }
-
- vec3 mod289(vec3 x)
- {
- return x - floor(x * (1.0 / 289.0)) * 289.0;
- }
- vec4 permute(vec4 x)
- {
- return mod289(((x*34.0)+1.0)*x);
- }
- vec4 taylorInvSqrt(vec4 r)
- {
- return 1.79284291400159 - 0.85373472095314 * r;
- }
- vec3 fade(vec3 t) {
- return t*t*t*(t*(t*6.0-15.0)+10.0);
- }
- // Classic Perlin noise
- float cnoise(vec3 P)
- {
- vec3 Pi0 = floor(P); // Integer part for indexing
- vec3 Pi1 = Pi0 + vec3(1.0); // Integer part + 1
- Pi0 = mod289(Pi0);
- Pi1 = mod289(Pi1);
- vec3 Pf0 = fract(P); // Fractional part for interpolation
- vec3 Pf1 = Pf0 - vec3(1.0); // Fractional part - 1.0
- vec4 ix = vec4(Pi0.x, Pi1.x, Pi0.x, Pi1.x);
- vec4 iy = vec4(Pi0.yy, Pi1.yy);
- vec4 iz0 = Pi0.zzzz;
- vec4 iz1 = Pi1.zzzz;
- vec4 ixy = permute(permute(ix) + iy);
- vec4 ixy0 = permute(ixy + iz0);
- vec4 ixy1 = permute(ixy + iz1);
- vec4 gx0 = ixy0 * (1.0 / 7.0);
- vec4 gy0 = fract(floor(gx0) * (1.0 / 7.0)) - 0.5;
- gx0 = fract(gx0);
- vec4 gz0 = vec4(0.5) - abs(gx0) - abs(gy0);
- vec4 sz0 = step(gz0, vec4(0.0));
- gx0 -= sz0 * (step(0.0, gx0) - 0.5);
- gy0 -= sz0 * (step(0.0, gy0) - 0.5);
- vec4 gx1 = ixy1 * (1.0 / 7.0);
- vec4 gy1 = fract(floor(gx1) * (1.0 / 7.0)) - 0.5;
- gx1 = fract(gx1);
- vec4 gz1 = vec4(0.5) - abs(gx1) - abs(gy1);
- vec4 sz1 = step(gz1, vec4(0.0));
- gx1 -= sz1 * (step(0.0, gx1) - 0.5);
- gy1 -= sz1 * (step(0.0, gy1) - 0.5);
- vec3 g000 = vec3(gx0.x,gy0.x,gz0.x);
- vec3 g100 = vec3(gx0.y,gy0.y,gz0.y);
- vec3 g010 = vec3(gx0.z,gy0.z,gz0.z);
- vec3 g110 = vec3(gx0.w,gy0.w,gz0.w);
- vec3 g001 = vec3(gx1.x,gy1.x,gz1.x);
- vec3 g101 = vec3(gx1.y,gy1.y,gz1.y);
- vec3 g011 = vec3(gx1.z,gy1.z,gz1.z);
- vec3 g111 = vec3(gx1.w,gy1.w,gz1.w);
- vec4 norm0 = taylorInvSqrt(vec4(dot(g000, g000), dot(g010, g010), dot(g100, g100), dot(g110, g110)));
- g000 *= norm0.x;
- g010 *= norm0.y;
- g100 *= norm0.z;
- g110 *= norm0.w;
- vec4 norm1 = taylorInvSqrt(vec4(dot(g001, g001), dot(g011, g011), dot(g101, g101), dot(g111, g111)));
- g001 *= norm1.x;
- g011 *= norm1.y;
- g101 *= norm1.z;
- g111 *= norm1.w;
- float n000 = dot(g000, Pf0);
- float n100 = dot(g100, vec3(Pf1.x, Pf0.yz));
- float n010 = dot(g010, vec3(Pf0.x, Pf1.y, Pf0.z));
- float n110 = dot(g110, vec3(Pf1.xy, Pf0.z));
- float n001 = dot(g001, vec3(Pf0.xy, Pf1.z));
- float n101 = dot(g101, vec3(Pf1.x, Pf0.y, Pf1.z));
- float n011 = dot(g011, vec3(Pf0.x, Pf1.yz));
- float n111 = dot(g111, Pf1);
- vec3 fade_xyz = fade(Pf0);
- vec4 n_z = mix(vec4(n000, n100, n010, n110), vec4(n001, n101, n011, n111), fade_xyz.z);
- vec2 n_yz = mix(n_z.xy, n_z.zw, fade_xyz.y);
- float n_xyz = mix(n_yz.x, n_yz.y, fade_xyz.x);
- return 2.2 * n_xyz;
- }
-
- void main(void)
- {
- vec2 texCoord = cubicvr_texCoord();
-
- float q = myTimer+100.0;
- float texScale = 20.0;
- float rnoise = cnoise(vec3((texCoord-0.5)*texScale,q*0.65));
- float gnoise = cnoise(vec3((texCoord-0.5)*texScale,q*-0.7));
- float bnoise = cnoise(vec3((texCoord-0.5)*texScale,q*0.8));
-
- vec4 color = vec4(rnoise/2.0,gnoise,bnoise,1.0); // use half of red
-
- vec3 normal = cubicvr_normal(texCoord);
-
- color = cubicvr_environment(color,normal,texCoord);
- color = cubicvr_lighting(color,normal,texCoord);
- color.r += rnoise/2.0; // add half red back in after lighting
- gl_FragColor = clamp(color,0.0,1.0);
- }
- </script>
- <script type='text/javascript'>
-
- function webGLStart() {
- // by default generate a full screen canvas with automatic resize
- var gl = CubicVR.init();
- var canvas = CubicVR.getCanvas();
- if (!gl) {
- alert("Sorry, no WebGL support.");
- return;
- };
- var myShader = new CubicVR.CustomShader({
- vertex: "#vs",
- fragment: "#fs",
- init: function(shader) {
- shader.myTimer.set(0); // not needed, just here for example purposes
- }
- });
- // Create a box mesh, size 1.0, apply material and UV parameters
- var boxMesh = new CubicVR.Mesh({
- primitive: {
- type: "box",
- size: 1.5,
- material: {
- shader: myShader
- },
- uvmapper: {
- projectionMode: CubicVR.enums.uv.projection.CUBIC,
- scale: [1, 1, 1]
- }
- },
- compile: true
- });
- // New scene with our canvas dimensions and default camera with FOV 80
- var scene = new CubicVR.Scene(canvas.width, canvas.height, 80);
- // set initial camera position and target
- scene.camera.position = [1, 1, 1];
- scene.camera.target = [0, 0, 0];
- // Add a simple directional light
- scene.bind(new CubicVR.Light({
- type: "directional",
- specular: [1, 1, 1],
- direction: [-0.6, -0.5, 0.6],
- }));
-
- CubicVR.setGlobalAmbient([0.1,0.1,0.1]);
-
-
- // SceneObject container for the mesh
- var boxObject = new CubicVR.SceneObject(boxMesh);
-
- // encapsulate the rotation in a sceneobject TICK event
- var boxEvent = boxObject.addEvent({
- id: "tick",
- action:function(event,evh) {
- var lus = event.getLastUpdateSeconds();
- var sceneObj = event.getSubject();
-
- if (myShader.isReady()) {
- myShader.myTimer.value = event.getSeconds();
- }
-
- sceneObj.rotation[0]+=lus*15.0;
- sceneObj.rotation[2]+=lus*13.0;
- }
- });
- // Add SceneObject containing the mesh to the scene
- scene.bind(boxObject);
- // Add our scene to the window resize list
- CubicVR.addResizeable(scene);
- // Start our main drawing loop, it provides a timer and the gl context as parameters
- CubicVR.MainLoop(function(timer, gl) {
- scene.render();
- scene.runEvents(timer.getSeconds());
- });
- // initialize a mouse view controller
- var mvc = new CubicVR.MouseViewController(canvas, scene.camera);
- }
- </script>
- </head>
-
- <body onLoad="webGLStart();"></body>
- </html>