/media/libjpeg/simd/jiss2red.asm

http://github.com/zpao/v8monkey · Assembly · 594 lines · 384 code · 118 blank · 92 comment · 1 complexity · f9ecd480998fdcf167ad9b3a59c3ae4c MD5 · raw file

  1. ;
  2. ; jiss2red.asm - reduced-size IDCT (SSE2)
  3. ;
  4. ; Copyright 2009 Pierre Ossman <ossman@cendio.se> for Cendio AB
  5. ;
  6. ; Based on
  7. ; x86 SIMD extension for IJG JPEG library
  8. ; Copyright (C) 1999-2006, MIYASAKA Masaru.
  9. ; For conditions of distribution and use, see copyright notice in jsimdext.inc
  10. ;
  11. ; This file should be assembled with NASM (Netwide Assembler),
  12. ; can *not* be assembled with Microsoft's MASM or any compatible
  13. ; assembler (including Borland's Turbo Assembler).
  14. ; NASM is available from http://nasm.sourceforge.net/ or
  15. ; http://sourceforge.net/project/showfiles.php?group_id=6208
  16. ;
  17. ; This file contains inverse-DCT routines that produce reduced-size
  18. ; output: either 4x4 or 2x2 pixels from an 8x8 DCT block.
  19. ; The following code is based directly on the IJG's original jidctred.c;
  20. ; see the jidctred.c for more details.
  21. ;
  22. ; [TAB8]
  23. %include "jsimdext.inc"
  24. %include "jdct.inc"
  25. ; --------------------------------------------------------------------------
  26. %define CONST_BITS 13
  27. %define PASS1_BITS 2
  28. %define DESCALE_P1_4 (CONST_BITS-PASS1_BITS+1)
  29. %define DESCALE_P2_4 (CONST_BITS+PASS1_BITS+3+1)
  30. %define DESCALE_P1_2 (CONST_BITS-PASS1_BITS+2)
  31. %define DESCALE_P2_2 (CONST_BITS+PASS1_BITS+3+2)
  32. %if CONST_BITS == 13
  33. F_0_211 equ 1730 ; FIX(0.211164243)
  34. F_0_509 equ 4176 ; FIX(0.509795579)
  35. F_0_601 equ 4926 ; FIX(0.601344887)
  36. F_0_720 equ 5906 ; FIX(0.720959822)
  37. F_0_765 equ 6270 ; FIX(0.765366865)
  38. F_0_850 equ 6967 ; FIX(0.850430095)
  39. F_0_899 equ 7373 ; FIX(0.899976223)
  40. F_1_061 equ 8697 ; FIX(1.061594337)
  41. F_1_272 equ 10426 ; FIX(1.272758580)
  42. F_1_451 equ 11893 ; FIX(1.451774981)
  43. F_1_847 equ 15137 ; FIX(1.847759065)
  44. F_2_172 equ 17799 ; FIX(2.172734803)
  45. F_2_562 equ 20995 ; FIX(2.562915447)
  46. F_3_624 equ 29692 ; FIX(3.624509785)
  47. %else
  48. ; NASM cannot do compile-time arithmetic on floating-point constants.
  49. %define DESCALE(x,n) (((x)+(1<<((n)-1)))>>(n))
  50. F_0_211 equ DESCALE( 226735879,30-CONST_BITS) ; FIX(0.211164243)
  51. F_0_509 equ DESCALE( 547388834,30-CONST_BITS) ; FIX(0.509795579)
  52. F_0_601 equ DESCALE( 645689155,30-CONST_BITS) ; FIX(0.601344887)
  53. F_0_720 equ DESCALE( 774124714,30-CONST_BITS) ; FIX(0.720959822)
  54. F_0_765 equ DESCALE( 821806413,30-CONST_BITS) ; FIX(0.765366865)
  55. F_0_850 equ DESCALE( 913142361,30-CONST_BITS) ; FIX(0.850430095)
  56. F_0_899 equ DESCALE( 966342111,30-CONST_BITS) ; FIX(0.899976223)
  57. F_1_061 equ DESCALE(1139878239,30-CONST_BITS) ; FIX(1.061594337)
  58. F_1_272 equ DESCALE(1366614119,30-CONST_BITS) ; FIX(1.272758580)
  59. F_1_451 equ DESCALE(1558831516,30-CONST_BITS) ; FIX(1.451774981)
  60. F_1_847 equ DESCALE(1984016188,30-CONST_BITS) ; FIX(1.847759065)
  61. F_2_172 equ DESCALE(2332956230,30-CONST_BITS) ; FIX(2.172734803)
  62. F_2_562 equ DESCALE(2751909506,30-CONST_BITS) ; FIX(2.562915447)
  63. F_3_624 equ DESCALE(3891787747,30-CONST_BITS) ; FIX(3.624509785)
  64. %endif
  65. ; --------------------------------------------------------------------------
  66. SECTION SEG_CONST
  67. alignz 16
  68. global EXTN(jconst_idct_red_sse2)
  69. EXTN(jconst_idct_red_sse2):
  70. PW_F184_MF076 times 4 dw F_1_847,-F_0_765
  71. PW_F256_F089 times 4 dw F_2_562, F_0_899
  72. PW_F106_MF217 times 4 dw F_1_061,-F_2_172
  73. PW_MF060_MF050 times 4 dw -F_0_601,-F_0_509
  74. PW_F145_MF021 times 4 dw F_1_451,-F_0_211
  75. PW_F362_MF127 times 4 dw F_3_624,-F_1_272
  76. PW_F085_MF072 times 4 dw F_0_850,-F_0_720
  77. PD_DESCALE_P1_4 times 4 dd 1 << (DESCALE_P1_4-1)
  78. PD_DESCALE_P2_4 times 4 dd 1 << (DESCALE_P2_4-1)
  79. PD_DESCALE_P1_2 times 4 dd 1 << (DESCALE_P1_2-1)
  80. PD_DESCALE_P2_2 times 4 dd 1 << (DESCALE_P2_2-1)
  81. PB_CENTERJSAMP times 16 db CENTERJSAMPLE
  82. alignz 16
  83. ; --------------------------------------------------------------------------
  84. SECTION SEG_TEXT
  85. BITS 32
  86. ;
  87. ; Perform dequantization and inverse DCT on one block of coefficients,
  88. ; producing a reduced-size 4x4 output block.
  89. ;
  90. ; GLOBAL(void)
  91. ; jsimd_idct_4x4_sse2 (void * dct_table, JCOEFPTR coef_block,
  92. ; JSAMPARRAY output_buf, JDIMENSION output_col)
  93. ;
  94. %define dct_table(b) (b)+8 ; void * dct_table
  95. %define coef_block(b) (b)+12 ; JCOEFPTR coef_block
  96. %define output_buf(b) (b)+16 ; JSAMPARRAY output_buf
  97. %define output_col(b) (b)+20 ; JDIMENSION output_col
  98. %define original_ebp ebp+0
  99. %define wk(i) ebp-(WK_NUM-(i))*SIZEOF_XMMWORD ; xmmword wk[WK_NUM]
  100. %define WK_NUM 2
  101. align 16
  102. global EXTN(jsimd_idct_4x4_sse2)
  103. EXTN(jsimd_idct_4x4_sse2):
  104. push ebp
  105. mov eax,esp ; eax = original ebp
  106. sub esp, byte 4
  107. and esp, byte (-SIZEOF_XMMWORD) ; align to 128 bits
  108. mov [esp],eax
  109. mov ebp,esp ; ebp = aligned ebp
  110. lea esp, [wk(0)]
  111. pushpic ebx
  112. ; push ecx ; unused
  113. ; push edx ; need not be preserved
  114. push esi
  115. push edi
  116. get_GOT ebx ; get GOT address
  117. ; ---- Pass 1: process columns from input.
  118. ; mov eax, [original_ebp]
  119. mov edx, POINTER [dct_table(eax)] ; quantptr
  120. mov esi, JCOEFPTR [coef_block(eax)] ; inptr
  121. %ifndef NO_ZERO_COLUMN_TEST_4X4_SSE2
  122. mov eax, DWORD [DWBLOCK(1,0,esi,SIZEOF_JCOEF)]
  123. or eax, DWORD [DWBLOCK(2,0,esi,SIZEOF_JCOEF)]
  124. jnz short .columnDCT
  125. movdqa xmm0, XMMWORD [XMMBLOCK(1,0,esi,SIZEOF_JCOEF)]
  126. movdqa xmm1, XMMWORD [XMMBLOCK(2,0,esi,SIZEOF_JCOEF)]
  127. por xmm0, XMMWORD [XMMBLOCK(3,0,esi,SIZEOF_JCOEF)]
  128. por xmm1, XMMWORD [XMMBLOCK(5,0,esi,SIZEOF_JCOEF)]
  129. por xmm0, XMMWORD [XMMBLOCK(6,0,esi,SIZEOF_JCOEF)]
  130. por xmm1, XMMWORD [XMMBLOCK(7,0,esi,SIZEOF_JCOEF)]
  131. por xmm0,xmm1
  132. packsswb xmm0,xmm0
  133. packsswb xmm0,xmm0
  134. movd eax,xmm0
  135. test eax,eax
  136. jnz short .columnDCT
  137. ; -- AC terms all zero
  138. movdqa xmm0, XMMWORD [XMMBLOCK(0,0,esi,SIZEOF_JCOEF)]
  139. pmullw xmm0, XMMWORD [XMMBLOCK(0,0,edx,SIZEOF_ISLOW_MULT_TYPE)]
  140. psllw xmm0,PASS1_BITS
  141. movdqa xmm3,xmm0 ; xmm0=in0=(00 01 02 03 04 05 06 07)
  142. punpcklwd xmm0,xmm0 ; xmm0=(00 00 01 01 02 02 03 03)
  143. punpckhwd xmm3,xmm3 ; xmm3=(04 04 05 05 06 06 07 07)
  144. pshufd xmm1,xmm0,0x50 ; xmm1=[col0 col1]=(00 00 00 00 01 01 01 01)
  145. pshufd xmm0,xmm0,0xFA ; xmm0=[col2 col3]=(02 02 02 02 03 03 03 03)
  146. pshufd xmm6,xmm3,0x50 ; xmm6=[col4 col5]=(04 04 04 04 05 05 05 05)
  147. pshufd xmm3,xmm3,0xFA ; xmm3=[col6 col7]=(06 06 06 06 07 07 07 07)
  148. jmp near .column_end
  149. alignx 16,7
  150. %endif
  151. .columnDCT:
  152. ; -- Odd part
  153. movdqa xmm0, XMMWORD [XMMBLOCK(1,0,esi,SIZEOF_JCOEF)]
  154. movdqa xmm1, XMMWORD [XMMBLOCK(3,0,esi,SIZEOF_JCOEF)]
  155. pmullw xmm0, XMMWORD [XMMBLOCK(1,0,edx,SIZEOF_ISLOW_MULT_TYPE)]
  156. pmullw xmm1, XMMWORD [XMMBLOCK(3,0,edx,SIZEOF_ISLOW_MULT_TYPE)]
  157. movdqa xmm2, XMMWORD [XMMBLOCK(5,0,esi,SIZEOF_JCOEF)]
  158. movdqa xmm3, XMMWORD [XMMBLOCK(7,0,esi,SIZEOF_JCOEF)]
  159. pmullw xmm2, XMMWORD [XMMBLOCK(5,0,edx,SIZEOF_ISLOW_MULT_TYPE)]
  160. pmullw xmm3, XMMWORD [XMMBLOCK(7,0,edx,SIZEOF_ISLOW_MULT_TYPE)]
  161. movdqa xmm4,xmm0
  162. movdqa xmm5,xmm0
  163. punpcklwd xmm4,xmm1
  164. punpckhwd xmm5,xmm1
  165. movdqa xmm0,xmm4
  166. movdqa xmm1,xmm5
  167. pmaddwd xmm4,[GOTOFF(ebx,PW_F256_F089)] ; xmm4=(tmp2L)
  168. pmaddwd xmm5,[GOTOFF(ebx,PW_F256_F089)] ; xmm5=(tmp2H)
  169. pmaddwd xmm0,[GOTOFF(ebx,PW_F106_MF217)] ; xmm0=(tmp0L)
  170. pmaddwd xmm1,[GOTOFF(ebx,PW_F106_MF217)] ; xmm1=(tmp0H)
  171. movdqa xmm6,xmm2
  172. movdqa xmm7,xmm2
  173. punpcklwd xmm6,xmm3
  174. punpckhwd xmm7,xmm3
  175. movdqa xmm2,xmm6
  176. movdqa xmm3,xmm7
  177. pmaddwd xmm6,[GOTOFF(ebx,PW_MF060_MF050)] ; xmm6=(tmp2L)
  178. pmaddwd xmm7,[GOTOFF(ebx,PW_MF060_MF050)] ; xmm7=(tmp2H)
  179. pmaddwd xmm2,[GOTOFF(ebx,PW_F145_MF021)] ; xmm2=(tmp0L)
  180. pmaddwd xmm3,[GOTOFF(ebx,PW_F145_MF021)] ; xmm3=(tmp0H)
  181. paddd xmm6,xmm4 ; xmm6=tmp2L
  182. paddd xmm7,xmm5 ; xmm7=tmp2H
  183. paddd xmm2,xmm0 ; xmm2=tmp0L
  184. paddd xmm3,xmm1 ; xmm3=tmp0H
  185. movdqa XMMWORD [wk(0)], xmm2 ; wk(0)=tmp0L
  186. movdqa XMMWORD [wk(1)], xmm3 ; wk(1)=tmp0H
  187. ; -- Even part
  188. movdqa xmm4, XMMWORD [XMMBLOCK(0,0,esi,SIZEOF_JCOEF)]
  189. movdqa xmm5, XMMWORD [XMMBLOCK(2,0,esi,SIZEOF_JCOEF)]
  190. movdqa xmm0, XMMWORD [XMMBLOCK(6,0,esi,SIZEOF_JCOEF)]
  191. pmullw xmm4, XMMWORD [XMMBLOCK(0,0,edx,SIZEOF_ISLOW_MULT_TYPE)]
  192. pmullw xmm5, XMMWORD [XMMBLOCK(2,0,edx,SIZEOF_ISLOW_MULT_TYPE)]
  193. pmullw xmm0, XMMWORD [XMMBLOCK(6,0,edx,SIZEOF_ISLOW_MULT_TYPE)]
  194. pxor xmm1,xmm1
  195. pxor xmm2,xmm2
  196. punpcklwd xmm1,xmm4 ; xmm1=tmp0L
  197. punpckhwd xmm2,xmm4 ; xmm2=tmp0H
  198. psrad xmm1,(16-CONST_BITS-1) ; psrad xmm1,16 & pslld xmm1,CONST_BITS+1
  199. psrad xmm2,(16-CONST_BITS-1) ; psrad xmm2,16 & pslld xmm2,CONST_BITS+1
  200. movdqa xmm3,xmm5 ; xmm5=in2=z2
  201. punpcklwd xmm5,xmm0 ; xmm0=in6=z3
  202. punpckhwd xmm3,xmm0
  203. pmaddwd xmm5,[GOTOFF(ebx,PW_F184_MF076)] ; xmm5=tmp2L
  204. pmaddwd xmm3,[GOTOFF(ebx,PW_F184_MF076)] ; xmm3=tmp2H
  205. movdqa xmm4,xmm1
  206. movdqa xmm0,xmm2
  207. paddd xmm1,xmm5 ; xmm1=tmp10L
  208. paddd xmm2,xmm3 ; xmm2=tmp10H
  209. psubd xmm4,xmm5 ; xmm4=tmp12L
  210. psubd xmm0,xmm3 ; xmm0=tmp12H
  211. ; -- Final output stage
  212. movdqa xmm5,xmm1
  213. movdqa xmm3,xmm2
  214. paddd xmm1,xmm6 ; xmm1=data0L
  215. paddd xmm2,xmm7 ; xmm2=data0H
  216. psubd xmm5,xmm6 ; xmm5=data3L
  217. psubd xmm3,xmm7 ; xmm3=data3H
  218. movdqa xmm6,[GOTOFF(ebx,PD_DESCALE_P1_4)] ; xmm6=[PD_DESCALE_P1_4]
  219. paddd xmm1,xmm6
  220. paddd xmm2,xmm6
  221. psrad xmm1,DESCALE_P1_4
  222. psrad xmm2,DESCALE_P1_4
  223. paddd xmm5,xmm6
  224. paddd xmm3,xmm6
  225. psrad xmm5,DESCALE_P1_4
  226. psrad xmm3,DESCALE_P1_4
  227. packssdw xmm1,xmm2 ; xmm1=data0=(00 01 02 03 04 05 06 07)
  228. packssdw xmm5,xmm3 ; xmm5=data3=(30 31 32 33 34 35 36 37)
  229. movdqa xmm7, XMMWORD [wk(0)] ; xmm7=tmp0L
  230. movdqa xmm6, XMMWORD [wk(1)] ; xmm6=tmp0H
  231. movdqa xmm2,xmm4
  232. movdqa xmm3,xmm0
  233. paddd xmm4,xmm7 ; xmm4=data1L
  234. paddd xmm0,xmm6 ; xmm0=data1H
  235. psubd xmm2,xmm7 ; xmm2=data2L
  236. psubd xmm3,xmm6 ; xmm3=data2H
  237. movdqa xmm7,[GOTOFF(ebx,PD_DESCALE_P1_4)] ; xmm7=[PD_DESCALE_P1_4]
  238. paddd xmm4,xmm7
  239. paddd xmm0,xmm7
  240. psrad xmm4,DESCALE_P1_4
  241. psrad xmm0,DESCALE_P1_4
  242. paddd xmm2,xmm7
  243. paddd xmm3,xmm7
  244. psrad xmm2,DESCALE_P1_4
  245. psrad xmm3,DESCALE_P1_4
  246. packssdw xmm4,xmm0 ; xmm4=data1=(10 11 12 13 14 15 16 17)
  247. packssdw xmm2,xmm3 ; xmm2=data2=(20 21 22 23 24 25 26 27)
  248. movdqa xmm6,xmm1 ; transpose coefficients(phase 1)
  249. punpcklwd xmm1,xmm4 ; xmm1=(00 10 01 11 02 12 03 13)
  250. punpckhwd xmm6,xmm4 ; xmm6=(04 14 05 15 06 16 07 17)
  251. movdqa xmm7,xmm2 ; transpose coefficients(phase 1)
  252. punpcklwd xmm2,xmm5 ; xmm2=(20 30 21 31 22 32 23 33)
  253. punpckhwd xmm7,xmm5 ; xmm7=(24 34 25 35 26 36 27 37)
  254. movdqa xmm0,xmm1 ; transpose coefficients(phase 2)
  255. punpckldq xmm1,xmm2 ; xmm1=[col0 col1]=(00 10 20 30 01 11 21 31)
  256. punpckhdq xmm0,xmm2 ; xmm0=[col2 col3]=(02 12 22 32 03 13 23 33)
  257. movdqa xmm3,xmm6 ; transpose coefficients(phase 2)
  258. punpckldq xmm6,xmm7 ; xmm6=[col4 col5]=(04 14 24 34 05 15 25 35)
  259. punpckhdq xmm3,xmm7 ; xmm3=[col6 col7]=(06 16 26 36 07 17 27 37)
  260. .column_end:
  261. ; -- Prefetch the next coefficient block
  262. prefetchnta [esi + DCTSIZE2*SIZEOF_JCOEF + 0*32]
  263. prefetchnta [esi + DCTSIZE2*SIZEOF_JCOEF + 1*32]
  264. prefetchnta [esi + DCTSIZE2*SIZEOF_JCOEF + 2*32]
  265. prefetchnta [esi + DCTSIZE2*SIZEOF_JCOEF + 3*32]
  266. ; ---- Pass 2: process rows, store into output array.
  267. mov eax, [original_ebp]
  268. mov edi, JSAMPARRAY [output_buf(eax)] ; (JSAMPROW *)
  269. mov eax, JDIMENSION [output_col(eax)]
  270. ; -- Even part
  271. pxor xmm4,xmm4
  272. punpcklwd xmm4,xmm1 ; xmm4=tmp0
  273. psrad xmm4,(16-CONST_BITS-1) ; psrad xmm4,16 & pslld xmm4,CONST_BITS+1
  274. ; -- Odd part
  275. punpckhwd xmm1,xmm0
  276. punpckhwd xmm6,xmm3
  277. movdqa xmm5,xmm1
  278. movdqa xmm2,xmm6
  279. pmaddwd xmm1,[GOTOFF(ebx,PW_F256_F089)] ; xmm1=(tmp2)
  280. pmaddwd xmm6,[GOTOFF(ebx,PW_MF060_MF050)] ; xmm6=(tmp2)
  281. pmaddwd xmm5,[GOTOFF(ebx,PW_F106_MF217)] ; xmm5=(tmp0)
  282. pmaddwd xmm2,[GOTOFF(ebx,PW_F145_MF021)] ; xmm2=(tmp0)
  283. paddd xmm6,xmm1 ; xmm6=tmp2
  284. paddd xmm2,xmm5 ; xmm2=tmp0
  285. ; -- Even part
  286. punpcklwd xmm0,xmm3
  287. pmaddwd xmm0,[GOTOFF(ebx,PW_F184_MF076)] ; xmm0=tmp2
  288. movdqa xmm7,xmm4
  289. paddd xmm4,xmm0 ; xmm4=tmp10
  290. psubd xmm7,xmm0 ; xmm7=tmp12
  291. ; -- Final output stage
  292. movdqa xmm1,[GOTOFF(ebx,PD_DESCALE_P2_4)] ; xmm1=[PD_DESCALE_P2_4]
  293. movdqa xmm5,xmm4
  294. movdqa xmm3,xmm7
  295. paddd xmm4,xmm6 ; xmm4=data0=(00 10 20 30)
  296. paddd xmm7,xmm2 ; xmm7=data1=(01 11 21 31)
  297. psubd xmm5,xmm6 ; xmm5=data3=(03 13 23 33)
  298. psubd xmm3,xmm2 ; xmm3=data2=(02 12 22 32)
  299. paddd xmm4,xmm1
  300. paddd xmm7,xmm1
  301. psrad xmm4,DESCALE_P2_4
  302. psrad xmm7,DESCALE_P2_4
  303. paddd xmm5,xmm1
  304. paddd xmm3,xmm1
  305. psrad xmm5,DESCALE_P2_4
  306. psrad xmm3,DESCALE_P2_4
  307. packssdw xmm4,xmm3 ; xmm4=(00 10 20 30 02 12 22 32)
  308. packssdw xmm7,xmm5 ; xmm7=(01 11 21 31 03 13 23 33)
  309. movdqa xmm0,xmm4 ; transpose coefficients(phase 1)
  310. punpcklwd xmm4,xmm7 ; xmm4=(00 01 10 11 20 21 30 31)
  311. punpckhwd xmm0,xmm7 ; xmm0=(02 03 12 13 22 23 32 33)
  312. movdqa xmm6,xmm4 ; transpose coefficients(phase 2)
  313. punpckldq xmm4,xmm0 ; xmm4=(00 01 02 03 10 11 12 13)
  314. punpckhdq xmm6,xmm0 ; xmm6=(20 21 22 23 30 31 32 33)
  315. packsswb xmm4,xmm6 ; xmm4=(00 01 02 03 10 11 12 13 20 ..)
  316. paddb xmm4,[GOTOFF(ebx,PB_CENTERJSAMP)]
  317. pshufd xmm2,xmm4,0x39 ; xmm2=(10 11 12 13 20 21 22 23 30 ..)
  318. pshufd xmm1,xmm4,0x4E ; xmm1=(20 21 22 23 30 31 32 33 00 ..)
  319. pshufd xmm3,xmm4,0x93 ; xmm3=(30 31 32 33 00 01 02 03 10 ..)
  320. mov edx, JSAMPROW [edi+0*SIZEOF_JSAMPROW]
  321. mov esi, JSAMPROW [edi+1*SIZEOF_JSAMPROW]
  322. movd XMM_DWORD [edx+eax*SIZEOF_JSAMPLE], xmm4
  323. movd XMM_DWORD [esi+eax*SIZEOF_JSAMPLE], xmm2
  324. mov edx, JSAMPROW [edi+2*SIZEOF_JSAMPROW]
  325. mov esi, JSAMPROW [edi+3*SIZEOF_JSAMPROW]
  326. movd XMM_DWORD [edx+eax*SIZEOF_JSAMPLE], xmm1
  327. movd XMM_DWORD [esi+eax*SIZEOF_JSAMPLE], xmm3
  328. pop edi
  329. pop esi
  330. ; pop edx ; need not be preserved
  331. ; pop ecx ; unused
  332. poppic ebx
  333. mov esp,ebp ; esp <- aligned ebp
  334. pop esp ; esp <- original ebp
  335. pop ebp
  336. ret
  337. ; --------------------------------------------------------------------------
  338. ;
  339. ; Perform dequantization and inverse DCT on one block of coefficients,
  340. ; producing a reduced-size 2x2 output block.
  341. ;
  342. ; GLOBAL(void)
  343. ; jsimd_idct_2x2_sse2 (void * dct_table, JCOEFPTR coef_block,
  344. ; JSAMPARRAY output_buf, JDIMENSION output_col)
  345. ;
  346. %define dct_table(b) (b)+8 ; void * dct_table
  347. %define coef_block(b) (b)+12 ; JCOEFPTR coef_block
  348. %define output_buf(b) (b)+16 ; JSAMPARRAY output_buf
  349. %define output_col(b) (b)+20 ; JDIMENSION output_col
  350. align 16
  351. global EXTN(jsimd_idct_2x2_sse2)
  352. EXTN(jsimd_idct_2x2_sse2):
  353. push ebp
  354. mov ebp,esp
  355. push ebx
  356. ; push ecx ; need not be preserved
  357. ; push edx ; need not be preserved
  358. push esi
  359. push edi
  360. get_GOT ebx ; get GOT address
  361. ; ---- Pass 1: process columns from input.
  362. mov edx, POINTER [dct_table(ebp)] ; quantptr
  363. mov esi, JCOEFPTR [coef_block(ebp)] ; inptr
  364. ; | input: | result: |
  365. ; | 00 01 ** 03 ** 05 ** 07 | |
  366. ; | 10 11 ** 13 ** 15 ** 17 | |
  367. ; | ** ** ** ** ** ** ** ** | |
  368. ; | 30 31 ** 33 ** 35 ** 37 | A0 A1 A3 A5 A7 |
  369. ; | ** ** ** ** ** ** ** ** | B0 B1 B3 B5 B7 |
  370. ; | 50 51 ** 53 ** 55 ** 57 | |
  371. ; | ** ** ** ** ** ** ** ** | |
  372. ; | 70 71 ** 73 ** 75 ** 77 | |
  373. ; -- Odd part
  374. movdqa xmm0, XMMWORD [XMMBLOCK(1,0,esi,SIZEOF_JCOEF)]
  375. movdqa xmm1, XMMWORD [XMMBLOCK(3,0,esi,SIZEOF_JCOEF)]
  376. pmullw xmm0, XMMWORD [XMMBLOCK(1,0,edx,SIZEOF_ISLOW_MULT_TYPE)]
  377. pmullw xmm1, XMMWORD [XMMBLOCK(3,0,edx,SIZEOF_ISLOW_MULT_TYPE)]
  378. movdqa xmm2, XMMWORD [XMMBLOCK(5,0,esi,SIZEOF_JCOEF)]
  379. movdqa xmm3, XMMWORD [XMMBLOCK(7,0,esi,SIZEOF_JCOEF)]
  380. pmullw xmm2, XMMWORD [XMMBLOCK(5,0,edx,SIZEOF_ISLOW_MULT_TYPE)]
  381. pmullw xmm3, XMMWORD [XMMBLOCK(7,0,edx,SIZEOF_ISLOW_MULT_TYPE)]
  382. ; xmm0=(10 11 ** 13 ** 15 ** 17), xmm1=(30 31 ** 33 ** 35 ** 37)
  383. ; xmm2=(50 51 ** 53 ** 55 ** 57), xmm3=(70 71 ** 73 ** 75 ** 77)
  384. pcmpeqd xmm7,xmm7
  385. pslld xmm7,WORD_BIT ; xmm7={0x0000 0xFFFF 0x0000 0xFFFF ..}
  386. movdqa xmm4,xmm0 ; xmm4=(10 11 ** 13 ** 15 ** 17)
  387. movdqa xmm5,xmm2 ; xmm5=(50 51 ** 53 ** 55 ** 57)
  388. punpcklwd xmm4,xmm1 ; xmm4=(10 30 11 31 ** ** 13 33)
  389. punpcklwd xmm5,xmm3 ; xmm5=(50 70 51 71 ** ** 53 73)
  390. pmaddwd xmm4,[GOTOFF(ebx,PW_F362_MF127)]
  391. pmaddwd xmm5,[GOTOFF(ebx,PW_F085_MF072)]
  392. psrld xmm0,WORD_BIT ; xmm0=(11 -- 13 -- 15 -- 17 --)
  393. pand xmm1,xmm7 ; xmm1=(-- 31 -- 33 -- 35 -- 37)
  394. psrld xmm2,WORD_BIT ; xmm2=(51 -- 53 -- 55 -- 57 --)
  395. pand xmm3,xmm7 ; xmm3=(-- 71 -- 73 -- 75 -- 77)
  396. por xmm0,xmm1 ; xmm0=(11 31 13 33 15 35 17 37)
  397. por xmm2,xmm3 ; xmm2=(51 71 53 73 55 75 57 77)
  398. pmaddwd xmm0,[GOTOFF(ebx,PW_F362_MF127)]
  399. pmaddwd xmm2,[GOTOFF(ebx,PW_F085_MF072)]
  400. paddd xmm4,xmm5 ; xmm4=tmp0[col0 col1 **** col3]
  401. paddd xmm0,xmm2 ; xmm0=tmp0[col1 col3 col5 col7]
  402. ; -- Even part
  403. movdqa xmm6, XMMWORD [XMMBLOCK(0,0,esi,SIZEOF_JCOEF)]
  404. pmullw xmm6, XMMWORD [XMMBLOCK(0,0,edx,SIZEOF_ISLOW_MULT_TYPE)]
  405. ; xmm6=(00 01 ** 03 ** 05 ** 07)
  406. movdqa xmm1,xmm6 ; xmm1=(00 01 ** 03 ** 05 ** 07)
  407. pslld xmm6,WORD_BIT ; xmm6=(-- 00 -- ** -- ** -- **)
  408. pand xmm1,xmm7 ; xmm1=(-- 01 -- 03 -- 05 -- 07)
  409. psrad xmm6,(WORD_BIT-CONST_BITS-2) ; xmm6=tmp10[col0 **** **** ****]
  410. psrad xmm1,(WORD_BIT-CONST_BITS-2) ; xmm1=tmp10[col1 col3 col5 col7]
  411. ; -- Final output stage
  412. movdqa xmm3,xmm6
  413. movdqa xmm5,xmm1
  414. paddd xmm6,xmm4 ; xmm6=data0[col0 **** **** ****]=(A0 ** ** **)
  415. paddd xmm1,xmm0 ; xmm1=data0[col1 col3 col5 col7]=(A1 A3 A5 A7)
  416. psubd xmm3,xmm4 ; xmm3=data1[col0 **** **** ****]=(B0 ** ** **)
  417. psubd xmm5,xmm0 ; xmm5=data1[col1 col3 col5 col7]=(B1 B3 B5 B7)
  418. movdqa xmm2,[GOTOFF(ebx,PD_DESCALE_P1_2)] ; xmm2=[PD_DESCALE_P1_2]
  419. punpckldq xmm6,xmm3 ; xmm6=(A0 B0 ** **)
  420. movdqa xmm7,xmm1
  421. punpcklqdq xmm1,xmm5 ; xmm1=(A1 A3 B1 B3)
  422. punpckhqdq xmm7,xmm5 ; xmm7=(A5 A7 B5 B7)
  423. paddd xmm6,xmm2
  424. psrad xmm6,DESCALE_P1_2
  425. paddd xmm1,xmm2
  426. paddd xmm7,xmm2
  427. psrad xmm1,DESCALE_P1_2
  428. psrad xmm7,DESCALE_P1_2
  429. ; -- Prefetch the next coefficient block
  430. prefetchnta [esi + DCTSIZE2*SIZEOF_JCOEF + 0*32]
  431. prefetchnta [esi + DCTSIZE2*SIZEOF_JCOEF + 1*32]
  432. prefetchnta [esi + DCTSIZE2*SIZEOF_JCOEF + 2*32]
  433. prefetchnta [esi + DCTSIZE2*SIZEOF_JCOEF + 3*32]
  434. ; ---- Pass 2: process rows, store into output array.
  435. mov edi, JSAMPARRAY [output_buf(ebp)] ; (JSAMPROW *)
  436. mov eax, JDIMENSION [output_col(ebp)]
  437. ; | input:| result:|
  438. ; | A0 B0 | |
  439. ; | A1 B1 | C0 C1 |
  440. ; | A3 B3 | D0 D1 |
  441. ; | A5 B5 | |
  442. ; | A7 B7 | |
  443. ; -- Odd part
  444. packssdw xmm1,xmm1 ; xmm1=(A1 A3 B1 B3 A1 A3 B1 B3)
  445. packssdw xmm7,xmm7 ; xmm7=(A5 A7 B5 B7 A5 A7 B5 B7)
  446. pmaddwd xmm1,[GOTOFF(ebx,PW_F362_MF127)]
  447. pmaddwd xmm7,[GOTOFF(ebx,PW_F085_MF072)]
  448. paddd xmm1,xmm7 ; xmm1=tmp0[row0 row1 row0 row1]
  449. ; -- Even part
  450. pslld xmm6,(CONST_BITS+2) ; xmm6=tmp10[row0 row1 **** ****]
  451. ; -- Final output stage
  452. movdqa xmm4,xmm6
  453. paddd xmm6,xmm1 ; xmm6=data0[row0 row1 **** ****]=(C0 C1 ** **)
  454. psubd xmm4,xmm1 ; xmm4=data1[row0 row1 **** ****]=(D0 D1 ** **)
  455. punpckldq xmm6,xmm4 ; xmm6=(C0 D0 C1 D1)
  456. paddd xmm6,[GOTOFF(ebx,PD_DESCALE_P2_2)]
  457. psrad xmm6,DESCALE_P2_2
  458. packssdw xmm6,xmm6 ; xmm6=(C0 D0 C1 D1 C0 D0 C1 D1)
  459. packsswb xmm6,xmm6 ; xmm6=(C0 D0 C1 D1 C0 D0 C1 D1 ..)
  460. paddb xmm6,[GOTOFF(ebx,PB_CENTERJSAMP)]
  461. pextrw ebx,xmm6,0x00 ; ebx=(C0 D0 -- --)
  462. pextrw ecx,xmm6,0x01 ; ecx=(C1 D1 -- --)
  463. mov edx, JSAMPROW [edi+0*SIZEOF_JSAMPROW]
  464. mov esi, JSAMPROW [edi+1*SIZEOF_JSAMPROW]
  465. mov WORD [edx+eax*SIZEOF_JSAMPLE], bx
  466. mov WORD [esi+eax*SIZEOF_JSAMPLE], cx
  467. pop edi
  468. pop esi
  469. ; pop edx ; need not be preserved
  470. ; pop ecx ; need not be preserved
  471. pop ebx
  472. pop ebp
  473. ret
  474. ; For some reason, the OS X linker does not honor the request to align the
  475. ; segment unless we do this.
  476. align 16