/*

 * Copyright (c) 2010  David Sorokin <david.sorokin@gmail.com>

 * Copyright (c) 2010  rampelstinskin@gmail.com

 * All rights reserved.

 *

 * Redistribution and use in source and binary forms, with or without

 * modification, are permitted provided that the following conditions

 * are met:

 *    1. Redistributions of source code must retain the above copyright

 *       notice, this list of conditions and the following disclaimer.

 *    2. Redistributions in binary form must reproduce the above copyright

 *       notice, this list of conditions and the following disclaimer in the

 *       documentation and/or other materials provided with the distribution.

 * 

 * THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR

 * IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES

 * OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN

 * NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,

 * SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED

 * TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR

 * PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF

 * LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING

 * NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS

 * SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.

 */



using Nemerle;

using Nemerle.Utility;

using Nemerle.Collections;



using System;

using System.Collections.Generic;

using System.Linq;



namespace Nemerle.ComputationExpressions.Internal

{

  /// <summary>

  /// Appends two enumerations using the tail call optimization.

  /// </summary>

  [Record]

  public class AppendEnumerable[T] : IEnumerable[T]

  {

    private ts1 : IEnumerable[T];

    private ts2 : IEnumerable[T];

    

    public GetEnumerator () : IEnumerator[T]

    {

      SubEnumerator (ts1.GetEnumerator (), () => ts2.GetEnumerator ())

    }

    

    public class SubEnumerator : IEnumerator[T]

    {

      private mutable ts : IEnumerator[T];

      private mutable cont : void -> IEnumerator[T];

      

      public this (ts : IEnumerator[T], cont : void -> IEnumerator[T])

      {

        this.ts = ts;

        this.cont = cont;

      }

      

      public Reset () : void

      {

        throw NotSupportedException ()

      }

      

      public Dispose () : void

      {

        ts.Dispose ();

      }

      

      public MoveNext () : bool

      {

        if (ts.MoveNext ())

          true

        else if (cont != null)

        {

          

          ts.Dispose ();

          ts = cont ();

          cont = null;

          

          match (ts)

          {

            | subts is SubEnumerator => 

              ts = subts.ts;

              cont = subts.cont;

            | _ => ()

          }

          

          MoveNext ();

        }

        else

          false

      }

      

      public Current : T

      {

        get

        {

          ts.Current

        }

      }

    }

  }

}