/media/libvpx/vp8/encoder/arm/armv5te/vp8_packtokens_mbrow_armv5.asm

http://github.com/zpao/v8monkey · Assembly · 327 lines · 234 code · 60 blank · 33 comment · 0 complexity · 398704bf05e1b31e95acb79a331c97ec MD5 · raw file

  1. ;
  2. ; Copyright (c) 2010 The WebM project authors. All Rights Reserved.
  3. ;
  4. ; Use of this source code is governed by a BSD-style license
  5. ; that can be found in the LICENSE file in the root of the source
  6. ; tree. An additional intellectual property rights grant can be found
  7. ; in the file PATENTS. All contributing project authors may
  8. ; be found in the AUTHORS file in the root of the source tree.
  9. ;
  10. EXPORT |vp8cx_pack_mb_row_tokens_armv5|
  11. INCLUDE asm_enc_offsets.asm
  12. ARM
  13. REQUIRE8
  14. PRESERVE8
  15. AREA |.text|, CODE, READONLY
  16. ; r0 VP8_COMP *cpi
  17. ; r1 vp8_writer *w
  18. ; r2 vp8_coef_encodings
  19. ; r3 vp8_extra_bits
  20. ; s0 vp8_coef_tree
  21. |vp8cx_pack_mb_row_tokens_armv5| PROC
  22. push {r4-r11, lr}
  23. sub sp, sp, #24
  24. ; Compute address of cpi->common.mb_rows
  25. ldr r4, _VP8_COMP_common_
  26. ldr r6, _VP8_COMMON_MBrows_
  27. add r4, r0, r4
  28. ldr r5, [r4, r6] ; load up mb_rows
  29. str r2, [sp, #20] ; save vp8_coef_encodings
  30. str r5, [sp, #12] ; save mb_rows
  31. str r3, [sp, #8] ; save vp8_extra_bits
  32. ldr r4, _VP8_COMP_tplist_
  33. add r4, r0, r4
  34. ldr r7, [r4, #0] ; dereference cpi->tp_list
  35. mov r0, r1 ; keep same as other loops
  36. ldr r2, [r0, #vp8_writer_lowvalue]
  37. ldr r5, [r0, #vp8_writer_range]
  38. ldr r3, [r0, #vp8_writer_count]
  39. mb_row_loop
  40. ldr r1, [r7, #tokenlist_start]
  41. ldr r9, [r7, #tokenlist_stop]
  42. str r9, [sp, #0] ; save stop for later comparison
  43. str r7, [sp, #16] ; tokenlist address for next time
  44. b check_p_lt_stop
  45. ; actuall work gets done here!
  46. while_p_lt_stop
  47. ldrb r6, [r1, #tokenextra_token] ; t
  48. ldr r4, [sp, #20] ; vp8_coef_encodings
  49. mov lr, #0
  50. add r4, r4, r6, lsl #3 ; a = vp8_coef_encodings + t
  51. ldr r9, [r1, #tokenextra_context_tree] ; pp
  52. ldrb r7, [r1, #tokenextra_skip_eob_node]
  53. ldr r6, [r4, #vp8_token_value] ; v
  54. ldr r8, [r4, #vp8_token_len] ; n
  55. ; vp8 specific skip_eob_node
  56. cmp r7, #0
  57. movne lr, #2 ; i = 2
  58. subne r8, r8, #1 ; --n
  59. rsb r4, r8, #32 ; 32-n
  60. ldr r10, [sp, #60] ; vp8_coef_tree
  61. ; v is kept in r12 during the token pack loop
  62. lsl r12, r6, r4 ; r12 = v << 32 - n
  63. ; loop start
  64. token_loop
  65. ldrb r4, [r9, lr, asr #1] ; pp [i>>1]
  66. sub r7, r5, #1 ; range-1
  67. ; Decisions are made based on the bit value shifted
  68. ; off of v, so set a flag here based on this.
  69. ; This value is refered to as "bb"
  70. lsls r12, r12, #1 ; bb = v >> n
  71. mul r4, r4, r7 ; ((range-1) * pp[i>>1]))
  72. ; bb can only be 0 or 1. So only execute this statement
  73. ; if bb == 1, otherwise it will act like i + 0
  74. addcs lr, lr, #1 ; i + bb
  75. mov r7, #1
  76. ldrsb lr, [r10, lr] ; i = vp8_coef_tree[i+bb]
  77. add r4, r7, r4, lsr #8 ; 1 + (((range-1) * pp[i>>1]) >> 8)
  78. addcs r2, r2, r4 ; if (bb) lowvalue += split
  79. subcs r4, r5, r4 ; if (bb) range = range-split
  80. ; Counting the leading zeros is used to normalize range.
  81. clz r6, r4
  82. sub r6, r6, #24 ; shift
  83. ; Flag is set on the sum of count. This flag is used later
  84. ; to determine if count >= 0
  85. adds r3, r3, r6 ; count += shift
  86. lsl r5, r4, r6 ; range <<= shift
  87. bmi token_count_lt_zero ; if(count >= 0)
  88. sub r6, r6, r3 ; offset = shift - count
  89. sub r4, r6, #1 ; offset-1
  90. lsls r4, r2, r4 ; if((lowvalue<<(offset-1)) & 0x80000000 )
  91. bpl token_high_bit_not_set
  92. ldr r4, [r0, #vp8_writer_pos] ; x
  93. sub r4, r4, #1 ; x = w->pos-1
  94. b token_zero_while_start
  95. token_zero_while_loop
  96. mov r10, #0
  97. strb r10, [r7, r4] ; w->buffer[x] =(unsigned char)0
  98. sub r4, r4, #1 ; x--
  99. token_zero_while_start
  100. cmp r4, #0
  101. ldrge r7, [r0, #vp8_writer_buffer]
  102. ldrb r11, [r7, r4]
  103. cmpge r11, #0xff
  104. beq token_zero_while_loop
  105. ldr r7, [r0, #vp8_writer_buffer]
  106. ldrb r10, [r7, r4] ; w->buffer[x]
  107. add r10, r10, #1
  108. strb r10, [r7, r4] ; w->buffer[x] + 1
  109. token_high_bit_not_set
  110. rsb r4, r6, #24 ; 24-offset
  111. ldr r10, [r0, #vp8_writer_buffer]
  112. lsr r7, r2, r4 ; lowvalue >> (24-offset)
  113. ldr r4, [r0, #vp8_writer_pos] ; w->pos
  114. lsl r2, r2, r6 ; lowvalue <<= offset
  115. mov r6, r3 ; shift = count
  116. add r11, r4, #1 ; w->pos++
  117. bic r2, r2, #0xff000000 ; lowvalue &= 0xffffff
  118. str r11, [r0, #vp8_writer_pos]
  119. sub r3, r3, #8 ; count -= 8
  120. strb r7, [r10, r4] ; w->buffer[w->pos++]
  121. ; r10 is used earlier in the loop, but r10 is used as
  122. ; temp variable here. So after r10 is used, reload
  123. ; vp8_coef_tree_dcd into r10
  124. ldr r10, [sp, #60] ; vp8_coef_tree
  125. token_count_lt_zero
  126. lsl r2, r2, r6 ; lowvalue <<= shift
  127. subs r8, r8, #1 ; --n
  128. bne token_loop
  129. ldrb r6, [r1, #tokenextra_token] ; t
  130. ldr r7, [sp, #8] ; vp8_extra_bits
  131. ; Add t * sizeof (vp8_extra_bit_struct) to get the desired
  132. ; element. Here vp8_extra_bit_struct == 16
  133. add r12, r7, r6, lsl #4 ; b = vp8_extra_bits + t
  134. ldr r4, [r12, #vp8_extra_bit_struct_base_val]
  135. cmp r4, #0
  136. beq skip_extra_bits
  137. ; if( b->base_val)
  138. ldr r8, [r12, #vp8_extra_bit_struct_len] ; L
  139. ldrsh lr, [r1, #tokenextra_extra] ; e = p->Extra
  140. cmp r8, #0 ; if( L)
  141. beq no_extra_bits
  142. ldr r9, [r12, #vp8_extra_bit_struct_prob]
  143. asr r7, lr, #1 ; v=e>>1
  144. ldr r10, [r12, #vp8_extra_bit_struct_tree]
  145. str r10, [sp, #4] ; b->tree
  146. rsb r4, r8, #32
  147. lsl r12, r7, r4
  148. mov lr, #0 ; i = 0
  149. extra_bits_loop
  150. ldrb r4, [r9, lr, asr #1] ; pp[i>>1]
  151. sub r7, r5, #1 ; range-1
  152. lsls r12, r12, #1 ; v >> n
  153. mul r4, r4, r7 ; (range-1) * pp[i>>1]
  154. addcs lr, lr, #1 ; i + bb
  155. mov r7, #1
  156. ldrsb lr, [r10, lr] ; i = b->tree[i+bb]
  157. add r4, r7, r4, lsr #8 ; split = 1 + (((range-1) * pp[i>>1]) >> 8)
  158. addcs r2, r2, r4 ; if (bb) lowvalue += split
  159. subcs r4, r5, r4 ; if (bb) range = range-split
  160. clz r6, r4
  161. sub r6, r6, #24
  162. adds r3, r3, r6 ; count += shift
  163. lsl r5, r4, r6 ; range <<= shift
  164. bmi extra_count_lt_zero ; if(count >= 0)
  165. sub r6, r6, r3 ; offset= shift - count
  166. sub r4, r6, #1 ; offset-1
  167. lsls r4, r2, r4 ; if((lowvalue<<(offset-1)) & 0x80000000 )
  168. bpl extra_high_bit_not_set
  169. ldr r4, [r0, #vp8_writer_pos] ; x
  170. sub r4, r4, #1 ; x = w->pos - 1
  171. b extra_zero_while_start
  172. extra_zero_while_loop
  173. mov r10, #0
  174. strb r10, [r7, r4] ; w->buffer[x] =(unsigned char)0
  175. sub r4, r4, #1 ; x--
  176. extra_zero_while_start
  177. cmp r4, #0
  178. ldrge r7, [r0, #vp8_writer_buffer]
  179. ldrb r11, [r7, r4]
  180. cmpge r11, #0xff
  181. beq extra_zero_while_loop
  182. ldr r7, [r0, #vp8_writer_buffer]
  183. ldrb r10, [r7, r4]
  184. add r10, r10, #1
  185. strb r10, [r7, r4]
  186. extra_high_bit_not_set
  187. rsb r4, r6, #24 ; 24-offset
  188. ldr r10, [r0, #vp8_writer_buffer]
  189. lsr r7, r2, r4 ; lowvalue >> (24-offset)
  190. ldr r4, [r0, #vp8_writer_pos]
  191. lsl r2, r2, r6 ; lowvalue <<= offset
  192. mov r6, r3 ; shift = count
  193. add r11, r4, #1 ; w->pos++
  194. bic r2, r2, #0xff000000 ; lowvalue &= 0xffffff
  195. str r11, [r0, #vp8_writer_pos]
  196. sub r3, r3, #8 ; count -= 8
  197. strb r7, [r10, r4] ; w->buffer[w->pos++]=(lowvalue >> (24-offset))
  198. ldr r10, [sp, #4] ; b->tree
  199. extra_count_lt_zero
  200. lsl r2, r2, r6
  201. subs r8, r8, #1 ; --n
  202. bne extra_bits_loop ; while (n)
  203. no_extra_bits
  204. ldr lr, [r1, #4] ; e = p->Extra
  205. add r4, r5, #1 ; range + 1
  206. tst lr, #1
  207. lsr r4, r4, #1 ; split = (range + 1) >> 1
  208. addne r2, r2, r4 ; lowvalue += split
  209. subne r4, r5, r4 ; range = range-split
  210. tst r2, #0x80000000 ; lowvalue & 0x80000000
  211. lsl r5, r4, #1 ; range <<= 1
  212. beq end_high_bit_not_set
  213. ldr r4, [r0, #vp8_writer_pos]
  214. mov r7, #0
  215. sub r4, r4, #1
  216. b end_zero_while_start
  217. end_zero_while_loop
  218. strb r7, [r6, r4]
  219. sub r4, r4, #1 ; x--
  220. end_zero_while_start
  221. cmp r4, #0
  222. ldrge r6, [r0, #vp8_writer_buffer]
  223. ldrb r12, [r6, r4]
  224. cmpge r12, #0xff
  225. beq end_zero_while_loop
  226. ldr r6, [r0, #vp8_writer_buffer]
  227. ldrb r7, [r6, r4]
  228. add r7, r7, #1
  229. strb r7, [r6, r4]
  230. end_high_bit_not_set
  231. adds r3, r3, #1 ; ++count
  232. lsl r2, r2, #1 ; lowvalue <<= 1
  233. bne end_count_zero
  234. ldr r4, [r0, #vp8_writer_pos]
  235. mvn r3, #7
  236. ldr r7, [r0, #vp8_writer_buffer]
  237. lsr r6, r2, #24 ; lowvalue >> 24
  238. add r12, r4, #1 ; w->pos++
  239. bic r2, r2, #0xff000000 ; lowvalue &= 0xffffff
  240. str r12, [r0, #0x10]
  241. strb r6, [r7, r4]
  242. end_count_zero
  243. skip_extra_bits
  244. add r1, r1, #TOKENEXTRA_SZ ; ++p
  245. check_p_lt_stop
  246. ldr r4, [sp, #0] ; stop
  247. cmp r1, r4 ; while( p < stop)
  248. bcc while_p_lt_stop
  249. ldr r6, [sp, #12] ; mb_rows
  250. ldr r7, [sp, #16] ; tokenlist address
  251. subs r6, r6, #1
  252. add r7, r7, #TOKENLIST_SZ ; next element in the array
  253. str r6, [sp, #12]
  254. bne mb_row_loop
  255. str r2, [r0, #vp8_writer_lowvalue]
  256. str r5, [r0, #vp8_writer_range]
  257. str r3, [r0, #vp8_writer_count]
  258. add sp, sp, #24
  259. pop {r4-r11, pc}
  260. ENDP
  261. _VP8_COMP_common_
  262. DCD vp8_comp_common
  263. _VP8_COMMON_MBrows_
  264. DCD vp8_common_mb_rows
  265. _VP8_COMP_tplist_
  266. DCD vp8_comp_tplist
  267. END