/media/libjpeg/simd/jfss2int-64.asm

http://github.com/zpao/v8monkey · Assembly · 622 lines · 408 code · 102 blank · 112 comment · 1 complexity · 5a2264f06e07bdc6f4c6d5897a384e2d MD5 · raw file

  1. ;
  2. ; jfss2int-64.asm - accurate integer FDCT (64-bit SSE2)
  3. ;
  4. ; Copyright 2009 Pierre Ossman <ossman@cendio.se> for Cendio AB
  5. ; Copyright 2009 D. R. Commander
  6. ;
  7. ; Based on
  8. ; x86 SIMD extension for IJG JPEG library
  9. ; Copyright (C) 1999-2006, MIYASAKA Masaru.
  10. ; For conditions of distribution and use, see copyright notice in jsimdext.inc
  11. ;
  12. ; This file should be assembled with NASM (Netwide Assembler),
  13. ; can *not* be assembled with Microsoft's MASM or any compatible
  14. ; assembler (including Borland's Turbo Assembler).
  15. ; NASM is available from http://nasm.sourceforge.net/ or
  16. ; http://sourceforge.net/project/showfiles.php?group_id=6208
  17. ;
  18. ; This file contains a slow-but-accurate integer implementation of the
  19. ; forward DCT (Discrete Cosine Transform). The following code is based
  20. ; directly on the IJG's original jfdctint.c; see the jfdctint.c for
  21. ; more details.
  22. ;
  23. ; [TAB8]
  24. %include "jsimdext.inc"
  25. %include "jdct.inc"
  26. ; --------------------------------------------------------------------------
  27. %define CONST_BITS 13
  28. %define PASS1_BITS 2
  29. %define DESCALE_P1 (CONST_BITS-PASS1_BITS)
  30. %define DESCALE_P2 (CONST_BITS+PASS1_BITS)
  31. %if CONST_BITS == 13
  32. F_0_298 equ 2446 ; FIX(0.298631336)
  33. F_0_390 equ 3196 ; FIX(0.390180644)
  34. F_0_541 equ 4433 ; FIX(0.541196100)
  35. F_0_765 equ 6270 ; FIX(0.765366865)
  36. F_0_899 equ 7373 ; FIX(0.899976223)
  37. F_1_175 equ 9633 ; FIX(1.175875602)
  38. F_1_501 equ 12299 ; FIX(1.501321110)
  39. F_1_847 equ 15137 ; FIX(1.847759065)
  40. F_1_961 equ 16069 ; FIX(1.961570560)
  41. F_2_053 equ 16819 ; FIX(2.053119869)
  42. F_2_562 equ 20995 ; FIX(2.562915447)
  43. F_3_072 equ 25172 ; FIX(3.072711026)
  44. %else
  45. ; NASM cannot do compile-time arithmetic on floating-point constants.
  46. %define DESCALE(x,n) (((x)+(1<<((n)-1)))>>(n))
  47. F_0_298 equ DESCALE( 320652955,30-CONST_BITS) ; FIX(0.298631336)
  48. F_0_390 equ DESCALE( 418953276,30-CONST_BITS) ; FIX(0.390180644)
  49. F_0_541 equ DESCALE( 581104887,30-CONST_BITS) ; FIX(0.541196100)
  50. F_0_765 equ DESCALE( 821806413,30-CONST_BITS) ; FIX(0.765366865)
  51. F_0_899 equ DESCALE( 966342111,30-CONST_BITS) ; FIX(0.899976223)
  52. F_1_175 equ DESCALE(1262586813,30-CONST_BITS) ; FIX(1.175875602)
  53. F_1_501 equ DESCALE(1612031267,30-CONST_BITS) ; FIX(1.501321110)
  54. F_1_847 equ DESCALE(1984016188,30-CONST_BITS) ; FIX(1.847759065)
  55. F_1_961 equ DESCALE(2106220350,30-CONST_BITS) ; FIX(1.961570560)
  56. F_2_053 equ DESCALE(2204520673,30-CONST_BITS) ; FIX(2.053119869)
  57. F_2_562 equ DESCALE(2751909506,30-CONST_BITS) ; FIX(2.562915447)
  58. F_3_072 equ DESCALE(3299298341,30-CONST_BITS) ; FIX(3.072711026)
  59. %endif
  60. ; --------------------------------------------------------------------------
  61. SECTION SEG_CONST
  62. alignz 16
  63. global EXTN(jconst_fdct_islow_sse2)
  64. EXTN(jconst_fdct_islow_sse2):
  65. PW_F130_F054 times 4 dw (F_0_541+F_0_765), F_0_541
  66. PW_F054_MF130 times 4 dw F_0_541, (F_0_541-F_1_847)
  67. PW_MF078_F117 times 4 dw (F_1_175-F_1_961), F_1_175
  68. PW_F117_F078 times 4 dw F_1_175, (F_1_175-F_0_390)
  69. PW_MF060_MF089 times 4 dw (F_0_298-F_0_899),-F_0_899
  70. PW_MF089_F060 times 4 dw -F_0_899, (F_1_501-F_0_899)
  71. PW_MF050_MF256 times 4 dw (F_2_053-F_2_562),-F_2_562
  72. PW_MF256_F050 times 4 dw -F_2_562, (F_3_072-F_2_562)
  73. PD_DESCALE_P1 times 4 dd 1 << (DESCALE_P1-1)
  74. PD_DESCALE_P2 times 4 dd 1 << (DESCALE_P2-1)
  75. PW_DESCALE_P2X times 8 dw 1 << (PASS1_BITS-1)
  76. alignz 16
  77. ; --------------------------------------------------------------------------
  78. SECTION SEG_TEXT
  79. BITS 64
  80. ;
  81. ; Perform the forward DCT on one block of samples.
  82. ;
  83. ; GLOBAL(void)
  84. ; jsimd_fdct_islow_sse2 (DCTELEM * data)
  85. ;
  86. ; r10 = DCTELEM * data
  87. %define wk(i) rbp-(WK_NUM-(i))*SIZEOF_XMMWORD ; xmmword wk[WK_NUM]
  88. %define WK_NUM 6
  89. align 16
  90. global EXTN(jsimd_fdct_islow_sse2)
  91. EXTN(jsimd_fdct_islow_sse2):
  92. push rbp
  93. mov rax,rsp ; rax = original rbp
  94. sub rsp, byte 4
  95. and rsp, byte (-SIZEOF_XMMWORD) ; align to 128 bits
  96. mov [rsp],rax
  97. mov rbp,rsp ; rbp = aligned rbp
  98. lea rsp, [wk(0)]
  99. collect_args
  100. ; ---- Pass 1: process rows.
  101. mov rdx, r10 ; (DCTELEM *)
  102. movdqa xmm0, XMMWORD [XMMBLOCK(0,0,rdx,SIZEOF_DCTELEM)]
  103. movdqa xmm1, XMMWORD [XMMBLOCK(1,0,rdx,SIZEOF_DCTELEM)]
  104. movdqa xmm2, XMMWORD [XMMBLOCK(2,0,rdx,SIZEOF_DCTELEM)]
  105. movdqa xmm3, XMMWORD [XMMBLOCK(3,0,rdx,SIZEOF_DCTELEM)]
  106. ; xmm0=(00 01 02 03 04 05 06 07), xmm2=(20 21 22 23 24 25 26 27)
  107. ; xmm1=(10 11 12 13 14 15 16 17), xmm3=(30 31 32 33 34 35 36 37)
  108. movdqa xmm4,xmm0 ; transpose coefficients(phase 1)
  109. punpcklwd xmm0,xmm1 ; xmm0=(00 10 01 11 02 12 03 13)
  110. punpckhwd xmm4,xmm1 ; xmm4=(04 14 05 15 06 16 07 17)
  111. movdqa xmm5,xmm2 ; transpose coefficients(phase 1)
  112. punpcklwd xmm2,xmm3 ; xmm2=(20 30 21 31 22 32 23 33)
  113. punpckhwd xmm5,xmm3 ; xmm5=(24 34 25 35 26 36 27 37)
  114. movdqa xmm6, XMMWORD [XMMBLOCK(4,0,rdx,SIZEOF_DCTELEM)]
  115. movdqa xmm7, XMMWORD [XMMBLOCK(5,0,rdx,SIZEOF_DCTELEM)]
  116. movdqa xmm1, XMMWORD [XMMBLOCK(6,0,rdx,SIZEOF_DCTELEM)]
  117. movdqa xmm3, XMMWORD [XMMBLOCK(7,0,rdx,SIZEOF_DCTELEM)]
  118. ; xmm6=( 4 12 20 28 36 44 52 60), xmm1=( 6 14 22 30 38 46 54 62)
  119. ; xmm7=( 5 13 21 29 37 45 53 61), xmm3=( 7 15 23 31 39 47 55 63)
  120. movdqa XMMWORD [wk(0)], xmm2 ; wk(0)=(20 30 21 31 22 32 23 33)
  121. movdqa XMMWORD [wk(1)], xmm5 ; wk(1)=(24 34 25 35 26 36 27 37)
  122. movdqa xmm2,xmm6 ; transpose coefficients(phase 1)
  123. punpcklwd xmm6,xmm7 ; xmm6=(40 50 41 51 42 52 43 53)
  124. punpckhwd xmm2,xmm7 ; xmm2=(44 54 45 55 46 56 47 57)
  125. movdqa xmm5,xmm1 ; transpose coefficients(phase 1)
  126. punpcklwd xmm1,xmm3 ; xmm1=(60 70 61 71 62 72 63 73)
  127. punpckhwd xmm5,xmm3 ; xmm5=(64 74 65 75 66 76 67 77)
  128. movdqa xmm7,xmm6 ; transpose coefficients(phase 2)
  129. punpckldq xmm6,xmm1 ; xmm6=(40 50 60 70 41 51 61 71)
  130. punpckhdq xmm7,xmm1 ; xmm7=(42 52 62 72 43 53 63 73)
  131. movdqa xmm3,xmm2 ; transpose coefficients(phase 2)
  132. punpckldq xmm2,xmm5 ; xmm2=(44 54 64 74 45 55 65 75)
  133. punpckhdq xmm3,xmm5 ; xmm3=(46 56 66 76 47 57 67 77)
  134. movdqa xmm1, XMMWORD [wk(0)] ; xmm1=(20 30 21 31 22 32 23 33)
  135. movdqa xmm5, XMMWORD [wk(1)] ; xmm5=(24 34 25 35 26 36 27 37)
  136. movdqa XMMWORD [wk(2)], xmm7 ; wk(2)=(42 52 62 72 43 53 63 73)
  137. movdqa XMMWORD [wk(3)], xmm2 ; wk(3)=(44 54 64 74 45 55 65 75)
  138. movdqa xmm7,xmm0 ; transpose coefficients(phase 2)
  139. punpckldq xmm0,xmm1 ; xmm0=(00 10 20 30 01 11 21 31)
  140. punpckhdq xmm7,xmm1 ; xmm7=(02 12 22 32 03 13 23 33)
  141. movdqa xmm2,xmm4 ; transpose coefficients(phase 2)
  142. punpckldq xmm4,xmm5 ; xmm4=(04 14 24 34 05 15 25 35)
  143. punpckhdq xmm2,xmm5 ; xmm2=(06 16 26 36 07 17 27 37)
  144. movdqa xmm1,xmm0 ; transpose coefficients(phase 3)
  145. punpcklqdq xmm0,xmm6 ; xmm0=(00 10 20 30 40 50 60 70)=data0
  146. punpckhqdq xmm1,xmm6 ; xmm1=(01 11 21 31 41 51 61 71)=data1
  147. movdqa xmm5,xmm2 ; transpose coefficients(phase 3)
  148. punpcklqdq xmm2,xmm3 ; xmm2=(06 16 26 36 46 56 66 76)=data6
  149. punpckhqdq xmm5,xmm3 ; xmm5=(07 17 27 37 47 57 67 77)=data7
  150. movdqa xmm6,xmm1
  151. movdqa xmm3,xmm0
  152. psubw xmm1,xmm2 ; xmm1=data1-data6=tmp6
  153. psubw xmm0,xmm5 ; xmm0=data0-data7=tmp7
  154. paddw xmm6,xmm2 ; xmm6=data1+data6=tmp1
  155. paddw xmm3,xmm5 ; xmm3=data0+data7=tmp0
  156. movdqa xmm2, XMMWORD [wk(2)] ; xmm2=(42 52 62 72 43 53 63 73)
  157. movdqa xmm5, XMMWORD [wk(3)] ; xmm5=(44 54 64 74 45 55 65 75)
  158. movdqa XMMWORD [wk(0)], xmm1 ; wk(0)=tmp6
  159. movdqa XMMWORD [wk(1)], xmm0 ; wk(1)=tmp7
  160. movdqa xmm1,xmm7 ; transpose coefficients(phase 3)
  161. punpcklqdq xmm7,xmm2 ; xmm7=(02 12 22 32 42 52 62 72)=data2
  162. punpckhqdq xmm1,xmm2 ; xmm1=(03 13 23 33 43 53 63 73)=data3
  163. movdqa xmm0,xmm4 ; transpose coefficients(phase 3)
  164. punpcklqdq xmm4,xmm5 ; xmm4=(04 14 24 34 44 54 64 74)=data4
  165. punpckhqdq xmm0,xmm5 ; xmm0=(05 15 25 35 45 55 65 75)=data5
  166. movdqa xmm2,xmm1
  167. movdqa xmm5,xmm7
  168. paddw xmm1,xmm4 ; xmm1=data3+data4=tmp3
  169. paddw xmm7,xmm0 ; xmm7=data2+data5=tmp2
  170. psubw xmm2,xmm4 ; xmm2=data3-data4=tmp4
  171. psubw xmm5,xmm0 ; xmm5=data2-data5=tmp5
  172. ; -- Even part
  173. movdqa xmm4,xmm3
  174. movdqa xmm0,xmm6
  175. paddw xmm3,xmm1 ; xmm3=tmp10
  176. paddw xmm6,xmm7 ; xmm6=tmp11
  177. psubw xmm4,xmm1 ; xmm4=tmp13
  178. psubw xmm0,xmm7 ; xmm0=tmp12
  179. movdqa xmm1,xmm3
  180. paddw xmm3,xmm6 ; xmm3=tmp10+tmp11
  181. psubw xmm1,xmm6 ; xmm1=tmp10-tmp11
  182. psllw xmm3,PASS1_BITS ; xmm3=data0
  183. psllw xmm1,PASS1_BITS ; xmm1=data4
  184. movdqa XMMWORD [wk(2)], xmm3 ; wk(2)=data0
  185. movdqa XMMWORD [wk(3)], xmm1 ; wk(3)=data4
  186. ; (Original)
  187. ; z1 = (tmp12 + tmp13) * 0.541196100;
  188. ; data2 = z1 + tmp13 * 0.765366865;
  189. ; data6 = z1 + tmp12 * -1.847759065;
  190. ;
  191. ; (This implementation)
  192. ; data2 = tmp13 * (0.541196100 + 0.765366865) + tmp12 * 0.541196100;
  193. ; data6 = tmp13 * 0.541196100 + tmp12 * (0.541196100 - 1.847759065);
  194. movdqa xmm7,xmm4 ; xmm4=tmp13
  195. movdqa xmm6,xmm4
  196. punpcklwd xmm7,xmm0 ; xmm0=tmp12
  197. punpckhwd xmm6,xmm0
  198. movdqa xmm4,xmm7
  199. movdqa xmm0,xmm6
  200. pmaddwd xmm7,[rel PW_F130_F054] ; xmm7=data2L
  201. pmaddwd xmm6,[rel PW_F130_F054] ; xmm6=data2H
  202. pmaddwd xmm4,[rel PW_F054_MF130] ; xmm4=data6L
  203. pmaddwd xmm0,[rel PW_F054_MF130] ; xmm0=data6H
  204. paddd xmm7,[rel PD_DESCALE_P1]
  205. paddd xmm6,[rel PD_DESCALE_P1]
  206. psrad xmm7,DESCALE_P1
  207. psrad xmm6,DESCALE_P1
  208. paddd xmm4,[rel PD_DESCALE_P1]
  209. paddd xmm0,[rel PD_DESCALE_P1]
  210. psrad xmm4,DESCALE_P1
  211. psrad xmm0,DESCALE_P1
  212. packssdw xmm7,xmm6 ; xmm7=data2
  213. packssdw xmm4,xmm0 ; xmm4=data6
  214. movdqa XMMWORD [wk(4)], xmm7 ; wk(4)=data2
  215. movdqa XMMWORD [wk(5)], xmm4 ; wk(5)=data6
  216. ; -- Odd part
  217. movdqa xmm3, XMMWORD [wk(0)] ; xmm3=tmp6
  218. movdqa xmm1, XMMWORD [wk(1)] ; xmm1=tmp7
  219. movdqa xmm6,xmm2 ; xmm2=tmp4
  220. movdqa xmm0,xmm5 ; xmm5=tmp5
  221. paddw xmm6,xmm3 ; xmm6=z3
  222. paddw xmm0,xmm1 ; xmm0=z4
  223. ; (Original)
  224. ; z5 = (z3 + z4) * 1.175875602;
  225. ; z3 = z3 * -1.961570560; z4 = z4 * -0.390180644;
  226. ; z3 += z5; z4 += z5;
  227. ;
  228. ; (This implementation)
  229. ; z3 = z3 * (1.175875602 - 1.961570560) + z4 * 1.175875602;
  230. ; z4 = z3 * 1.175875602 + z4 * (1.175875602 - 0.390180644);
  231. movdqa xmm7,xmm6
  232. movdqa xmm4,xmm6
  233. punpcklwd xmm7,xmm0
  234. punpckhwd xmm4,xmm0
  235. movdqa xmm6,xmm7
  236. movdqa xmm0,xmm4
  237. pmaddwd xmm7,[rel PW_MF078_F117] ; xmm7=z3L
  238. pmaddwd xmm4,[rel PW_MF078_F117] ; xmm4=z3H
  239. pmaddwd xmm6,[rel PW_F117_F078] ; xmm6=z4L
  240. pmaddwd xmm0,[rel PW_F117_F078] ; xmm0=z4H
  241. movdqa XMMWORD [wk(0)], xmm7 ; wk(0)=z3L
  242. movdqa XMMWORD [wk(1)], xmm4 ; wk(1)=z3H
  243. ; (Original)
  244. ; z1 = tmp4 + tmp7; z2 = tmp5 + tmp6;
  245. ; tmp4 = tmp4 * 0.298631336; tmp5 = tmp5 * 2.053119869;
  246. ; tmp6 = tmp6 * 3.072711026; tmp7 = tmp7 * 1.501321110;
  247. ; z1 = z1 * -0.899976223; z2 = z2 * -2.562915447;
  248. ; data7 = tmp4 + z1 + z3; data5 = tmp5 + z2 + z4;
  249. ; data3 = tmp6 + z2 + z3; data1 = tmp7 + z1 + z4;
  250. ;
  251. ; (This implementation)
  252. ; tmp4 = tmp4 * (0.298631336 - 0.899976223) + tmp7 * -0.899976223;
  253. ; tmp5 = tmp5 * (2.053119869 - 2.562915447) + tmp6 * -2.562915447;
  254. ; tmp6 = tmp5 * -2.562915447 + tmp6 * (3.072711026 - 2.562915447);
  255. ; tmp7 = tmp4 * -0.899976223 + tmp7 * (1.501321110 - 0.899976223);
  256. ; data7 = tmp4 + z3; data5 = tmp5 + z4;
  257. ; data3 = tmp6 + z3; data1 = tmp7 + z4;
  258. movdqa xmm7,xmm2
  259. movdqa xmm4,xmm2
  260. punpcklwd xmm7,xmm1
  261. punpckhwd xmm4,xmm1
  262. movdqa xmm2,xmm7
  263. movdqa xmm1,xmm4
  264. pmaddwd xmm7,[rel PW_MF060_MF089] ; xmm7=tmp4L
  265. pmaddwd xmm4,[rel PW_MF060_MF089] ; xmm4=tmp4H
  266. pmaddwd xmm2,[rel PW_MF089_F060] ; xmm2=tmp7L
  267. pmaddwd xmm1,[rel PW_MF089_F060] ; xmm1=tmp7H
  268. paddd xmm7, XMMWORD [wk(0)] ; xmm7=data7L
  269. paddd xmm4, XMMWORD [wk(1)] ; xmm4=data7H
  270. paddd xmm2,xmm6 ; xmm2=data1L
  271. paddd xmm1,xmm0 ; xmm1=data1H
  272. paddd xmm7,[rel PD_DESCALE_P1]
  273. paddd xmm4,[rel PD_DESCALE_P1]
  274. psrad xmm7,DESCALE_P1
  275. psrad xmm4,DESCALE_P1
  276. paddd xmm2,[rel PD_DESCALE_P1]
  277. paddd xmm1,[rel PD_DESCALE_P1]
  278. psrad xmm2,DESCALE_P1
  279. psrad xmm1,DESCALE_P1
  280. packssdw xmm7,xmm4 ; xmm7=data7
  281. packssdw xmm2,xmm1 ; xmm2=data1
  282. movdqa xmm4,xmm5
  283. movdqa xmm1,xmm5
  284. punpcklwd xmm4,xmm3
  285. punpckhwd xmm1,xmm3
  286. movdqa xmm5,xmm4
  287. movdqa xmm3,xmm1
  288. pmaddwd xmm4,[rel PW_MF050_MF256] ; xmm4=tmp5L
  289. pmaddwd xmm1,[rel PW_MF050_MF256] ; xmm1=tmp5H
  290. pmaddwd xmm5,[rel PW_MF256_F050] ; xmm5=tmp6L
  291. pmaddwd xmm3,[rel PW_MF256_F050] ; xmm3=tmp6H
  292. paddd xmm4,xmm6 ; xmm4=data5L
  293. paddd xmm1,xmm0 ; xmm1=data5H
  294. paddd xmm5, XMMWORD [wk(0)] ; xmm5=data3L
  295. paddd xmm3, XMMWORD [wk(1)] ; xmm3=data3H
  296. paddd xmm4,[rel PD_DESCALE_P1]
  297. paddd xmm1,[rel PD_DESCALE_P1]
  298. psrad xmm4,DESCALE_P1
  299. psrad xmm1,DESCALE_P1
  300. paddd xmm5,[rel PD_DESCALE_P1]
  301. paddd xmm3,[rel PD_DESCALE_P1]
  302. psrad xmm5,DESCALE_P1
  303. psrad xmm3,DESCALE_P1
  304. packssdw xmm4,xmm1 ; xmm4=data5
  305. packssdw xmm5,xmm3 ; xmm5=data3
  306. ; ---- Pass 2: process columns.
  307. movdqa xmm6, XMMWORD [wk(2)] ; xmm6=col0
  308. movdqa xmm0, XMMWORD [wk(4)] ; xmm0=col2
  309. ; xmm6=(00 10 20 30 40 50 60 70), xmm0=(02 12 22 32 42 52 62 72)
  310. ; xmm2=(01 11 21 31 41 51 61 71), xmm5=(03 13 23 33 43 53 63 73)
  311. movdqa xmm1,xmm6 ; transpose coefficients(phase 1)
  312. punpcklwd xmm6,xmm2 ; xmm6=(00 01 10 11 20 21 30 31)
  313. punpckhwd xmm1,xmm2 ; xmm1=(40 41 50 51 60 61 70 71)
  314. movdqa xmm3,xmm0 ; transpose coefficients(phase 1)
  315. punpcklwd xmm0,xmm5 ; xmm0=(02 03 12 13 22 23 32 33)
  316. punpckhwd xmm3,xmm5 ; xmm3=(42 43 52 53 62 63 72 73)
  317. movdqa xmm2, XMMWORD [wk(3)] ; xmm2=col4
  318. movdqa xmm5, XMMWORD [wk(5)] ; xmm5=col6
  319. ; xmm2=(04 14 24 34 44 54 64 74), xmm5=(06 16 26 36 46 56 66 76)
  320. ; xmm4=(05 15 25 35 45 55 65 75), xmm7=(07 17 27 37 47 57 67 77)
  321. movdqa XMMWORD [wk(0)], xmm0 ; wk(0)=(02 03 12 13 22 23 32 33)
  322. movdqa XMMWORD [wk(1)], xmm3 ; wk(1)=(42 43 52 53 62 63 72 73)
  323. movdqa xmm0,xmm2 ; transpose coefficients(phase 1)
  324. punpcklwd xmm2,xmm4 ; xmm2=(04 05 14 15 24 25 34 35)
  325. punpckhwd xmm0,xmm4 ; xmm0=(44 45 54 55 64 65 74 75)
  326. movdqa xmm3,xmm5 ; transpose coefficients(phase 1)
  327. punpcklwd xmm5,xmm7 ; xmm5=(06 07 16 17 26 27 36 37)
  328. punpckhwd xmm3,xmm7 ; xmm3=(46 47 56 57 66 67 76 77)
  329. movdqa xmm4,xmm2 ; transpose coefficients(phase 2)
  330. punpckldq xmm2,xmm5 ; xmm2=(04 05 06 07 14 15 16 17)
  331. punpckhdq xmm4,xmm5 ; xmm4=(24 25 26 27 34 35 36 37)
  332. movdqa xmm7,xmm0 ; transpose coefficients(phase 2)
  333. punpckldq xmm0,xmm3 ; xmm0=(44 45 46 47 54 55 56 57)
  334. punpckhdq xmm7,xmm3 ; xmm7=(64 65 66 67 74 75 76 77)
  335. movdqa xmm5, XMMWORD [wk(0)] ; xmm5=(02 03 12 13 22 23 32 33)
  336. movdqa xmm3, XMMWORD [wk(1)] ; xmm3=(42 43 52 53 62 63 72 73)
  337. movdqa XMMWORD [wk(2)], xmm4 ; wk(2)=(24 25 26 27 34 35 36 37)
  338. movdqa XMMWORD [wk(3)], xmm0 ; wk(3)=(44 45 46 47 54 55 56 57)
  339. movdqa xmm4,xmm6 ; transpose coefficients(phase 2)
  340. punpckldq xmm6,xmm5 ; xmm6=(00 01 02 03 10 11 12 13)
  341. punpckhdq xmm4,xmm5 ; xmm4=(20 21 22 23 30 31 32 33)
  342. movdqa xmm0,xmm1 ; transpose coefficients(phase 2)
  343. punpckldq xmm1,xmm3 ; xmm1=(40 41 42 43 50 51 52 53)
  344. punpckhdq xmm0,xmm3 ; xmm0=(60 61 62 63 70 71 72 73)
  345. movdqa xmm5,xmm6 ; transpose coefficients(phase 3)
  346. punpcklqdq xmm6,xmm2 ; xmm6=(00 01 02 03 04 05 06 07)=data0
  347. punpckhqdq xmm5,xmm2 ; xmm5=(10 11 12 13 14 15 16 17)=data1
  348. movdqa xmm3,xmm0 ; transpose coefficients(phase 3)
  349. punpcklqdq xmm0,xmm7 ; xmm0=(60 61 62 63 64 65 66 67)=data6
  350. punpckhqdq xmm3,xmm7 ; xmm3=(70 71 72 73 74 75 76 77)=data7
  351. movdqa xmm2,xmm5
  352. movdqa xmm7,xmm6
  353. psubw xmm5,xmm0 ; xmm5=data1-data6=tmp6
  354. psubw xmm6,xmm3 ; xmm6=data0-data7=tmp7
  355. paddw xmm2,xmm0 ; xmm2=data1+data6=tmp1
  356. paddw xmm7,xmm3 ; xmm7=data0+data7=tmp0
  357. movdqa xmm0, XMMWORD [wk(2)] ; xmm0=(24 25 26 27 34 35 36 37)
  358. movdqa xmm3, XMMWORD [wk(3)] ; xmm3=(44 45 46 47 54 55 56 57)
  359. movdqa XMMWORD [wk(0)], xmm5 ; wk(0)=tmp6
  360. movdqa XMMWORD [wk(1)], xmm6 ; wk(1)=tmp7
  361. movdqa xmm5,xmm4 ; transpose coefficients(phase 3)
  362. punpcklqdq xmm4,xmm0 ; xmm4=(20 21 22 23 24 25 26 27)=data2
  363. punpckhqdq xmm5,xmm0 ; xmm5=(30 31 32 33 34 35 36 37)=data3
  364. movdqa xmm6,xmm1 ; transpose coefficients(phase 3)
  365. punpcklqdq xmm1,xmm3 ; xmm1=(40 41 42 43 44 45 46 47)=data4
  366. punpckhqdq xmm6,xmm3 ; xmm6=(50 51 52 53 54 55 56 57)=data5
  367. movdqa xmm0,xmm5
  368. movdqa xmm3,xmm4
  369. paddw xmm5,xmm1 ; xmm5=data3+data4=tmp3
  370. paddw xmm4,xmm6 ; xmm4=data2+data5=tmp2
  371. psubw xmm0,xmm1 ; xmm0=data3-data4=tmp4
  372. psubw xmm3,xmm6 ; xmm3=data2-data5=tmp5
  373. ; -- Even part
  374. movdqa xmm1,xmm7
  375. movdqa xmm6,xmm2
  376. paddw xmm7,xmm5 ; xmm7=tmp10
  377. paddw xmm2,xmm4 ; xmm2=tmp11
  378. psubw xmm1,xmm5 ; xmm1=tmp13
  379. psubw xmm6,xmm4 ; xmm6=tmp12
  380. movdqa xmm5,xmm7
  381. paddw xmm7,xmm2 ; xmm7=tmp10+tmp11
  382. psubw xmm5,xmm2 ; xmm5=tmp10-tmp11
  383. paddw xmm7,[rel PW_DESCALE_P2X]
  384. paddw xmm5,[rel PW_DESCALE_P2X]
  385. psraw xmm7,PASS1_BITS ; xmm7=data0
  386. psraw xmm5,PASS1_BITS ; xmm5=data4
  387. movdqa XMMWORD [XMMBLOCK(0,0,rdx,SIZEOF_DCTELEM)], xmm7
  388. movdqa XMMWORD [XMMBLOCK(4,0,rdx,SIZEOF_DCTELEM)], xmm5
  389. ; (Original)
  390. ; z1 = (tmp12 + tmp13) * 0.541196100;
  391. ; data2 = z1 + tmp13 * 0.765366865;
  392. ; data6 = z1 + tmp12 * -1.847759065;
  393. ;
  394. ; (This implementation)
  395. ; data2 = tmp13 * (0.541196100 + 0.765366865) + tmp12 * 0.541196100;
  396. ; data6 = tmp13 * 0.541196100 + tmp12 * (0.541196100 - 1.847759065);
  397. movdqa xmm4,xmm1 ; xmm1=tmp13
  398. movdqa xmm2,xmm1
  399. punpcklwd xmm4,xmm6 ; xmm6=tmp12
  400. punpckhwd xmm2,xmm6
  401. movdqa xmm1,xmm4
  402. movdqa xmm6,xmm2
  403. pmaddwd xmm4,[rel PW_F130_F054] ; xmm4=data2L
  404. pmaddwd xmm2,[rel PW_F130_F054] ; xmm2=data2H
  405. pmaddwd xmm1,[rel PW_F054_MF130] ; xmm1=data6L
  406. pmaddwd xmm6,[rel PW_F054_MF130] ; xmm6=data6H
  407. paddd xmm4,[rel PD_DESCALE_P2]
  408. paddd xmm2,[rel PD_DESCALE_P2]
  409. psrad xmm4,DESCALE_P2
  410. psrad xmm2,DESCALE_P2
  411. paddd xmm1,[rel PD_DESCALE_P2]
  412. paddd xmm6,[rel PD_DESCALE_P2]
  413. psrad xmm1,DESCALE_P2
  414. psrad xmm6,DESCALE_P2
  415. packssdw xmm4,xmm2 ; xmm4=data2
  416. packssdw xmm1,xmm6 ; xmm1=data6
  417. movdqa XMMWORD [XMMBLOCK(2,0,rdx,SIZEOF_DCTELEM)], xmm4
  418. movdqa XMMWORD [XMMBLOCK(6,0,rdx,SIZEOF_DCTELEM)], xmm1
  419. ; -- Odd part
  420. movdqa xmm7, XMMWORD [wk(0)] ; xmm7=tmp6
  421. movdqa xmm5, XMMWORD [wk(1)] ; xmm5=tmp7
  422. movdqa xmm2,xmm0 ; xmm0=tmp4
  423. movdqa xmm6,xmm3 ; xmm3=tmp5
  424. paddw xmm2,xmm7 ; xmm2=z3
  425. paddw xmm6,xmm5 ; xmm6=z4
  426. ; (Original)
  427. ; z5 = (z3 + z4) * 1.175875602;
  428. ; z3 = z3 * -1.961570560; z4 = z4 * -0.390180644;
  429. ; z3 += z5; z4 += z5;
  430. ;
  431. ; (This implementation)
  432. ; z3 = z3 * (1.175875602 - 1.961570560) + z4 * 1.175875602;
  433. ; z4 = z3 * 1.175875602 + z4 * (1.175875602 - 0.390180644);
  434. movdqa xmm4,xmm2
  435. movdqa xmm1,xmm2
  436. punpcklwd xmm4,xmm6
  437. punpckhwd xmm1,xmm6
  438. movdqa xmm2,xmm4
  439. movdqa xmm6,xmm1
  440. pmaddwd xmm4,[rel PW_MF078_F117] ; xmm4=z3L
  441. pmaddwd xmm1,[rel PW_MF078_F117] ; xmm1=z3H
  442. pmaddwd xmm2,[rel PW_F117_F078] ; xmm2=z4L
  443. pmaddwd xmm6,[rel PW_F117_F078] ; xmm6=z4H
  444. movdqa XMMWORD [wk(0)], xmm4 ; wk(0)=z3L
  445. movdqa XMMWORD [wk(1)], xmm1 ; wk(1)=z3H
  446. ; (Original)
  447. ; z1 = tmp4 + tmp7; z2 = tmp5 + tmp6;
  448. ; tmp4 = tmp4 * 0.298631336; tmp5 = tmp5 * 2.053119869;
  449. ; tmp6 = tmp6 * 3.072711026; tmp7 = tmp7 * 1.501321110;
  450. ; z1 = z1 * -0.899976223; z2 = z2 * -2.562915447;
  451. ; data7 = tmp4 + z1 + z3; data5 = tmp5 + z2 + z4;
  452. ; data3 = tmp6 + z2 + z3; data1 = tmp7 + z1 + z4;
  453. ;
  454. ; (This implementation)
  455. ; tmp4 = tmp4 * (0.298631336 - 0.899976223) + tmp7 * -0.899976223;
  456. ; tmp5 = tmp5 * (2.053119869 - 2.562915447) + tmp6 * -2.562915447;
  457. ; tmp6 = tmp5 * -2.562915447 + tmp6 * (3.072711026 - 2.562915447);
  458. ; tmp7 = tmp4 * -0.899976223 + tmp7 * (1.501321110 - 0.899976223);
  459. ; data7 = tmp4 + z3; data5 = tmp5 + z4;
  460. ; data3 = tmp6 + z3; data1 = tmp7 + z4;
  461. movdqa xmm4,xmm0
  462. movdqa xmm1,xmm0
  463. punpcklwd xmm4,xmm5
  464. punpckhwd xmm1,xmm5
  465. movdqa xmm0,xmm4
  466. movdqa xmm5,xmm1
  467. pmaddwd xmm4,[rel PW_MF060_MF089] ; xmm4=tmp4L
  468. pmaddwd xmm1,[rel PW_MF060_MF089] ; xmm1=tmp4H
  469. pmaddwd xmm0,[rel PW_MF089_F060] ; xmm0=tmp7L
  470. pmaddwd xmm5,[rel PW_MF089_F060] ; xmm5=tmp7H
  471. paddd xmm4, XMMWORD [wk(0)] ; xmm4=data7L
  472. paddd xmm1, XMMWORD [wk(1)] ; xmm1=data7H
  473. paddd xmm0,xmm2 ; xmm0=data1L
  474. paddd xmm5,xmm6 ; xmm5=data1H
  475. paddd xmm4,[rel PD_DESCALE_P2]
  476. paddd xmm1,[rel PD_DESCALE_P2]
  477. psrad xmm4,DESCALE_P2
  478. psrad xmm1,DESCALE_P2
  479. paddd xmm0,[rel PD_DESCALE_P2]
  480. paddd xmm5,[rel PD_DESCALE_P2]
  481. psrad xmm0,DESCALE_P2
  482. psrad xmm5,DESCALE_P2
  483. packssdw xmm4,xmm1 ; xmm4=data7
  484. packssdw xmm0,xmm5 ; xmm0=data1
  485. movdqa XMMWORD [XMMBLOCK(7,0,rdx,SIZEOF_DCTELEM)], xmm4
  486. movdqa XMMWORD [XMMBLOCK(1,0,rdx,SIZEOF_DCTELEM)], xmm0
  487. movdqa xmm1,xmm3
  488. movdqa xmm5,xmm3
  489. punpcklwd xmm1,xmm7
  490. punpckhwd xmm5,xmm7
  491. movdqa xmm3,xmm1
  492. movdqa xmm7,xmm5
  493. pmaddwd xmm1,[rel PW_MF050_MF256] ; xmm1=tmp5L
  494. pmaddwd xmm5,[rel PW_MF050_MF256] ; xmm5=tmp5H
  495. pmaddwd xmm3,[rel PW_MF256_F050] ; xmm3=tmp6L
  496. pmaddwd xmm7,[rel PW_MF256_F050] ; xmm7=tmp6H
  497. paddd xmm1,xmm2 ; xmm1=data5L
  498. paddd xmm5,xmm6 ; xmm5=data5H
  499. paddd xmm3, XMMWORD [wk(0)] ; xmm3=data3L
  500. paddd xmm7, XMMWORD [wk(1)] ; xmm7=data3H
  501. paddd xmm1,[rel PD_DESCALE_P2]
  502. paddd xmm5,[rel PD_DESCALE_P2]
  503. psrad xmm1,DESCALE_P2
  504. psrad xmm5,DESCALE_P2
  505. paddd xmm3,[rel PD_DESCALE_P2]
  506. paddd xmm7,[rel PD_DESCALE_P2]
  507. psrad xmm3,DESCALE_P2
  508. psrad xmm7,DESCALE_P2
  509. packssdw xmm1,xmm5 ; xmm1=data5
  510. packssdw xmm3,xmm7 ; xmm3=data3
  511. movdqa XMMWORD [XMMBLOCK(5,0,rdx,SIZEOF_DCTELEM)], xmm1
  512. movdqa XMMWORD [XMMBLOCK(3,0,rdx,SIZEOF_DCTELEM)], xmm3
  513. uncollect_args
  514. mov rsp,rbp ; rsp <- aligned rbp
  515. pop rsp ; rsp <- original rbp
  516. pop rbp
  517. ret
  518. ; For some reason, the OS X linker does not honor the request to align the
  519. ; segment unless we do this.
  520. align 16