/media/libvpx/vp8/common/arm/neon/bilinearpredict8x8_neon.asm

http://github.com/zpao/v8monkey · Assembly · 183 lines · 128 code · 34 blank · 21 comment · 0 complexity · ee06f1b3f6424b4555141d2b9a9f32c9 MD5 · raw file

  1. ;
  2. ; Copyright (c) 2010 The WebM project authors. All Rights Reserved.
  3. ;
  4. ; Use of this source code is governed by a BSD-style license
  5. ; that can be found in the LICENSE file in the root of the source
  6. ; tree. An additional intellectual property rights grant can be found
  7. ; in the file PATENTS. All contributing project authors may
  8. ; be found in the AUTHORS file in the root of the source tree.
  9. ;
  10. EXPORT |vp8_bilinear_predict8x8_neon|
  11. ARM
  12. REQUIRE8
  13. PRESERVE8
  14. AREA ||.text||, CODE, READONLY, ALIGN=2
  15. ; r0 unsigned char *src_ptr,
  16. ; r1 int src_pixels_per_line,
  17. ; r2 int xoffset,
  18. ; r3 int yoffset,
  19. ; r4 unsigned char *dst_ptr,
  20. ; stack(lr) int dst_pitch
  21. |vp8_bilinear_predict8x8_neon| PROC
  22. push {r4, lr}
  23. adr r12, bifilter8_coeff
  24. ldr r4, [sp, #8] ;load parameters from stack
  25. ldr lr, [sp, #12] ;load parameters from stack
  26. cmp r2, #0 ;skip first_pass filter if xoffset=0
  27. beq skip_firstpass_filter
  28. ;First pass: output_height lines x output_width columns (9x8)
  29. add r2, r12, r2, lsl #3 ;calculate filter location
  30. vld1.u8 {q1}, [r0], r1 ;load src data
  31. vld1.u32 {d31}, [r2] ;load first_pass filter
  32. vld1.u8 {q2}, [r0], r1
  33. vdup.8 d0, d31[0] ;first_pass filter (d0 d1)
  34. vld1.u8 {q3}, [r0], r1
  35. vdup.8 d1, d31[4]
  36. vld1.u8 {q4}, [r0], r1
  37. vmull.u8 q6, d2, d0 ;(src_ptr[0] * vp8_filter[0])
  38. vmull.u8 q7, d4, d0
  39. vmull.u8 q8, d6, d0
  40. vmull.u8 q9, d8, d0
  41. vext.8 d3, d2, d3, #1 ;construct src_ptr[-1]
  42. vext.8 d5, d4, d5, #1
  43. vext.8 d7, d6, d7, #1
  44. vext.8 d9, d8, d9, #1
  45. vmlal.u8 q6, d3, d1 ;(src_ptr[1] * vp8_filter[1])
  46. vmlal.u8 q7, d5, d1
  47. vmlal.u8 q8, d7, d1
  48. vmlal.u8 q9, d9, d1
  49. vld1.u8 {q1}, [r0], r1 ;load src data
  50. vqrshrn.u16 d22, q6, #7 ;shift/round/saturate to u8
  51. vld1.u8 {q2}, [r0], r1
  52. vqrshrn.u16 d23, q7, #7
  53. vld1.u8 {q3}, [r0], r1
  54. vqrshrn.u16 d24, q8, #7
  55. vld1.u8 {q4}, [r0], r1
  56. vqrshrn.u16 d25, q9, #7
  57. ;first_pass filtering on the rest 5-line data
  58. vld1.u8 {q5}, [r0], r1
  59. vmull.u8 q6, d2, d0 ;(src_ptr[0] * vp8_filter[0])
  60. vmull.u8 q7, d4, d0
  61. vmull.u8 q8, d6, d0
  62. vmull.u8 q9, d8, d0
  63. vmull.u8 q10, d10, d0
  64. vext.8 d3, d2, d3, #1 ;construct src_ptr[-1]
  65. vext.8 d5, d4, d5, #1
  66. vext.8 d7, d6, d7, #1
  67. vext.8 d9, d8, d9, #1
  68. vext.8 d11, d10, d11, #1
  69. vmlal.u8 q6, d3, d1 ;(src_ptr[1] * vp8_filter[1])
  70. vmlal.u8 q7, d5, d1
  71. vmlal.u8 q8, d7, d1
  72. vmlal.u8 q9, d9, d1
  73. vmlal.u8 q10, d11, d1
  74. vqrshrn.u16 d26, q6, #7 ;shift/round/saturate to u8
  75. vqrshrn.u16 d27, q7, #7
  76. vqrshrn.u16 d28, q8, #7
  77. vqrshrn.u16 d29, q9, #7
  78. vqrshrn.u16 d30, q10, #7
  79. ;Second pass: 8x8
  80. secondpass_filter
  81. cmp r3, #0 ;skip second_pass filter if yoffset=0
  82. beq skip_secondpass_filter
  83. add r3, r12, r3, lsl #3
  84. add r0, r4, lr
  85. vld1.u32 {d31}, [r3] ;load second_pass filter
  86. add r1, r0, lr
  87. vdup.8 d0, d31[0] ;second_pass filter parameters (d0 d1)
  88. vdup.8 d1, d31[4]
  89. vmull.u8 q1, d22, d0 ;(src_ptr[0] * vp8_filter[0])
  90. vmull.u8 q2, d23, d0
  91. vmull.u8 q3, d24, d0
  92. vmull.u8 q4, d25, d0
  93. vmull.u8 q5, d26, d0
  94. vmull.u8 q6, d27, d0
  95. vmull.u8 q7, d28, d0
  96. vmull.u8 q8, d29, d0
  97. vmlal.u8 q1, d23, d1 ;(src_ptr[pixel_step] * vp8_filter[1])
  98. vmlal.u8 q2, d24, d1
  99. vmlal.u8 q3, d25, d1
  100. vmlal.u8 q4, d26, d1
  101. vmlal.u8 q5, d27, d1
  102. vmlal.u8 q6, d28, d1
  103. vmlal.u8 q7, d29, d1
  104. vmlal.u8 q8, d30, d1
  105. vqrshrn.u16 d2, q1, #7 ;shift/round/saturate to u8
  106. vqrshrn.u16 d3, q2, #7
  107. vqrshrn.u16 d4, q3, #7
  108. vqrshrn.u16 d5, q4, #7
  109. vqrshrn.u16 d6, q5, #7
  110. vqrshrn.u16 d7, q6, #7
  111. vqrshrn.u16 d8, q7, #7
  112. vqrshrn.u16 d9, q8, #7
  113. vst1.u8 {d2}, [r4] ;store result
  114. vst1.u8 {d3}, [r0]
  115. vst1.u8 {d4}, [r1], lr
  116. vst1.u8 {d5}, [r1], lr
  117. vst1.u8 {d6}, [r1], lr
  118. vst1.u8 {d7}, [r1], lr
  119. vst1.u8 {d8}, [r1], lr
  120. vst1.u8 {d9}, [r1], lr
  121. pop {r4, pc}
  122. ;--------------------
  123. skip_firstpass_filter
  124. vld1.u8 {d22}, [r0], r1 ;load src data
  125. vld1.u8 {d23}, [r0], r1
  126. vld1.u8 {d24}, [r0], r1
  127. vld1.u8 {d25}, [r0], r1
  128. vld1.u8 {d26}, [r0], r1
  129. vld1.u8 {d27}, [r0], r1
  130. vld1.u8 {d28}, [r0], r1
  131. vld1.u8 {d29}, [r0], r1
  132. vld1.u8 {d30}, [r0], r1
  133. b secondpass_filter
  134. ;---------------------
  135. skip_secondpass_filter
  136. vst1.u8 {d22}, [r4], lr ;store result
  137. vst1.u8 {d23}, [r4], lr
  138. vst1.u8 {d24}, [r4], lr
  139. vst1.u8 {d25}, [r4], lr
  140. vst1.u8 {d26}, [r4], lr
  141. vst1.u8 {d27}, [r4], lr
  142. vst1.u8 {d28}, [r4], lr
  143. vst1.u8 {d29}, [r4], lr
  144. pop {r4, pc}
  145. ENDP
  146. ;-----------------
  147. bifilter8_coeff
  148. DCD 128, 0, 112, 16, 96, 32, 80, 48, 64, 64, 48, 80, 32, 96, 16, 112
  149. END