/trunk/bindings/f77/CMakeLists.txt

# bindings/f77/CMakeLists.txt
### Process this file with cmake to produce Makefile
###
# Copyright (C) 2006 Andrew Ross
#
# This file is part of PLplot.
#
# PLplot is free software; you can redistribute it and/or modify
# it under the terms of the GNU Library General Public License as published
# by the Free Software Foundation; version 2 of the License.
#
# PLplot is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU Library General Public License for more details.
#
# You should have received a copy of the GNU Library General Public License
# along with PLplot; if not, write to the Free Software
# Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301  USA

if(ENABLE_f77)

  ## Generate source files depending on type of PLFLT
  ## Note: sed will possibly fail on windows. Would this be better
  ## done using the cmake configure_file option eventually?
  ## Answer: no.  The configuration option requires @ placeholders
  ## throughout the f77 source files which make them extremely hard
  ## to understand/maintain.  Instead, we ask those Windows users who
  ## want the single-precision library to install sed (from MSYS or
  ## wherever).
  if(PL_DOUBLE)
    add_custom_command(
      OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/sfstubs.f
      COMMAND ${CMAKE_COMMAND}
      -E copy_if_different ${CMAKE_CURRENT_SOURCE_DIR}/sfstubs.fm4 ${CMAKE_CURRENT_BINARY_DIR}/sfstubs.f
      DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/sfstubs.fm4
      )
    add_custom_command(
      OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/plplot_parameters.h
      COMMAND ${CMAKE_COMMAND}
      -E copy_if_different ${CMAKE_CURRENT_SOURCE_DIR}/plplot_parameters.fm4 ${CMAKE_CURRENT_BINARY_DIR}/plplot_parameters.h
      DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/plplot_parameters.fm4
      )
  else(PL_DOUBLE)
    add_custom_command(
      OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/sfstubs.f
      COMMAND sed
      -f ${CMAKE_CURRENT_SOURCE_DIR}/double2single.sed ${CMAKE_CURRENT_SOURCE_DIR}/sfstubs.fm4 > ${CMAKE_CURRENT_BINARY_DIR}/sfstubs.f
      DEPENDS
      ${CMAKE_CURRENT_SOURCE_DIR}/double2single.sed
      ${CMAKE_CURRENT_SOURCE_DIR}/sfstubs.fm4
      )

    # For this case, use more extensive examples/f77 sed script since
    # have double-precision floating-point constants to convert.
    add_custom_command(
      OUTPUT
      ${CMAKE_CURRENT_BINARY_DIR}/plplot_parameters.h
      COMMAND sed
      -f ${CMAKE_SOURCE_DIR}/examples/f77/double2single.sed ${CMAKE_CURRENT_SOURCE_DIR}/plplot_parameters.fm4 > ${CMAKE_CURRENT_BINARY_DIR}/plplot_parameters.h
      DEPENDS
      ${CMAKE_SOURCE_DIR}/examples/f77/double2single.sed
      ${CMAKE_CURRENT_SOURCE_DIR}/plplot_parameters.fm4
      )
  endif(PL_DOUBLE)

  add_custom_target(build_plplot_parameters_h ALL
    DEPENDS
    ${CMAKE_CURRENT_BINARY_DIR}/plplot_parameters.h
    )

  install(
    FILES
    ${CMAKE_CURRENT_BINARY_DIR}/plplot_parameters.h
    DESTINATION ${F77_INCLUDE_DIR}
    )

  set_source_files_properties(${CMAKE_CURRENT_BINARY_DIR}/sfstubs.f
    PROPERTIES GENERATED ON)

  if(WIN32)
    # Set the flags for the C compiler. The C stubs need to have the
    # correction case and calling convention for the Fortran compiler
    IF(TARGET_FORTRAN MATCHES "IVF")
      SET(DEFFILE "_ifort")
      SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /DIVF")
    ELSEIF(TARGET_FORTRAN MATCHES "CVF")
      SET(DEFFILE "")
      SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /DCVF")
    ENDIF(TARGET_FORTRAN MATCHES "IVF")
  endif(WIN32)

  if(F77_CMD_LINE)
    set(HAVE_F77PARSE_CL_FALSE C)
  else(F77_CMD_LINE)
    set(HAVE_F77PARSE_CL_TRUE C)
  endif(F77_CMD_LINE)

  configure_file(
    ${CMAKE_CURRENT_SOURCE_DIR}/configurable.f.cmake
    ${CMAKE_CURRENT_BINARY_DIR}/configurable.f
    )

  # Set the include path
  include_directories(
    ${CMAKE_CURRENT_SOURCE_DIR}
    ${CMAKE_SOURCE_DIR}/lib/qsastime
    ${CMAKE_SOURCE_DIR}/include
    ${CMAKE_BINARY_DIR}
    ${CMAKE_BINARY_DIR}/include
    )

  ## Build C part of F77 bindings

  # Check consistency of plplot_parameters.fm4.
  add_custom_target(
    check_f77_parameters
    COMMAND ${CMAKE_COMMAND} -E remove -f 
    ${CMAKE_CURRENT_BINARY_DIR}/plplot_parameters.fm4_compare
    COMMAND
    sed -f ${CMAKE_CURRENT_SOURCE_DIR}/global_defines.sed < 
    ${CMAKE_SOURCE_DIR}/bindings/swig-support/plplotcapi.i > 
    ${CMAKE_CURRENT_BINARY_DIR}/plplot_parameters.fm4_compare
    COMMAND
    ${CMAKE_COMMAND} -E echo "Check that plplot_parameters.fm4 is consistent with the #defines in bindings/swig-support/plplotcapi.i"
    COMMAND
    cmp ${CMAKE_CURRENT_SOURCE_DIR}/plplot_parameters.fm4
    ${CMAKE_CURRENT_BINARY_DIR}/plplot_parameters.fm4_compare
    )

  set(plplotf77c${LIB_TAG}_LIB_SRCS
    sc3d.c
    sccont.c
    scstubs.c
    )

  if(BUILD_SHARED_LIBS)
    SET_SOURCE_FILES_PROPERTIES( ${plplotf77c${LIB_TAG}_LIB_SRCS}
      PROPERTIES COMPILE_FLAGS "-DUSINGDLL" )
  endif(BUILD_SHARED_LIBS)

  add_library(plplotf77c${LIB_TAG} ${plplotf77c${LIB_TAG}_LIB_SRCS})

  target_link_libraries(plplotf77c${LIB_TAG} plplot${LIB_TAG})

  if(USE_RPATH)
    get_target_property(LIB_INSTALL_RPATH plplot${LIB_TAG} INSTALL_RPATH)
    set_target_properties(plplotf77c${LIB_TAG}
      PROPERTIES
      SOVERSION ${plplotf77_SOVERSION}
      VERSION ${plplotf77_VERSION}
      INSTALL_RPATH "${LIB_INSTALL_RPATH}"
      INSTALL_NAME_DIR "${LIB_DIR}"
      )
  else(USE_RPATH)
    set_target_properties(plplotf77c${LIB_TAG}
      PROPERTIES
      SOVERSION ${plplotf77_SOVERSION}
      VERSION ${plplotf77_VERSION}
      INSTALL_NAME_DIR "${LIB_DIR}"
      )
  endif(USE_RPATH)

  # Set the path and the suffix for the (shared) libraries
  if(CYGWIN)
    if(BUILD_SHARED_LIBS)
      set(SHLIB_DIR "${BIN_DIR}")
    endif(BUILD_SHARED_LIBS)
    set(VERSION_SUFFIX "-${plplotf77_VERSION}")
  else(CYGWIN)
    set(VERSION_SUFFIX "")
  endif(CYGWIN)

  install(TARGETS plplotf77c${LIB_TAG}
    EXPORT export_plplot
    ARCHIVE DESTINATION ${LIB_DIR}
    LIBRARY DESTINATION ${LIB_DIR}
    RUNTIME DESTINATION ${BIN_DIR}
    )

  ## Build fortran part of F77 bindings
  set(plplotf77${LIB_TAG}_LIB_SRCS
    strutil.f
    sfstubs.f
    configurable.f
    )

  if(WIN32 AND BUILD_SHARED_LIBS AND NOT CYGWIN AND NOT MINGW)
    SET(plplotf77${LIB_TAG}_LIB_SRCS ${plplotf77${LIB_TAG}_LIB_SRCS} plplotf77${DEFFILE}.def)
  endif(WIN32 AND BUILD_SHARED_LIBS AND NOT CYGWIN AND NOT MINGW)

  add_library(plplotf77${LIB_TAG} ${plplotf77${LIB_TAG}_LIB_SRCS})

  if(NON_TRANSITIVE)
    # empty list ==> non-transitive linking for everything that links to
    # libplplotf77cd and libplplotf77d in the shared libraries case.
    target_link_libraries(plplotf77c${LIB_TAG} LINK_INTERFACE_LIBRARIES)
    target_link_libraries(plplotf77${LIB_TAG} LINK_INTERFACE_LIBRARIES)
    # This configures the pkg-config method to use non-transitive linking.
    set(PC_REQUIRES_TAG "Requires.private")
  else(NON_TRANSITIVE)
    # This configures the pkg-config method to use transitive linking
    set(PC_REQUIRES_TAG "Requires")
  endif(NON_TRANSITIVE)

  target_link_libraries(plplotf77${LIB_TAG}  plplotf77c${LIB_TAG})

  if(USE_RPATH)
    set_target_properties(plplotf77${LIB_TAG}
      PROPERTIES
      SOVERSION ${plplotf77_SOVERSION}
      VERSION ${plplotf77_VERSION}
      INSTALL_RPATH "${LIB_INSTALL_RPATH}"
      INSTALL_NAME_DIR "${LIB_DIR}"
      )
  else(USE_RPATH)
    set_target_properties(plplotf77${LIB_TAG}
      PROPERTIES
      SOVERSION ${plplotf77_SOVERSION}
      VERSION ${plplotf77_VERSION}
      INSTALL_NAME_DIR "${LIB_DIR}"
      )
  endif(USE_RPATH)

  install(TARGETS plplotf77${LIB_TAG}
    EXPORT export_plplot
    ARCHIVE DESTINATION ${LIB_DIR}
    LIBRARY DESTINATION ${LIB_DIR}
    RUNTIME DESTINATION ${BIN_DIR}
    )

  # Configure pkg-config *.pc file corresponding to libplplotf77${LIB_TAG}
  if(PKG_CONFIG_EXECUTABLE)
    if(LIB_TAG)
      set(PC_PRECISION "double")
    else(LIB_TAG)
      set(PC_PRECISION "single")
    endif(LIB_TAG)
    # Each list element must consist of a colon-separated string with the
    # following fields which are parsed out in the foreach loop below and
    # used to configure the corresponding pkg-config *.pc file.
    # BINDING 	      	  - ENABLE_${BINDING} keeps track of whether a
    # 			    binding has been enabled (ON) or not (OFF).
    #			    Also, ${BINDING} used to determine PC_FILE_SUFFIX
    #			    which helps to determine name of configured
    #			    *.pc file.
    # PC_SHORT_NAME	  - Used in *.pc NAME: field
    # PC_LONG_NAME	  - Used in *.pc Description: field
    # PC_LIBRARY_NAME	  - Used in *.pc Libs: field
    #                         Also used to determine PC_LINK_FLAGS and
    #                         PC_COMPILE_FLAGS used in *.pc Libs: and Cflags:
    #			    fields.
    set(PC_DATA "f77:F77:F77 bindings, :plplotf77${LIB_TAG}${VERSION_SUFFIX}")

    string(REGEX REPLACE "^(.*):.*:.*:.*$" "\\1" BINDING ${PC_DATA})
    set(PC_FILE_SUFFIX "-${BINDING}")
    set(PC_REQUIRES "plplot${LIB_TAG}")
    string(REGEX REPLACE "^.*:(.*):.*:.*$" "\\1" PC_SHORT_NAME ${PC_DATA})
    string(REGEX REPLACE "^.*:.*:(.*):.*$" "\\1" PC_LONG_NAME ${PC_DATA})
    string(REGEX REPLACE "^.*:.*:.*:(.*)$" "\\1" PC_LIBRARY_NAME ${PC_DATA})
    set(PC_LINK_FLAGS "${lib${PC_LIBRARY_NAME}_LINK_FLAGS}")
    set(PC_COMPILE_FLAGS "${lib${PC_LIBRARY_NAME}_COMPILE_FLAGS}")
    set(PC_COMPILE_FLAGS "-I${F77_INCLUDE_DIR} ${PC_COMPILE_FLAGS}")
    set(PC_LINK_FLAGS
      "-l${PC_LIBRARY_NAME} -lplplotf77c${LIB_TAG}${VERSION_SUFFIX} ${PC_LINK_FLAGS}"
      )
    set(PC_CONFIGURED_FILE
      ${CMAKE_BINARY_DIR}/pkgcfg/plplot${LIB_TAG}${PC_FILE_SUFFIX}.pc
      )
    configure_file(
      ${CMAKE_SOURCE_DIR}/pkgcfg/plplot-template.pc.cmake
      ${PC_CONFIGURED_FILE}
      @ONLY
      )
    install(FILES ${PC_CONFIGURED_FILE} DESTINATION ${PKG_CONFIG_DIR})
  endif(PKG_CONFIG_EXECUTABLE)

endif(ENABLE_f77)