/opensource.apple.com/source/ruby/ruby-22/ruby/parse.y
Happy | 3226 lines | 2988 code | 238 blank | 0 comment | 0 complexity | b7bda74b50c4fe8e34f2341f744bd99f MD5 | raw file
Possible License(s): MPL-2.0-no-copyleft-exception, GPL-2.0, BSD-3-Clause, GPL-3.0, MPL-2.0, LGPL-2.0, LGPL-2.1, CC-BY-SA-3.0, IPL-1.0, ISC, AGPL-1.0, AGPL-3.0, JSON, Apache-2.0, 0BSD
- <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN"
- "http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd">
- <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
- <head>
- <title>parse.y</title>
- <style type="text/css">
- .enscript-comment { font-style: italic; color: rgb(178,34,34); }
- .enscript-function-name { font-weight: bold; color: rgb(0,0,255); }
- .enscript-variable-name { font-weight: bold; color: rgb(184,134,11); }
- .enscript-keyword { font-weight: bold; color: rgb(160,32,240); }
- .enscript-reference { font-weight: bold; color: rgb(95,158,160); }
- .enscript-string { font-weight: bold; color: rgb(188,143,143); }
- .enscript-builtin { font-weight: bold; color: rgb(218,112,214); }
- .enscript-type { font-weight: bold; color: rgb(34,139,34); }
- .enscript-highlight { text-decoration: underline; color: 0; }
- </style>
- </head>
- <body id="top">
- <h1 style="margin:8px;" id="f1">parse.y <span style="font-weight: normal; font-size: 0.5em;">[<a href="?txt">plain text</a>]</span></h1>
- <hr/>
- <div></div>
- <pre>
- /**********************************************************************
- parse.y -
- $Author: matz $
- $Date: 2004/11/29 06:13:51 $
- created at: Fri May 28 18:02:42 JST 1993
- Copyright (C) 1993-2003 Yukihiro Matsumoto
- **********************************************************************/
- %{
- #define YYDEBUG 1
- #include "ruby.h"
- #include "env.h"
- #include "intern.h"
- #include "node.h"
- #include "st.h"
- #include <stdio.h>
- #include <errno.h>
- #include <ctype.h>
- #define yyparse ruby_yyparse
- #define yylex ruby_yylex
- #define yyerror ruby_yyerror
- #define yylval ruby_yylval
- #define yychar ruby_yychar
- #define yydebug ruby_yydebug
- #define ID_SCOPE_SHIFT 3
- #define ID_SCOPE_MASK 0x07
- #define ID_LOCAL 0x01
- #define ID_INSTANCE 0x02
- #define ID_GLOBAL 0x03
- #define ID_ATTRSET 0x04
- #define ID_CONST 0x05
- #define ID_CLASS 0x06
- #define ID_JUNK 0x07
- #define ID_INTERNAL ID_JUNK
- #define is_notop_id(id) ((id)>tLAST_TOKEN)
- #define is_local_id(id) (is_notop_id(id)&&((id)&ID_SCOPE_MASK)==ID_LOCAL)
- #define is_global_id(id) (is_notop_id(id)&&((id)&ID_SCOPE_MASK)==ID_GLOBAL)
- #define is_instance_id(id) (is_notop_id(id)&&((id)&ID_SCOPE_MASK)==ID_INSTANCE)
- #define is_attrset_id(id) (is_notop_id(id)&&((id)&ID_SCOPE_MASK)==ID_ATTRSET)
- #define is_const_id(id) (is_notop_id(id)&&((id)&ID_SCOPE_MASK)==ID_CONST)
- #define is_class_id(id) (is_notop_id(id)&&((id)&ID_SCOPE_MASK)==ID_CLASS)
- #define is_junk_id(id) (is_notop_id(id)&&((id)&ID_SCOPE_MASK)==ID_JUNK)
- #define is_asgn_or_id(id) ((is_notop_id(id)) && \
- (((id)&ID_SCOPE_MASK) == ID_GLOBAL || \
- ((id)&ID_SCOPE_MASK) == ID_INSTANCE || \
- ((id)&ID_SCOPE_MASK) == ID_CLASS))
- NODE *ruby_eval_tree_begin = 0;
- NODE *ruby_eval_tree = 0;
- char *ruby_sourcefile; /* current source file */
- int ruby_sourceline; /* current line no. */
- static int yylex();
- static int yyerror();
- static enum lex_state {
- EXPR_BEG, /* ignore newline, +/- is a sign. */
- EXPR_END, /* newline significant, +/- is a operator. */
- EXPR_ARG, /* newline significant, +/- is a operator. */
- EXPR_CMDARG, /* newline significant, +/- is a operator. */
- EXPR_ENDARG, /* newline significant, +/- is a operator. */
- EXPR_MID, /* newline significant, +/- is a operator. */
- EXPR_FNAME, /* ignore newline, no reserved words. */
- EXPR_DOT, /* right after `.' or `::', no reserved words. */
- EXPR_CLASS, /* immediate after `class', no here document. */
- } lex_state;
- static NODE *lex_strterm;
- #ifdef HAVE_LONG_LONG
- typedef unsigned LONG_LONG stack_type;
- #else
- typedef unsigned long stack_type;
- #endif
- #define BITSTACK_PUSH(stack, n) (stack = (stack<<1)|((n)&1))
- #define BITSTACK_POP(stack) (stack >>= 1)
- #define BITSTACK_LEXPOP(stack) (stack = (stack >> 1) | (stack & 1))
- #define BITSTACK_SET_P(stack) (stack&1)
- static stack_type cond_stack = 0;
- #define COND_PUSH(n) BITSTACK_PUSH(cond_stack, n)
- #define COND_POP() BITSTACK_POP(cond_stack)
- #define COND_LEXPOP() BITSTACK_LEXPOP(cond_stack)
- #define COND_P() BITSTACK_SET_P(cond_stack)
- static stack_type cmdarg_stack = 0;
- #define CMDARG_PUSH(n) BITSTACK_PUSH(cmdarg_stack, n)
- #define CMDARG_POP() BITSTACK_POP(cmdarg_stack)
- #define CMDARG_LEXPOP() BITSTACK_LEXPOP(cmdarg_stack)
- #define CMDARG_P() BITSTACK_SET_P(cmdarg_stack)
- static int class_nest = 0;
- static int in_single = 0;
- static int in_def = 0;
- static int compile_for_eval = 0;
- static ID cur_mid = 0;
- static NODE *cond();
- static NODE *logop();
- static int cond_negative();
- static NODE *newline_node();
- static void fixpos();
- static int value_expr0();
- static void void_expr0();
- static void void_stmts();
- static NODE *remove_begin();
- #define value_expr(node) value_expr0((node) = remove_begin(node))
- #define void_expr(node) void_expr0((node) = remove_begin(node))
- static NODE *block_append();
- static NODE *list_append();
- static NODE *list_concat();
- static NODE *arg_concat();
- static NODE *arg_prepend();
- static NODE *literal_concat();
- static NODE *new_evstr();
- static NODE *evstr2dstr();
- static NODE *call_op();
- static int in_defined = 0;
- static NODE *negate_lit();
- static NODE *ret_args();
- static NODE *arg_blk_pass();
- static NODE *new_call();
- static NODE *new_fcall();
- static NODE *new_super();
- static NODE *new_yield();
- static NODE *gettable();
- static NODE *assignable();
- static NODE *aryset();
- static NODE *attrset();
- static void rb_backref_error();
- static NODE *node_assign();
- static NODE *match_gen();
- static void local_push();
- static void local_pop();
- static int local_append();
- static int local_cnt();
- static int local_id();
- static ID *local_tbl();
- static ID internal_id();
- static struct RVarmap *dyna_push();
- static void dyna_pop();
- static int dyna_in_block();
- static NODE *dyna_init();
- static void top_local_init();
- static void top_local_setup();
- #define RE_OPTION_ONCE 0x80
- #define NODE_STRTERM NODE_ZARRAY /* nothing to gc */
- #define NODE_HEREDOC NODE_ARRAY /* 1, 3 to gc */
- #define SIGN_EXTEND(x,n) (((1<<(n)-1)^((x)&~(~0<<(n))))-(1<<(n)-1))
- #define nd_func u1.id
- #if SIZEOF_SHORT == 2
- #define nd_term(node) ((signed short)(node)->u2.id)
- #else
- #define nd_term(node) SIGN_EXTEND((node)->u2.id, CHAR_BIT*2)
- #endif
- #define nd_paren(node) (char)((node)->u2.id >> CHAR_BIT*2)
- #define nd_nest u3.id
- /* Older versions of Yacc set YYMAXDEPTH to a very low value by default (150,
- for instance). This is too low for Ruby to parse some files, such as
- date/format.rb, therefore bump the value up to at least Bison's default. */
- #ifdef OLD_YACC
- #ifndef YYMAXDEPTH
- #define YYMAXDEPTH 10000
- #endif
- #endif
- %}
- %union {
- NODE *node;
- ID id;
- int num;
- struct RVarmap *vars;
- }
- %token kCLASS
- kMODULE
- kDEF
- kUNDEF
- kBEGIN
- kRESCUE
- kENSURE
- kEND
- kIF
- kUNLESS
- kTHEN
- kELSIF
- kELSE
- kCASE
- kWHEN
- kWHILE
- kUNTIL
- kFOR
- kBREAK
- kNEXT
- kREDO
- kRETRY
- kIN
- kDO
- kDO_COND
- kDO_BLOCK
- kRETURN
- kYIELD
- kSUPER
- kSELF
- kNIL
- kTRUE
- kFALSE
- kAND
- kOR
- kNOT
- kIF_MOD
- kUNLESS_MOD
- kWHILE_MOD
- kUNTIL_MOD
- kRESCUE_MOD
- kALIAS
- kDEFINED
- klBEGIN
- klEND
- k__LINE__
- k__FILE__
- %token <id> tIDENTIFIER tFID tGVAR tIVAR tCONSTANT tCVAR
- %token <node> tINTEGER tFLOAT tSTRING_CONTENT
- %token <node> tNTH_REF tBACK_REF
- %token <num> tREGEXP_END
- %type <node> singleton strings string string1 xstring regexp
- %type <node> string_contents xstring_contents string_content
- %type <node> words qwords word_list qword_list word
- %type <node> literal numeric dsym cpath
- %type <node> bodystmt compstmt stmts stmt expr arg primary command command_call method_call
- %type <node> expr_value arg_value primary_value
- %type <node> if_tail opt_else case_body cases opt_rescue exc_list exc_var opt_ensure
- %type <node> args when_args call_args call_args2 open_args paren_args opt_paren_args
- %type <node> command_args aref_args opt_block_arg block_arg var_ref var_lhs
- %type <node> mrhs superclass block_call block_command
- %type <node> f_arglist f_args f_optarg f_opt f_block_arg opt_f_block_arg
- %type <node> assoc_list assocs assoc undef_list backref string_dvar
- %type <node> block_var opt_block_var brace_block cmd_brace_block do_block lhs none
- %type <node> mlhs mlhs_head mlhs_basic mlhs_entry mlhs_item mlhs_node
- %type <id> fitem variable sym symbol operation operation2 operation3
- %type <id> cname fname op f_rest_arg
- %type <num> f_norm_arg f_arg
- %token tUPLUS /* unary+ */
- %token tUMINUS /* unary- */
- %token tPOW /* ** */
- %token tCMP /* <=> */
- %token tEQ /* == */
- %token tEQQ /* === */
- %token tNEQ /* != */
- %token tGEQ /* >= */
- %token tLEQ /* <= */
- %token tANDOP tOROP /* && and || */
- %token tMATCH tNMATCH /* =~ and !~ */
- %token tDOT2 tDOT3 /* .. and ... */
- %token tAREF tASET /* [] and []= */
- %token tLSHFT tRSHFT /* << and >> */
- %token tCOLON2 /* :: */
- %token tCOLON3 /* :: at EXPR_BEG */
- %token <id> tOP_ASGN /* +=, -= etc. */
- %token tASSOC /* => */
- %token tLPAREN /* ( */
- %token tLPAREN_ARG /* ( */
- %token tRPAREN /* ) */
- %token tLBRACK /* [ */
- %token tLBRACE /* { */
- %token tLBRACE_ARG /* { */
- %token tSTAR /* * */
- %token tAMPER /* & */
- %token tSYMBEG tSTRING_BEG tXSTRING_BEG tREGEXP_BEG tWORDS_BEG tQWORDS_BEG
- %token tSTRING_DBEG tSTRING_DVAR tSTRING_END
- /*
- * precedence table
- */
- %nonassoc tLOWEST
- %nonassoc tLBRACE_ARG
- %nonassoc kIF_MOD kUNLESS_MOD kWHILE_MOD kUNTIL_MOD
- %left kOR kAND
- %right kNOT
- %nonassoc kDEFINED
- %right '=' tOP_ASGN
- %left kRESCUE_MOD
- %right '?' ':'
- %nonassoc tDOT2 tDOT3
- %left tOROP
- %left tANDOP
- %nonassoc tCMP tEQ tEQQ tNEQ tMATCH tNMATCH
- %left '>' tGEQ '<' tLEQ
- %left '|' '^'
- %left '&'
- %left tLSHFT tRSHFT
- %left '+' '-'
- %left '*' '/' '%'
- %right tUMINUS_NUM tUMINUS
- %right tPOW
- %right '!' '~' tUPLUS
- %token tLAST_TOKEN
- %%
- program : {
- lex_state = EXPR_BEG;
- top_local_init();
- if (ruby_class == rb_cObject) class_nest = 0;
- else class_nest = 1;
- }
- compstmt
- {
- if ($2 && !compile_for_eval) {
- /* last expression should not be void */
- if (nd_type($2) != NODE_BLOCK) void_expr($2);
- else {
- NODE *node = $2;
- while (node->nd_next) {
- node = node->nd_next;
- }
- void_expr(node->nd_head);
- }
- }
- ruby_eval_tree = block_append(ruby_eval_tree, $2);
- top_local_setup();
- class_nest = 0;
- }
- ;
- bodystmt : compstmt
- opt_rescue
- opt_else
- opt_ensure
- {
- $$ = $1;
- if ($2) {
- $$ = NEW_RESCUE($1, $2, $3);
- }
- else if ($3) {
- rb_warn("else without rescue is useless");
- $$ = block_append($$, $3);
- }
- if ($4) {
- $$ = NEW_ENSURE($$, $4);
- }
- fixpos($$, $1);
- }
- ;
- compstmt : stmts opt_terms
- {
- void_stmts($1);
- $$ = $1;
- }
- ;
- stmts : none
- | stmt
- {
- $$ = newline_node($1);
- }
- | stmts terms stmt
- {
- $$ = block_append($1, newline_node($3));
- }
- | error stmt
- {
- $$ = $2;
- }
- ;
- stmt : kALIAS fitem {lex_state = EXPR_FNAME;} fitem
- {
- $$ = NEW_ALIAS($2, $4);
- }
- | kALIAS tGVAR tGVAR
- {
- $$ = NEW_VALIAS($2, $3);
- }
- | kALIAS tGVAR tBACK_REF
- {
- char buf[3];
- sprintf(buf, "$%c", (char)$3->nd_nth);
- $$ = NEW_VALIAS($2, rb_intern(buf));
- }
- | kALIAS tGVAR tNTH_REF
- {
- yyerror("can't make alias for the number variables");
- $$ = 0;
- }
- | kUNDEF undef_list
- {
- $$ = $2;
- }
- | stmt kIF_MOD expr_value
- {
- $$ = NEW_IF(cond($3), $1, 0);
- fixpos($$, $3);
- if (cond_negative(&$$->nd_cond)) {
- $$->nd_else = $$->nd_body;
- $$->nd_body = 0;
- }
- }
- | stmt kUNLESS_MOD expr_value
- {
- $$ = NEW_UNLESS(cond($3), $1, 0);
- fixpos($$, $3);
- if (cond_negative(&$$->nd_cond)) {
- $$->nd_body = $$->nd_else;
- $$->nd_else = 0;
- }
- }
- | stmt kWHILE_MOD expr_value
- {
- if ($1 && nd_type($1) == NODE_BEGIN) {
- $$ = NEW_WHILE(cond($3), $1->nd_body, 0);
- }
- else {
- $$ = NEW_WHILE(cond($3), $1, 1);
- }
- if (cond_negative(&$$->nd_cond)) {
- nd_set_type($$, NODE_UNTIL);
- }
- }
- | stmt kUNTIL_MOD expr_value
- {
- if ($1 && nd_type($1) == NODE_BEGIN) {
- $$ = NEW_UNTIL(cond($3), $1->nd_body, 0);
- }
- else {
- $$ = NEW_UNTIL(cond($3), $1, 1);
- }
- if (cond_negative(&$$->nd_cond)) {
- nd_set_type($$, NODE_WHILE);
- }
- }
- | stmt kRESCUE_MOD stmt
- {
- $$ = NEW_RESCUE($1, NEW_RESBODY(0,$3,0), 0);
- }
- | klBEGIN
- {
- if (in_def || in_single) {
- yyerror("BEGIN in method");
- }
- local_push(0);
- }
- '{' compstmt '}'
- {
- ruby_eval_tree_begin = block_append(ruby_eval_tree_begin,
- NEW_PREEXE($4));
- local_pop();
- $$ = 0;
- }
- | klEND '{' compstmt '}'
- {
- if (in_def || in_single) {
- rb_warn("END in method; use at_exit");
- }
- $$ = NEW_ITER(0, NEW_POSTEXE(), $3);
- }
- | lhs '=' command_call
- {
- $$ = node_assign($1, $3);
- }
- | mlhs '=' command_call
- {
- value_expr($3);
- $1->nd_value = ($1->nd_head) ? NEW_TO_ARY($3) : NEW_ARRAY($3);
- $$ = $1;
- }
- | var_lhs tOP_ASGN command_call
- {
- value_expr($3);
- if ($1) {
- ID vid = $1->nd_vid;
- if ($2 == tOROP) {
- $1->nd_value = $3;
- $$ = NEW_OP_ASGN_OR(gettable(vid), $1);
- if (is_asgn_or_id(vid)) {
- $$->nd_aid = vid;
- }
- }
- else if ($2 == tANDOP) {
- $1->nd_value = $3;
- $$ = NEW_OP_ASGN_AND(gettable(vid), $1);
- }
- else {
- $$ = $1;
- $$->nd_value = call_op(gettable(vid),$2,1,$3);
- }
- }
- else {
- $$ = 0;
- }
- }
- | primary_value '[' aref_args ']' tOP_ASGN command_call
- {
- NODE *args;
- value_expr($6);
- args = NEW_LIST($6);
- if ($3 && nd_type($3) != NODE_ARRAY)
- $3 = NEW_LIST($3);
- $3 = list_append($3, NEW_NIL());
- list_concat(args, $3);
- if ($5 == tOROP) {
- $5 = 0;
- }
- else if ($5 == tANDOP) {
- $5 = 1;
- }
- $$ = NEW_OP_ASGN1($1, $5, args);
- fixpos($$, $1);
- }
- | primary_value '.' tIDENTIFIER tOP_ASGN command_call
- {
- value_expr($5);
- if ($4 == tOROP) {
- $4 = 0;
- }
- else if ($4 == tANDOP) {
- $4 = 1;
- }
- $$ = NEW_OP_ASGN2($1, $3, $4, $5);
- fixpos($$, $1);
- }
- | primary_value '.' tCONSTANT tOP_ASGN command_call
- {
- value_expr($5);
- if ($4 == tOROP) {
- $4 = 0;
- }
- else if ($4 == tANDOP) {
- $4 = 1;
- }
- $$ = NEW_OP_ASGN2($1, $3, $4, $5);
- fixpos($$, $1);
- }
- | primary_value tCOLON2 tIDENTIFIER tOP_ASGN command_call
- {
- value_expr($5);
- if ($4 == tOROP) {
- $4 = 0;
- }
- else if ($4 == tANDOP) {
- $4 = 1;
- }
- $$ = NEW_OP_ASGN2($1, $3, $4, $5);
- fixpos($$, $1);
- }
- | backref tOP_ASGN command_call
- {
- rb_backref_error($1);
- $$ = 0;
- }
- | lhs '=' mrhs
- {
- $$ = node_assign($1, NEW_SVALUE($3));
- }
- | mlhs '=' arg_value
- {
- $1->nd_value = ($1->nd_head) ? NEW_TO_ARY($3) : NEW_ARRAY($3);
- $$ = $1;
- }
- | mlhs '=' mrhs
- {
- $1->nd_value = $3;
- $$ = $1;
- }
- | expr
- ;
- expr : command_call
- | expr kAND expr
- {
- $$ = logop(NODE_AND, $1, $3);
- }
- | expr kOR expr
- {
- $$ = logop(NODE_OR, $1, $3);
- }
- | kNOT expr
- {
- $$ = NEW_NOT(cond($2));
- }
- | '!' command_call
- {
- $$ = NEW_NOT(cond($2));
- }
- | arg
- ;
- expr_value : expr
- {
- value_expr($$);
- $$ = $1;
- }
- ;
- command_call : command
- | block_command
- | kRETURN call_args
- {
- $$ = NEW_RETURN(ret_args($2));
- }
- | kBREAK call_args
- {
- $$ = NEW_BREAK(ret_args($2));
- }
- | kNEXT call_args
- {
- $$ = NEW_NEXT(ret_args($2));
- }
- ;
- block_command : block_call
- | block_call '.' operation2 command_args
- {
- $$ = new_call($1, $3, $4);
- }
- | block_call tCOLON2 operation2 command_args
- {
- $$ = new_call($1, $3, $4);
- }
- ;
- cmd_brace_block : tLBRACE_ARG
- {
- $<vars>$ = dyna_push();
- $<num>1 = ruby_sourceline;
- }
- opt_block_var {$<vars>$ = ruby_dyna_vars;}
- compstmt
- '}'
- {
- $$ = NEW_ITER($3, 0, dyna_init($5, $<vars>4));
- nd_set_line($$, $<num>1);
- dyna_pop($<vars>2);
- }
- ;
- command : operation command_args %prec tLOWEST
- {
- $$ = new_fcall($1, $2);
- fixpos($$, $2);
- }
- | operation command_args cmd_brace_block
- {
- $$ = new_fcall($1, $2);
- if ($3) {
- if (nd_type($$) == NODE_BLOCK_PASS) {
- rb_compile_error("both block arg and actual block given");
- }
- $3->nd_iter = $$;
- $$ = $3;
- }
- fixpos($$, $2);
- }
- | primary_value '.' operation2 command_args %prec tLOWEST
- {
- $$ = new_call($1, $3, $4);
- fixpos($$, $1);
- }
- | primary_value '.' operation2 command_args cmd_brace_block
- {
- $$ = new_call($1, $3, $4);
- if ($5) {
- if (nd_type($$) == NODE_BLOCK_PASS) {
- rb_compile_error("both block arg and actual block given");
- }
- $5->nd_iter = $$;
- $$ = $5;
- }
- fixpos($$, $1);
- }
- | primary_value tCOLON2 operation2 command_args %prec tLOWEST
- {
- $$ = new_call($1, $3, $4);
- fixpos($$, $1);
- }
- | primary_value tCOLON2 operation2 command_args cmd_brace_block
- {
- $$ = new_call($1, $3, $4);
- if ($5) {
- if (nd_type($$) == NODE_BLOCK_PASS) {
- rb_compile_error("both block arg and actual block given");
- }
- $5->nd_iter = $$;
- $$ = $5;
- }
- fixpos($$, $1);
- }
- | kSUPER command_args
- {
- $$ = new_super($2);
- fixpos($$, $2);
- }
- | kYIELD command_args
- {
- $$ = new_yield($2);
- fixpos($$, $2);
- }
- ;
- mlhs : mlhs_basic
- | tLPAREN mlhs_entry ')'
- {
- $$ = $2;
- }
- ;
- mlhs_entry : mlhs_basic
- | tLPAREN mlhs_entry ')'
- {
- $$ = NEW_MASGN(NEW_LIST($2), 0);
- }
- ;
- mlhs_basic : mlhs_head
- {
- $$ = NEW_MASGN($1, 0);
- }
- | mlhs_head mlhs_item
- {
- $$ = NEW_MASGN(list_append($1,$2), 0);
- }
- | mlhs_head tSTAR mlhs_node
- {
- $$ = NEW_MASGN($1, $3);
- }
- | mlhs_head tSTAR
- {
- $$ = NEW_MASGN($1, -1);
- }
- | tSTAR mlhs_node
- {
- $$ = NEW_MASGN(0, $2);
- }
- | tSTAR
- {
- $$ = NEW_MASGN(0, -1);
- }
- ;
- mlhs_item : mlhs_node
- | tLPAREN mlhs_entry ')'
- {
- $$ = $2;
- }
- ;
- mlhs_head : mlhs_item ','
- {
- $$ = NEW_LIST($1);
- }
- | mlhs_head mlhs_item ','
- {
- $$ = list_append($1, $2);
- }
- ;
- mlhs_node : variable
- {
- $$ = assignable($1, 0);
- }
- | primary_value '[' aref_args ']'
- {
- $$ = aryset($1, $3);
- }
- | primary_value '.' tIDENTIFIER
- {
- $$ = attrset($1, $3);
- }
- | primary_value tCOLON2 tIDENTIFIER
- {
- $$ = attrset($1, $3);
- }
- | primary_value '.' tCONSTANT
- {
- $$ = attrset($1, $3);
- }
- | primary_value tCOLON2 tCONSTANT
- {
- if (in_def || in_single)
- yyerror("dynamic constant assignment");
- $$ = NEW_CDECL(0, 0, NEW_COLON2($1, $3));
- }
- | tCOLON3 tCONSTANT
- {
- if (in_def || in_single)
- yyerror("dynamic constant assignment");
- $$ = NEW_CDECL(0, 0, NEW_COLON3($2));
- }
- | backref
- {
- rb_backref_error($1);
- $$ = 0;
- }
- ;
- lhs : variable
- {
- $$ = assignable($1, 0);
- }
- | primary_value '[' aref_args ']'
- {
- $$ = aryset($1, $3);
- }
- | primary_value '.' tIDENTIFIER
- {
- $$ = attrset($1, $3);
- }
- | primary_value tCOLON2 tIDENTIFIER
- {
- $$ = attrset($1, $3);
- }
- | primary_value '.' tCONSTANT
- {
- $$ = attrset($1, $3);
- }
- | primary_value tCOLON2 tCONSTANT
- {
- if (in_def || in_single)
- yyerror("dynamic constant assignment");
- $$ = NEW_CDECL(0, 0, NEW_COLON2($1, $3));
- }
- | tCOLON3 tCONSTANT
- {
- if (in_def || in_single)
- yyerror("dynamic constant assignment");
- $$ = NEW_CDECL(0, 0, NEW_COLON3($2));
- }
- | backref
- {
- rb_backref_error($1);
- $$ = 0;
- }
- ;
- cname : tIDENTIFIER
- {
- yyerror("class/module name must be CONSTANT");
- }
- | tCONSTANT
- ;
- cpath : tCOLON3 cname
- {
- $$ = NEW_COLON3($2);
- }
- | cname
- {
- $$ = NEW_COLON2(0, $$);
- }
- | primary_value tCOLON2 cname
- {
- $$ = NEW_COLON2($1, $3);
- }
- ;
- fname : tIDENTIFIER
- | tCONSTANT
- | tFID
- | op
- {
- lex_state = EXPR_END;
- $$ = $1;
- }
- | reswords
- {
- lex_state = EXPR_END;
- $$ = $<id>1;
- }
- ;
- fitem : fname
- | symbol
- ;
- undef_list : fitem
- {
- $$ = NEW_UNDEF($1);
- }
- | undef_list ',' {lex_state = EXPR_FNAME;} fitem
- {
- $$ = block_append($1, NEW_UNDEF($4));
- }
- ;
- op : '|' { $$ = '|'; }
- | '^' { $$ = '^'; }
- | '&' { $$ = '&'; }
- | tCMP { $$ = tCMP; }
- | tEQ { $$ = tEQ; }
- | tEQQ { $$ = tEQQ; }
- | tMATCH { $$ = tMATCH; }
- | '>' { $$ = '>'; }
- | tGEQ { $$ = tGEQ; }
- | '<' { $$ = '<'; }
- | tLEQ { $$ = tLEQ; }
- | tLSHFT { $$ = tLSHFT; }
- | tRSHFT { $$ = tRSHFT; }
- | '+' { $$ = '+'; }
- | '-' { $$ = '-'; }
- | '*' { $$ = '*'; }
- | tSTAR { $$ = '*'; }
- | '/' { $$ = '/'; }
- | '%' { $$ = '%'; }
- | tPOW { $$ = tPOW; }
- | '~' { $$ = '~'; }
- | tUPLUS { $$ = tUPLUS; }
- | tUMINUS { $$ = tUMINUS; }
- | tAREF { $$ = tAREF; }
- | tASET { $$ = tASET; }
- | '`' { $$ = '`'; }
- ;
- reswords : k__LINE__ | k__FILE__ | klBEGIN | klEND
- | kALIAS | kAND | kBEGIN | kBREAK | kCASE | kCLASS | kDEF
- | kDEFINED | kDO | kELSE | kELSIF | kEND | kENSURE | kFALSE
- | kFOR | kIN | kMODULE | kNEXT | kNIL | kNOT
- | kOR | kREDO | kRESCUE | kRETRY | kRETURN | kSELF | kSUPER
- | kTHEN | kTRUE | kUNDEF | kWHEN | kYIELD
- | kIF_MOD | kUNLESS_MOD | kWHILE_MOD | kUNTIL_MOD | kRESCUE_MOD
- ;
- arg : lhs '=' arg
- {
- $$ = node_assign($1, $3);
- }
- | lhs '=' arg kRESCUE_MOD arg
- {
- $$ = node_assign($1, NEW_RESCUE($3, NEW_RESBODY(0,$5,0), 0));
- }
- | var_lhs tOP_ASGN arg
- {
- value_expr($3);
- if ($1) {
- ID vid = $1->nd_vid;
- if ($2 == tOROP) {
- $1->nd_value = $3;
- $$ = NEW_OP_ASGN_OR(gettable(vid), $1);
- if (is_asgn_or_id(vid)) {
- $$->nd_aid = vid;
- }
- }
- else if ($2 == tANDOP) {
- $1->nd_value = $3;
- $$ = NEW_OP_ASGN_AND(gettable(vid), $1);
- }
- else {
- $$ = $1;
- $$->nd_value = call_op(gettable(vid),$2,1,$3);
- }
- }
- else {
- $$ = 0;
- }
- }
- | primary_value '[' aref_args ']' tOP_ASGN arg
- {
- NODE *args;
- value_expr($6);
- args = NEW_LIST($6);
- if ($3 && nd_type($3) != NODE_ARRAY)
- $3 = NEW_LIST($3);
- $3 = list_append($3, NEW_NIL());
- list_concat(args, $3);
- if ($5 == tOROP) {
- $5 = 0;
- }
- else if ($5 == tANDOP) {
- $5 = 1;
- }
- $$ = NEW_OP_ASGN1($1, $5, args);
- fixpos($$, $1);
- }
- | primary_value '.' tIDENTIFIER tOP_ASGN arg
- {
- value_expr($5);
- if ($4 == tOROP) {
- $4 = 0;
- }
- else if ($4 == tANDOP) {
- $4 = 1;
- }
- $$ = NEW_OP_ASGN2($1, $3, $4, $5);
- fixpos($$, $1);
- }
- | primary_value '.' tCONSTANT tOP_ASGN arg
- {
- value_expr($5);
- if ($4 == tOROP) {
- $4 = 0;
- }
- else if ($4 == tANDOP) {
- $4 = 1;
- }
- $$ = NEW_OP_ASGN2($1, $3, $4, $5);
- fixpos($$, $1);
- }
- | primary_value tCOLON2 tIDENTIFIER tOP_ASGN arg
- {
- value_expr($5);
- if ($4 == tOROP) {
- $4 = 0;
- }
- else if ($4 == tANDOP) {
- $4 = 1;
- }
- $$ = NEW_OP_ASGN2($1, $3, $4, $5);
- fixpos($$, $1);
- }
- | primary_value tCOLON2 tCONSTANT tOP_ASGN arg
- {
- yyerror("constant re-assignment");
- $$ = 0;
- }
- | tCOLON3 tCONSTANT tOP_ASGN arg
- {
- yyerror("constant re-assignment");
- $$ = 0;
- }
- | backref tOP_ASGN arg
- {
- rb_backref_error($1);
- $$ = 0;
- }
- | arg tDOT2 arg
- {
- value_expr($1);
- value_expr($3);
- $$ = NEW_DOT2($1, $3);
- }
- | arg tDOT3 arg
- {
- value_expr($1);
- value_expr($3);
- $$ = NEW_DOT3($1, $3);
- }
- | arg '+' arg
- {
- $$ = call_op($1, '+', 1, $3);
- }
- | arg '-' arg
- {
- $$ = call_op($1, '-', 1, $3);
- }
- | arg '*' arg
- {
- $$ = call_op($1, '*', 1, $3);
- }
- | arg '/' arg
- {
- $$ = call_op($1, '/', 1, $3);
- }
- | arg '%' arg
- {
- $$ = call_op($1, '%', 1, $3);
- }
- | arg tPOW arg
- {
- $$ = call_op($1, tPOW, 1, $3);
- }
- | tUMINUS_NUM tINTEGER tPOW arg
- {
- $$ = call_op(call_op($2, tPOW, 1, $4), tUMINUS, 0, 0);
- }
- | tUMINUS_NUM tFLOAT tPOW arg
- {
- $$ = call_op(call_op($2, tPOW, 1, $4), tUMINUS, 0, 0);
- }
- | tUPLUS arg
- {
- if ($2 && nd_type($2) == NODE_LIT) {
- $$ = $2;
- }
- else {
- $$ = call_op($2, tUPLUS, 0, 0);
- }
- }
- | tUMINUS arg
- {
- $$ = call_op($2, tUMINUS, 0, 0);
- }
- | arg '|' arg
- {
- $$ = call_op($1, '|', 1, $3);
- }
- | arg '^' arg
- {
- $$ = call_op($1, '^', 1, $3);
- }
- | arg '&' arg
- {
- $$ = call_op($1, '&', 1, $3);
- }
- | arg tCMP arg
- {
- $$ = call_op($1, tCMP, 1, $3);
- }
- | arg '>' arg
- {
- $$ = call_op($1, '>', 1, $3);
- }
- | arg tGEQ arg
- {
- $$ = call_op($1, tGEQ, 1, $3);
- }
- | arg '<' arg
- {
- $$ = call_op($1, '<', 1, $3);
- }
- | arg tLEQ arg
- {
- $$ = call_op($1, tLEQ, 1, $3);
- }
- | arg tEQ arg
- {
- $$ = call_op($1, tEQ, 1, $3);
- }
- | arg tEQQ arg
- {
- $$ = call_op($1, tEQQ, 1, $3);
- }
- | arg tNEQ arg
- {
- $$ = NEW_NOT(call_op($1, tEQ, 1, $3));
- }
- | arg tMATCH arg
- {
- $$ = match_gen($1, $3);
- }
- | arg tNMATCH arg
- {
- $$ = NEW_NOT(match_gen($1, $3));
- }
- | '!' arg
- {
- $$ = NEW_NOT(cond($2));
- }
- | '~' arg
- {
- $$ = call_op($2, '~', 0, 0);
- }
- | arg tLSHFT arg
- {
- $$ = call_op($1, tLSHFT, 1, $3);
- }
- | arg tRSHFT arg
- {
- $$ = call_op($1, tRSHFT, 1, $3);
- }
- | arg tANDOP arg
- {
- $$ = logop(NODE_AND, $1, $3);
- }
- | arg tOROP arg
- {
- $$ = logop(NODE_OR, $1, $3);
- }
- | kDEFINED opt_nl {in_defined = 1;} arg
- {
- in_defined = 0;
- $$ = NEW_DEFINED($4);
- }
- | arg '?' arg ':' arg
- {
- $$ = NEW_IF(cond($1), $3, $5);
- fixpos($$, $1);
- }
- | primary
- {
- $$ = $1;
- }
- ;
- arg_value : arg
- {
- value_expr($1);
- $$ = $1;
- }
- ;
- aref_args : none
- | command opt_nl
- {
- rb_warn("parenthesize argument(s) for future version");
- $$ = NEW_LIST($1);
- }
- | args trailer
- {
- $$ = $1;
- }
- | args ',' tSTAR arg opt_nl
- {
- value_expr($4);
- $$ = arg_concat($1, $4);
- }
- | assocs trailer
- {
- $$ = NEW_LIST(NEW_HASH($1));
- }
- | tSTAR arg opt_nl
- {
- value_expr($2);
- $$ = NEW_NEWLINE(NEW_SPLAT($2));
- }
- ;
- paren_args : '(' none ')'
- {
- $$ = $2;
- }
- | '(' call_args opt_nl ')'
- {
- $$ = $2;
- }
- | '(' block_call opt_nl ')'
- {
- rb_warn("parenthesize argument for future version");
- $$ = NEW_LIST($2);
- }
- | '(' args ',' block_call opt_nl ')'
- {
- rb_warn("parenthesize argument for future version");
- $$ = list_append($2, $4);
- }
- ;
- opt_paren_args : none
- | paren_args
- ;
- call_args : command
- {
- rb_warn("parenthesize argument(s) for future version");
- $$ = NEW_LIST($1);
- }
- | args opt_block_arg
- {
- $$ = arg_blk_pass($1, $2);
- }
- | args ',' tSTAR arg_value opt_block_arg
- {
- $$ = arg_concat($1, $4);
- $$ = arg_blk_pass($$, $5);
- }
- | assocs opt_block_arg
- {
- $$ = NEW_LIST(NEW_HASH($1));
- $$ = arg_blk_pass($$, $2);
- }
- | assocs ',' tSTAR arg_value opt_block_arg
- {
- $$ = arg_concat(NEW_LIST(NEW_HASH($1)), $4);
- $$ = arg_blk_pass($$, $5);
- }
- | args ',' assocs opt_block_arg
- {
- $$ = list_append($1, NEW_HASH($3));
- $$ = arg_blk_pass($$, $4);
- }
- | args ',' assocs ',' tSTAR arg opt_block_arg
- {
- value_expr($6);
- $$ = arg_concat(list_append($1, NEW_HASH($3)), $6);
- $$ = arg_blk_pass($$, $7);
- }
- | tSTAR arg_value opt_block_arg
- {
- $$ = arg_blk_pass(NEW_SPLAT($2), $3);
- }
- | block_arg
- ;
- call_args2 : arg_value ',' args opt_block_arg
- {
- $$ = arg_blk_pass(list_concat(NEW_LIST($1),$3), $4);
- }
- | arg_value ',' block_arg
- {
- $$ = arg_blk_pass($1, $3);
- }
- | arg_value ',' tSTAR arg_value opt_block_arg
- {
- $$ = arg_concat(NEW_LIST($1), $4);
- $$ = arg_blk_pass($$, $5);
- }
- | arg_value ',' args ',' tSTAR arg_value opt_block_arg
- {
- $$ = arg_concat(list_concat(NEW_LIST($1),$3), $6);
- $$ = arg_blk_pass($$, $7);
- }
- | assocs opt_block_arg
- {
- $$ = NEW_LIST(NEW_HASH($1));
- $$ = arg_blk_pass($$, $2);
- }
- | assocs ',' tSTAR arg_value opt_block_arg
- {
- $$ = arg_concat(NEW_LIST(NEW_HASH($1)), $4);
- $$ = arg_blk_pass($$, $5);
- }
- | arg_value ',' assocs opt_block_arg
- {
- $$ = list_append(NEW_LIST($1), NEW_HASH($3));
- $$ = arg_blk_pass($$, $4);
- }
- | arg_value ',' args ',' assocs opt_block_arg
- {
- $$ = list_append(list_concat(NEW_LIST($1),$3), NEW_HASH($5));
- $$ = arg_blk_pass($$, $6);
- }
- | arg_value ',' assocs ',' tSTAR arg_value opt_block_arg
- {
- $$ = arg_concat(list_append(NEW_LIST($1), NEW_HASH($3)), $6);
- $$ = arg_blk_pass($$, $7);
- }
- | arg_value ',' args ',' assocs ',' tSTAR arg_value opt_block_arg
- {
- $$ = arg_concat(list_append(list_concat(NEW_LIST($1), $3), NEW_HASH($5)), $8);
- $$ = arg_blk_pass($$, $9);
- }
- | tSTAR arg_value opt_block_arg
- {
- $$ = arg_blk_pass(NEW_SPLAT($2), $3);
- }
- | block_arg
- ;
- command_args : {
- $<num>$ = cmdarg_stack;
- CMDARG_PUSH(1);
- }
- open_args
- {
- /* CMDARG_POP() */
- cmdarg_stack = $<num>1;
- $$ = $2;
- }
- ;
- open_args : call_args
- | tLPAREN_ARG {lex_state = EXPR_ENDARG;} ')'
- {
- rb_warn("don't put space before argument parentheses");
- $$ = 0;
- }
- | tLPAREN_ARG call_args2 {lex_state = EXPR_ENDARG;} ')'
- {
- rb_warn("don't put space before argument parentheses");
- $$ = $2;
- }
- ;
- block_arg : tAMPER arg_value
- {
- $$ = NEW_BLOCK_PASS($2);
- }
- ;
- opt_block_arg : ',' block_arg
- {
- $$ = $2;
- }
- | none
- ;
- args : arg_value
- {
- $$ = NEW_LIST($1);
- }
- | args ',' arg_value
- {
- $$ = list_append($1, $3);
- }
- ;
- mrhs : args ',' arg_value
- {
- $$ = list_append($1, $3);
- }
- | args ',' tSTAR arg_value
- {
- $$ = arg_concat($1, $4);
- }
- | tSTAR arg_value
- {
- $$ = NEW_SPLAT($2);
- }
- ;
- primary : literal
- | strings
- | xstring
- | regexp
- | words
- | qwords
- | var_ref
- | backref
- | tFID
- {
- $$ = NEW_FCALL($1, 0);
- }
- | kBEGIN
- {
- $<num>1 = ruby_sourceline;
- }
- bodystmt
- kEND
- {
- if ($3 == NULL)
- $$ = NEW_NIL();
- else
- $$ = NEW_BEGIN($3);
- nd_set_line($$, $<num>1);
- }
- | tLPAREN_ARG expr {lex_state = EXPR_ENDARG;} opt_nl ')'
- {
- rb_warning("(...) interpreted as grouped expression");
- $$ = $2;
- }
- | tLPAREN compstmt ')'
- {
- $$ = $2;
- }
- | primary_value tCOLON2 tCONSTANT
- {
- $$ = NEW_COLON2($1, $3);
- }
- | tCOLON3 tCONSTANT
- {
- $$ = NEW_COLON3($2);
- }
- | primary_value '[' aref_args ']'
- {
- if ($1 && nd_type($1) == NODE_SELF)
- $$ = NEW_FCALL(tAREF, $3);
- else
- $$ = NEW_CALL($1, tAREF, $3);
- fixpos($$, $1);
- }
- | tLBRACK aref_args ']'
- {
- if ($2 == 0) {
- $$ = NEW_ZARRAY(); /* zero length array*/
- }
- else {
- $$ = $2;
- }
- }
- | tLBRACE assoc_list '}'
- {
- $$ = NEW_HASH($2);
- }
- | kRETURN
- {
- $$ = NEW_RETURN(0);
- }
- | kYIELD '(' call_args ')'
- {
- $$ = new_yield($3);
- }
- | kYIELD '(' ')'
- {
- $$ = NEW_YIELD(0, Qfalse);
- }
- | kYIELD
- {
- $$ = NEW_YIELD(0, Qfalse);
- }
- | kDEFINED opt_nl '(' {in_defined = 1;} expr ')'
- {
- in_defined = 0;
- $$ = NEW_DEFINED($5);
- }
- | operation brace_block
- {
- $2->nd_iter = NEW_FCALL($1, 0);
- $$ = $2;
- fixpos($2->nd_iter, $2);
- }
- | method_call
- | method_call brace_block
- {
- if ($1 && nd_type($1) == NODE_BLOCK_PASS) {
- rb_compile_error("both block arg and actual block given");
- }
- $2->nd_iter = $1;
- $$ = $2;
- fixpos($$, $1);
- }
- | kIF expr_value then
- compstmt
- if_tail
- kEND
- {
- $$ = NEW_IF(cond($2), $4, $5);
- fixpos($$, $2);
- if (cond_negative(&$$->nd_cond)) {
- NODE *tmp = $$->nd_body;
- $$->nd_body = $$->nd_else;
- $$->nd_else = tmp;
- }
- }
- | kUNLESS expr_value then
- compstmt
- opt_else
- kEND
- {
- $$ = NEW_UNLESS(cond($2), $4, $5);
- fixpos($$, $2);
- if (cond_negative(&$$->nd_cond)) {
- NODE *tmp = $$->nd_body;
- $$->nd_body = $$->nd_else;
- $$->nd_else = tmp;
- }
- }
- | kWHILE {COND_PUSH(1);} expr_value do {COND_POP();}
- compstmt
- kEND
- {
- $$ = NEW_WHILE(cond($3), $6, 1);
- fixpos($$, $3);
- if (cond_negative(&$$->nd_cond)) {
- nd_set_type($$, NODE_UNTIL);
- }
- }
- | kUNTIL {COND_PUSH(1);} expr_value do {COND_POP();}
- compstmt
- kEND
- {
- $$ = NEW_UNTIL(cond($3), $6, 1);
- fixpos($$, $3);
- if (cond_negative(&$$->nd_cond)) {
- nd_set_type($$, NODE_WHILE);
- }
- }
- | kCASE expr_value opt_terms
- case_body
- kEND
- {
- $$ = NEW_CASE($2, $4);
- fixpos($$, $2);
- }
- | kCASE opt_terms case_body kEND
- {
- $$ = $3;
- }
- | kCASE opt_terms kELSE compstmt kEND
- {
- $$ = $4;
- }
- | kFOR block_var kIN {COND_PUSH(1);} expr_value do {COND_POP();}
- compstmt
- kEND
- {
- $$ = NEW_FOR($2, $5, $8);
- fixpos($$, $2);
- }
- | kCLASS cpath superclass
- {
- if (in_def || in_single)
- yyerror("class definition in method body");
- class_nest++;
- local_push(0);
- $<num>$ = ruby_sourceline;
- }
- bodystmt
- kEND
- {
- $$ = NEW_CLASS($2, $5, $3);
- nd_set_line($$, $<num>4);
- local_pop();
- class_nest--;
- }
- | kCLASS tLSHFT expr
- {
- $<num>$ = in_def;
- in_def = 0;
- }
- term
- {
- $<num>$ = in_single;
- in_single = 0;
- class_nest++;
- local_push(0);
- }
- bodystmt
- kEND
- {
- $$ = NEW_SCLASS($3, $7);
- fixpos($$, $3);
- local_pop();
- class_nest--;
- in_def = $<num>4;
- in_single = $<num>6;
- }
- | kMODULE cpath
- {
- if (in_def || in_single)
- yyerror("module definition in method body");
- class_nest++;
- local_push(0);
- $<num>$ = ruby_sourceline;
- }
- bodystmt
- kEND
- {
- $$ = NEW_MODULE($2, $4);
- nd_set_line($$, $<num>3);
- local_pop();
- class_nest--;
- }
- | kDEF fname
- {
- $<id>$ = cur_mid;
- cur_mid = $2;
- in_def++;
- local_push(0);
- }
- f_arglist
- bodystmt
- kEND
- {
- if (!$5) $5 = NEW_NIL();
- $$ = NEW_DEFN($2, $4, $5, NOEX_PRIVATE);
- fixpos($$, $4);
- local_pop();
- in_def--;
- cur_mid = $<id>3;
- }
- | kDEF singleton dot_or_colon {lex_state = EXPR_FNAME;} fname
- {
- in_single++;
- local_push(0);
- lex_state = EXPR_END; /* force for args */
- }
- f_arglist
- bodystmt
- kEND
- {
- $$ = NEW_DEFS($2, $5, $7, $8);
- fixpos($$, $2);
- local_pop();
- in_single--;
- }
- | kBREAK
- {
- $$ = NEW_BREAK(0);
- }
- | kNEXT
- {
- $$ = NEW_NEXT(0);
- }
- | kREDO
- {
- $$ = NEW_REDO();
- }
- | kRETRY
- {
- $$ = NEW_RETRY();
- }
- ;
- primary_value : primary
- {
- value_expr($1);
- $$ = $1;
- }
- ;
- then : term
- | ':'
- | kTHEN
- | term kTHEN
- ;
- do : term
- | ':'
- | kDO_COND
- ;
- if_tail : opt_else
- | kELSIF expr_value then
- compstmt
- if_tail
- {
- $$ = NEW_IF(cond($2), $4, $5);
- fixpos($$, $2);
- }
- ;
- opt_else : none
- | kELSE compstmt
- {
- $$ = $2;
- }
- ;
- block_var : lhs
- | mlhs
- ;
- opt_block_var : none
- | '|' /* none */ '|'
- {
- $$ = (NODE*)1;
- }
- | tOROP
- {
- $$ = (NODE*)1;
- }
- | '|' block_var '|'
- {
- $$ = $2;
- }
- ;
- do_block : kDO_BLOCK
- {
- $<vars>$ = dyna_push();
- $<num>1 = ruby_sourceline;
- }
- opt_block_var {$<vars>$ = ruby_dyna_vars;}
- compstmt
- kEND
- {
- $$ = NEW_ITER($3, 0, dyna_init($5, $<vars>4));
- nd_set_line($$, $<num>1);
- dyna_pop($<vars>2);
- }
- ;
- block_call : command do_block
- {
- if ($1 && nd_type($1) == NODE_BLOCK_PASS) {
- rb_compile_error("both block arg and actual block given");
- }
- $2->nd_iter = $1;
- $$ = $2;
- fixpos($$, $1);
- }
- | block_call '.' operation2 opt_paren_args
- {
- $$ = new_call($1, $3, $4);
- }
- | block_call tCOLON2 operation2 opt_paren_args
- {
- $$ = new_call($1, $3, $4);
- }
- ;
- method_call : operation paren_args
- {
- $$ = new_fcall($1, $2);
- fixpos($$, $2);
- }
- | primary_value '.' operation2 opt_paren_args
- {
- $$ = new_call($1, $3, $4);
- fixpos($$, $1);
- }
- | primary_value tCOLON2 operation2 paren_args
- {
- $$ = new_call($1, $3, $4);
- fixpos($$, $1);
- }
- | primary_value tCOLON2 operation3
- {
- $$ = new_call($1, $3, 0);
- }
- | kSUPER paren_args
- {
- $$ = new_super($2);
- }
- | kSUPER
- {
- $$ = NEW_ZSUPER();
- }
- ;
- brace_block : '{'
- {
- $<vars>$ = dyna_push();
- $<num>1 = ruby_sourceline;
- }
- opt_block_var {$<vars>$ = ruby_dyna_vars;}
- compstmt '}'
- {
- $$ = NEW_ITER($3, 0, dyna_init($5, $<vars>4));
- nd_set_line($$, $<num>1);
- dyna_pop($<vars>2);
- }
- | kDO
- {
- $<vars>$ = dyna_push();
- $<num>1 = ruby_sourceline;
- }
- opt_block_var {$<vars>$ = ruby_dyna_vars;}
- compstmt kEND
- {
- $$ = NEW_ITER($3, 0, dyna_init($5, $<vars>4));
- nd_set_line($$, $<num>1);
- dyna_pop($<vars>2);
- }
- ;
- case_body : kWHEN when_args then
- compstmt
- cases
- {
- $$ = NEW_WHEN($2, $4, $5);
- }
- ;
- when_args : args
- | args ',' tSTAR arg_value
- {
- $$ = list_append($1, NEW_WHEN($4, 0, 0));
- }
- | tSTAR arg_value
- {
- $$ = NEW_LIST(NEW_WHEN($2, 0, 0));
- }
- ;
- cases : opt_else
- | case_body
- ;
- opt_rescue : kRESCUE exc_list exc_var then
- compstmt
- opt_rescue
- {
- if ($3) {
- $3 = node_assign($3, NEW_GVAR(rb_intern("$!")));
- $5 = block_append($3, $5);
- }
- $$ = NEW_RESBODY($2, $5, $6);
- fixpos($$, $2?$2:$5);
- }
- | none
- ;
- exc_list : arg_value
- {
- $$ = NEW_LIST($1);
- }
- | mrhs
- | none
- ;
- exc_var : tASSOC lhs
- {
- $$ = $2;
- }
- | none
- ;
- opt_ensure : kENSURE compstmt
- {
- if ($2)
- $$ = $2;
- else
- /* place holder */
- $$ = NEW_NIL();
- }
- | none
- ;
- literal : numeric
- | symbol
- {
- $$ = NEW_LIT(ID2SYM($1));
- }
- | dsym
- ;
- strings : string
- {
- NODE *node = $1;
- if (!node) {
- node = NEW_STR(rb_str_new(0, 0));
- }
- else {
- node = evstr2dstr(node);
- }
- $$ = node;
- }
- ;
- string : string1
- | string string1
- {
- $$ = literal_concat($1, $2);
- }
- ;
- string1 : tSTRING_BEG string_contents tSTRING_END
- {
- $$ = $2;
- }
- ;
- xstring : tXSTRING_BEG xstring_contents tSTRING_END
- {
- NODE *node = $2;
- if (!node) {
- node = NEW_XSTR(rb_str_new(0, 0));
- }
- else {
- switch (nd_type(node)) {
- case NODE_STR:
- nd_set_type(node, NODE_XSTR);
- break;
- case NODE_DSTR:
- nd_set_type(node, NODE_DXSTR);
- break;
- default:
- node = NEW_NODE(NODE_DXSTR, rb_str_new(0, 0), 1, NEW_LIST(node));
- break;
- }
- }
- $$ = node;
- }
- ;
- regexp : tREGEXP_BEG xstring_contents tREGEXP_END
- {
- int options = $3;
- NODE *node = $2;
- if (!node) {
- node = NEW_LIT(rb_reg_new("", 0, options & ~RE_OPTION_ONCE));
- }
- else switch (nd_type(node)) {
- case NODE_STR:
- {
- VALUE src = node->nd_lit;
- nd_set_type(node, NODE_LIT);
- node->nd_lit = rb_reg_new(RSTRING(src)->ptr,
- RSTRING(src)->len,
- options & ~RE_OPTION_ONCE);
- }
- break;
- default:
- node = NEW_NODE(NODE_DSTR, rb_str_new(0, 0), 1, NEW_LIST(node));
- case NODE_DSTR:
- if (options & RE_OPTION_ONCE) {
- nd_set_type(node, NODE_DREGX_ONCE);
- }
- else {
- nd_set_type(node, NODE_DREGX);
- }
- node->nd_cflag = options & ~RE_OPTION_ONCE;
- break;
- }
- $$ = node;
- }
- ;
- words : tWORDS_BEG ' ' tSTRING_END
- {
- $$ = NEW_ZARRAY();
- }
- | tWORDS_BEG word_list tSTRING_END
- {
- $$ = $2;
- }
- ;
- word_list : /* none */
- {
- $$ = 0;
- }
- | word_list word ' '
- {
- $$ = list_append($1, evstr2dstr($2));
- }
- ;
- word : string_content
- | word string_content
- {
- $$ = literal_concat($1, $2);
- }
- ;
- qwords : tQWORDS_BEG ' ' tSTRING_END
- {
- $$ = NEW_ZARRAY();
- }
- | tQWORDS_BEG qword_list tSTRING_END
- {
- $$ = $2;
- }
- ;
- qword_list : /* none */
- {
- $$ = 0;
- }
- | qword_list tSTRING_CONTENT ' '
- {
- $$ = list_append($1, $2);
- }
- ;
- string_contents : /* none */
- {
- $$ = 0;
- }
- | string_contents string_content
- {
- $$ = literal_concat($1, $2);
- }
- ;
- xstring_contents: /* none */
- {
- $$ = 0;
- }
- | xstring_contents string_content
- {
- $$ = literal_concat($1, $2);
- }
- ;
- string_content : tSTRING_CONTENT
- | tSTRING_DVAR
- {
- $<node>$ = lex_strterm;
- lex_strterm = 0;
- lex_state = EXPR_BEG;
- }
- string_dvar
- {
- lex_strterm = $<node>2;
- $$ = NEW_EVSTR($3);
- }
- | tSTRING_DBEG
- {
- $<node>$ = lex_strterm;
- lex_strterm = 0;
- lex_state = EXPR_BEG;
- COND_PUSH(0);
- CMDARG_PUSH(0);
- }
- compstmt '}'
- {
- lex_strterm = $<node>2;
- COND_LEXPOP();
- CMDARG_LEXPOP();
- if (($$ = $3) && nd_type($$) == NODE_NEWLINE) {
- $$ = $$->nd_next;
- rb_gc_force_recycle((VALUE)$3);
- }
- $$ = new_evstr($$);
- }
- ;
- string_dvar : tGVAR {$$ = NEW_GVAR($1);}
- | tIVAR {$$ = NEW_IVAR($1);}
- | tCVAR {$$ = NEW_CVAR($1);}
- | backref
- ;
- symbol : tSYMBEG sym
- {
- lex_state = EXPR_END;
- $$ = $2;
- }
- ;
- sym : fname
- | tIVAR
- | tGVAR
- | tCVAR
- ;
- dsym : tSYMBEG xstring_contents tSTRING_END
- {
- lex_state = EXPR_END;
- if (!($$ = $2)) {
- yyerror("empty symbol literal");
- }
- else {
- switch (nd_type($$)) {
- case NODE_DSTR:
- nd_set_type($$, NODE_DSYM);
- break;
- case NODE_STR:
- if (strlen(RSTRING($$->nd_lit)->ptr) == RSTRING($$->nd_lit)->len) {
- $$->nd_lit = ID2SYM(rb_intern(RSTRING($$->nd_lit)->ptr));
- nd_set_type($$, NODE_LIT);
- break;
- }
- /* fall through */
- default:
- $$ = NEW_NODE(NODE_DSYM, rb_str_new(0, 0), 1, NEW_LIST($$));
- break;
- }
- }
- }
- ;
- numeric : tINTEGER
- | tFLOAT
- | tUMINUS_NUM tINTEGER %prec tLOWEST
- {
- $$ = negate_lit($2);
- }
- | tUMINUS_NUM tFLOAT %prec tLOWEST
- {
- $$ = negate_lit($2);
- }
- ;
- variable : tIDENTIFIER
- | tIVAR
- | tGVAR
- | tCONSTANT
- | tCVAR
- | kNIL {$$ = kNIL;}
- | kSELF {$$ = kSELF;}
- | kTRUE {$$ = kTRUE;}
- | kFALSE {$$ = kFALSE;}
- | k__FILE__ {$$ = k__FILE__;}
- | k__LINE__ {$$ = k__LINE__;}
- ;
- var_ref : variable
- {
- $$ = gettable($1);
- }
- ;
- var_lhs : variable
- {
- $$ = assignable($1, 0);
- }
- ;
- backref : tNTH_REF
- | tBACK_REF
- ;
- superclass : term
- {
- $$ = 0;
- }
- | '<'
- {
- lex_state = EXPR_BEG;
- }
- expr_value term
- {
- $$ = $3;
- }
- | error term {yyerrok; $$ = 0;}
- ;
- f_arglist : '(' f_args opt_nl ')'
- {
- $$ = $2;
- lex_state = EXPR_BEG;
- }
- | f_args term
- {
- $$ = $1;
- }
- ;
- f_args : f_arg ',' f_optarg ',' f_rest_arg opt_f_block_arg
- {
- $$ = block_append(NEW_ARGS($1, $3, $5), $6);
- }
- | f_arg ',' f_optarg opt_f_block_arg
- {
- $$ = block_append(NEW_ARGS($1, $3, -1), $4);
- }
- | f_arg ',' f_rest_arg opt_f_block_arg
- {
- $$ = block_append(NEW_ARGS($1, 0, $3), $4);
- }
- | f_arg opt_f_block_arg
- {
- $$ = block_append(NEW_ARGS($1, 0, -1), $2);
- }
- | f_optarg ',' f_rest_arg opt_f_block_arg
- {
- $$ = block_append(NEW_ARGS(0, $1, $3), $4);
- }
- | f_optarg opt_f_block_arg
- {
- $$ = block_append(NEW_ARGS(0, $1, -1), $2);
- }
- | f_rest_arg opt_f_block_arg
- {
- $$ = block_append(NEW_ARGS(0, 0, $1), $2);
- }
- | f_block_arg
- {
- $$ = block_append(NEW_ARGS(0, 0, -1), $1);
- }
- | /* none */
- {
- $$ = NEW_ARGS(0, 0, -1);
- }
- ;
- f_norm_arg : tCONSTANT
- {
- yyerror("formal argument cannot be a constant");
- }
- | tIVAR
- {
- yyerror("formal argument cannot be an instance variable");
- }
- | tGVAR
- {
- yyerror("formal argument cannot be a global variable");
- }
- | tCVAR
- {
- yyerror("formal argument cannot be a class variable");
- }
- | tIDENTIFIER
- {
- if (!is_local_id($1))
- yyerror("formal argument must be local variable");
- else if (local_id($1))
- yyerror("duplicate argument name");
- local_cnt($1);
- $$ = 1;
- }
- ;
- f_arg : f_norm_arg
- | f_arg ',' f_norm_arg
- {
- $$ += 1;
- }
- ;
- f_opt : tIDENTIFIER '=' arg_value
- {
- if (!is_local_id($1))
- yyerror("formal argument must be local variable");
- else if (local_id($1))
- yyerror("duplicate optional argument name");
- $$ = assignable($1, $3);
- }
- ;
- f_optarg : f_opt
- {
- $$ = NEW_BLOCK($1);
- $$->nd_end = $$;
- }
- | f_optarg ',' f_opt
- {
- $$ = block_append($1, $3);
- }
- ;
- restarg_mark : '*'
- | tSTAR
- ;
- f_rest_arg : restarg_mark tIDENTIFIER
- {
- if (!is_local_id($2))
- yyerror("rest argument must be local variable");
- else if (local_id($2))
- yyerror("duplicate rest argument name");
- $$ = local_cnt($2);
- }
- | restarg_mark
- {
- $$ = -2;
- }
- ;
- blkarg_mark : '&'
- | tAMPER
- ;
- f_block_arg : blkarg_mark tIDENTIFIER
- {
- if (!is_local_id($2))
- yyerror("block argument must be local variable");
- else if (local_id($2))
- yyerror("duplicate block argument name");
- $$ = NEW_BLOCK_ARG($2);
- }
- ;
- opt_f_block_arg : ',' f_block_arg
- {
- $$ = $2;
- }
- | none
- ;
- singleton : var_ref
- {
- if (nd_type($1) == NODE_SELF) {
- $$ = NEW_SELF();
- }
- else {
- $$ = $1;
- value_expr($$);
- }
- }
- | '(' {lex_state = EXPR_BEG;} expr opt_nl ')'
- {
- if ($3 == 0) {
- yyerror("can't define singleton method for ().");
- }
- else {
- switch (nd_type($3)) {
- case NODE_STR:
- case NODE_DSTR:
- case NODE_XSTR:
- case NODE_DXSTR:
- case NODE_DREGX:
- case NODE_LIT:
- case NODE_ARRAY:
- case NODE_ZARRAY:
- yyerror("can't define singleton method for literals");
- default:
- value_expr($3);
- break;
- }
- }
- $$ = $3;
- }
- ;
- assoc_list : none
- | assocs trailer
- {
- $$ = $1;
- }
- | args trailer
- {
- if ($1->nd_alen%2 != 0) {
- yyerror("odd number list for Hash");
- }
- $$ = $1;
- }
- ;
- assocs : assoc
- | assocs ',' assoc
- {
- $$ = list_concat($1, $3);
- }
- ;
- assoc : arg_value tASSOC arg_value
- {
- $$ = list_append(NEW_LIST($1), $3);
- }
- ;
- operation : tIDENTIFIER
- | tCONSTANT
- | tFID
- ;
- operation2 : tIDENTIFIER
- | tCONSTANT
- | tFID
- | op
- ;
- operation3 : tIDENTIFIER
- | tFID
- | op
- ;
- dot_or_colon : '.'
- | tCOLON2
- ;
- opt_terms : /* none */
- | terms
- ;
- opt_nl : /* none */
- | '\n'
- ;
- trailer : /* none */
- | '\n'
- | ','
- ;
- term : ';' {yyerrok;}
- | '\n'
- ;
- terms : term
- | terms ';' {yyerrok;}
- ;
- none : /* none */ {$$ = 0;}
- ;
- %%
- #include "regex.h"
- #include "util.h"
- /* We remove any previous definition of `SIGN_EXTEND_CHAR',
- since ours (we hope) works properly with all combinations of
- machines, compilers, `char' and `unsigned char' argument types.
- (Per Bothner suggested the basic approach.) */
- #undef SIGN_EXTEND_CHAR
- #if __STDC__
- # define SIGN_EXTEND_CHAR(c) ((signed char)(c))
- #else /* not __STDC__ */
- /* As in Harbison and Steele. */
- # define SIGN_EXTEND_CHAR(c) ((((unsigned char)(c)) ^ 128) - 128)
- #endif
- #define is_identchar(c) (SIGN_EXTEND_CHAR(c)!=-1&&(ISALNUM(c) || (c) == '_' || ismbchar(c)))
- static char *tokenbuf = NULL;
- static int tokidx, toksiz = 0;
- #define LEAVE_BS 1
- static VALUE (*lex_gets)(); /* gets function */
- static VALUE lex_input; /* non-nil if File */
- static VALUE lex_lastline; /* gc protect */
- static char *lex_pbeg;
- static char *lex_p;
- static char *lex_pend;
- static int
- yyerror(msg)
- const char *msg;
- {
- char *p, *pe, *buf;
- int len, i;
- rb_compile_error("%s", msg);
- p = lex_p;
- while (lex_pbeg <= p) {
- if (*p == '\n') break;
- p--;
- }
- p++;
- pe = lex_p;
- while (pe < lex_pend) {
- if (*pe == '\n') break;
- pe++;
- }
- len = pe - p;
- if (len > 4) {
- buf = ALLOCA_N(char, len+2);
- MEMCPY(buf, p, char, len);
- buf[len] = '\0';
- rb_compile_error_append("%s", buf);
- i = lex_p - p;
- p = buf; pe = p + len;
- while (p < pe) {
- if (*p != '\t') *p = ' ';
- p++;
- }
- buf[i] = '^';
- buf[i+1] = '\0';
- rb_compile_error_append("%s", buf);
- }
- return 0;
- }
- static int heredoc_end;
- static int command_start = Qtrue;
- int ruby_in_compile = 0;
- int ruby__end__seen;
- static VALUE ruby_debug_lines;
- static NODE*
- yycompile(f, line)
- char *f;
- int line;
- {
- int n;
- NODE *node = 0;
- struct RVarmap *vp, *vars = ruby_dyna_vars;
- ruby_in_compile = 1;
- if (!compile_for_eval && rb_safe_level() == 0 &&
- rb_const_defined(rb_cObject, rb_intern("SCRIPT_LINES__"))) {
- VALUE hash, fname;
- hash = rb_const_get(rb_cObject, rb_intern("SCRIPT_LINES__"));
- if (TYPE(hash) == T_HASH) {
- fname = rb_str_new2(f);
- ruby_debug_lines = rb_hash_aref(hash, fname);
- if (NIL_P(ruby_debug_lines)) {
- ruby_debug_lines = rb_ary_new();
- rb_hash_aset(hash, fname, ruby_debug_lines);
- }
- }
- if (line > 1) {
- VALUE str = rb_str_new(0,0);
- while (line > 1) {
- rb_ary_push(ruby_debug_lines, str);
- line--;
- }
- }
- }
- ruby__end__seen = 0;
- ruby_eval_tree = 0;
- heredoc_end = 0;
- lex_strterm = 0;
- ruby_current_node = 0;
- ruby_sourcefile = rb_source_filename(f);
- n = yyparse();
- ruby_debug_lines = 0;
- compile_for_eval = 0;
- ruby_in_compile = 0;
- cond_stack = 0;
- cmdarg_stack = 0;
- command_start = 1;
- class_nest = 0;
- in_single = 0;
- in_def = 0;
- cur_mid = 0;
- vp = ruby_dyna_vars;
- ruby_dyna_vars = vars;
- lex_strterm = 0;
- while (vp && vp != vars) {
- struct RVarmap *tmp = vp;
- vp = vp->next;
- rb_gc_force_recycle((VALUE)tmp);
- }
- if (n == 0) node = ruby_eval_tree;
- else ruby_eval_tree_begin = 0;
- return node;
- }
- static int lex_gets_ptr;
- static VALUE
- lex_get_str(s)
- VALUE s;
- {
- char *beg, *end, *pend;
- beg = RSTRING(s)->ptr;
- if (lex_gets_ptr) {
- if (RSTRING(s)->len == lex_gets_ptr) return Qnil;
- beg += lex_gets_ptr;
- }
- pend = RSTRING(s)->ptr + RSTRING(s)->len;
- end = beg;
- while (end < pend) {
- if (*end++ == '\n') break;
- }
- lex_gets_ptr = end - RSTRING(s)->ptr;
- return rb_str_new(beg, end - beg);
- }
- static VALUE
- lex_getline()
- {
- VALUE line = (*lex_gets)(lex_input);
- if (ruby_debug_lines && !NIL_P(line)) {
- rb_ary_push(ruby_debug_lines, line);
- }
- return line;
- }
- NODE*
- rb_compile_string(f, s, line)
- const char *f;
- VALUE s;
- int line;
- {
- lex_gets = lex_get_str;
- lex_gets_ptr = 0;
- lex_input = s;
- lex_pbeg = lex_p = lex_pend = 0;
- ruby_sourceline = line - 1;
- compile_for_eval = ruby_in_eval;
- return yycompile(f, line);
- }
- NODE*
- rb_compile_cstr(f, s, len, line)
- const char *f, *s;
- int len, line;
- {
- return rb_compile_string(f, rb_str_new(s, len), line);
- }
- NODE*
- rb_compile_file(f, file, start)
- const char *f;
- VALUE file;
- int start;
- {
- lex_gets = rb_io_gets;
- lex_input = file;
- lex_pbeg = lex_p = lex_pend = 0;
- ruby_sourceline = start - 1;
- return yycompile(f, start);
- }
- static inline int
- nextc()
- {
- int c;
- if (lex_p == lex_pend) {
- if (lex_input) {
- VALUE v = lex_getline();
- if (NIL_P(v)) return -1;
- if (heredoc_end > 0) {
- ruby_sourceline = heredoc_end;
- heredoc_end = 0;
- }
- ruby_sourceline++;
- lex_pbeg = lex_p = RSTRING(v)->ptr;
- lex_pend = lex_p + RSTRING(v)->len;
- lex_lastline = v;
- }
- else {
- lex_lastline = 0;
- return -1;
- }
- }
- c = (unsigned char)*lex_p++;
- if (c == '\r' && lex_p < lex_pend && *lex_p == '\n') {
- lex_p++;
- c = '\n';
- }
- return c;
- }
- static void
- pushback(c)
- int c;
- {
- if (c == -1) return;
- lex_p--;
- }
- #define was_bol() (lex_p == lex_pbeg + 1)
- #define peek(c) (lex_p != lex_pend && (c) == *lex_p)
- #define tokfix() (tokenbuf[tokidx]='\0')
- #define tok() tokenbuf
- #define toklen() tokidx
- #define toklast() (tokidx>0?tokenbuf[tokidx-1]:0)
- static char*
- newtok()
- {
- tokidx = 0;
- if (!tokenbuf) {
- toksiz = 60;
- tokenbuf = ALLOC_N(char, 60);
- }
- if (toksiz > 4096) {
- toksiz = 60;
- REALLOC_N(tokenbuf, char, 60);
- }
- return tokenbuf;
- }
- static void
- tokadd(c)
- char c;
- {
- tokenbuf[tokidx++] = c;
- if (tokidx >= toksiz) {
- toksiz *= 2;
- REALLOC_N(tokenbuf, char, toksiz);
- }
- }
- static int
- read_escape()
- {
- int c;
- switch (c = nextc()) {
- case '\\': /* Backslash */
- return c;
- case 'n': /* newline */
- return '\n';
- case 't': /* horizontal tab */
- return '\t';
- case 'r': /* carriage-return */
- return '\r';
- case 'f': /* form-feed */
- return '\f';
- case 'v': /* vertical tab */
- return '\13';
- case 'a': /* alarm(bell) */
- return '\007';
- case 'e': /* escape */
- return 033;
- case '0': case '1': case '2': case '3': /* octal constant */
- case '4': case '5': case '6': case '7':
- {
- int numlen;
- pushback(c);
- c = scan_oct(lex_p, 3, &numlen);
- lex_p += numlen;
- }
- return c;
- case 'x': /* hex constant */
- {
- int numlen;
- c = scan_hex(lex_p, 2, &numlen);
- if (numlen == 0) {
- yyerror("Invalid escape character syntax");
- return 0;
- }
- lex_p += numlen;
- }
- return c;
- case 'b': /* backspace */
- return '\010';
- case 's': /* space */
- return ' ';
- case 'M':
- if ((c = nextc()) != '-') {
- yyerror("Invalid escape character syntax");
- pushback(c);
- return '\0';
- }
- if ((c = nextc()) == '\\') {
- return read_escape() | 0x80;
- }
- else if (c == -1) goto eof;
- else {
- return ((c & 0xff) | 0x80);
- }
- case 'C':
- if ((c = nextc()) != '-') {
- yyerror("Invalid escape character syntax");
- pushback(c);
- return '\0';
- }
- case 'c':
- if ((c = nextc())== '\\') {
- c = read_escape();
- }
- else if (c == '?')
- return 0177;
- else if (c == -1) goto eof;
- return c & 0x9f;
- eof:
- case -1:
- yyerror("Invalid escape character syntax");
- return '\0';
- default:
- return c;
- }
- }
- static int
- tokadd_escape(term)
- int term;
- {
- int c;
- switch (c = nextc()) {
- case '\n':
- return 0; /* just ignore */
- case '0': case '1': case '2': case '3': /* octal constant */
- case '4': case '5': case '6': case '7':
- {
- int i;
- tokadd('\\');
- tokadd(c);
- for (i=0; i<2; i++) {
- c = nextc();
- if (c == -1) goto eof;
- if (c < '0' || '7' < c) {
- pushback(c);
- break;
- }
- tokadd(c);
- }
- }
- return 0;
- case 'x': /* hex constant */
- {
- int numlen;
- tokadd('\\');
- tokadd(c);
- scan_hex(lex_p, 2, &numlen);
- if (numlen == 0) {
- yyerror("Invalid escape character syntax");
- return -1;
- }
- while (numlen--)
- tokadd(nextc());
- }
- return 0;
- case 'M':
- if ((c = nextc()) != '-') {
- yyerror("Invalid escape character syntax");
- pushback(c);
- return 0;
- }
- tokadd('\\'); tokadd('M'); tokadd('-');
- goto escaped;
- case 'C':
- if ((c = nextc()) != '-') {
- yyerror("Invalid escape character syntax");
- pushback(c);
- return 0;
- }
- tokadd('\\'); tokadd('C'); tokadd('-');
- goto escaped;
- case 'c':
- tokadd('\\'); tokadd('c');
- escaped:
- if ((c = nextc()) == '\\') {
- return tokadd_escape(term);
- }
- else if (c == -1) goto eof;
- tokadd(c);
- return 0;
- eof:
- case -1:
- yyerror("Invalid escape character syntax");
- return -1;
- default:
- if (c != '\\' || c != term)
- tokadd('\\');
- tokadd(c);
- }
- return 0;
- }
- static int
- regx_options()
- {
- char kcode = 0;
- int options = 0;
- int c;
- newtok();
- while (c = nextc(), ISALPHA(c)) {
- switch (c) {
- case 'i':
- options |= RE_OPTION_IGNORECASE;
- break;
- case 'x':
- options |= RE_OPTION_EXTENDED;
- break;
- case 'm':
- options |= RE_OPTION_MULTILINE;
- break;
- case 'o':
- options |= RE_OPTION_ONCE;
- break;
- case 'n':
- kcode = 16;
- break;
- case 'e':
- kcode = 32;
- break;
- case 's':
- kcode = 48;
- break;
- case 'u':
- kcode = 64;
- break;
- default:
- tokadd(c);
- break;
- }
- }
- pushback(c);
- if (toklen()) {
- tokfix();
- rb_compile_error("unknown regexp option%s - %s",
- toklen() > 1 ? "s" : "", tok());
- }
- return options | kcode;
- }
- #define STR_FUNC_ESCAPE 0x01
- #define STR_FUNC_EXPAND 0x02
- #define STR_FUNC_REGEXP 0x04
- #define STR_FUNC_QWORDS 0x08
- #define STR_FUNC_SYMBOL 0x10
- #define STR_FUNC_INDENT 0x20
- enum string_type {
- str_squote = (0),
- str_dquote = (STR_FUNC_EXPAND),
- str_xquote = (STR_FUNC_EXPAND),
- str_regexp = (STR_FUNC_REGEXP|STR_FUNC_ESCAPE|STR_FUNC_EXPAND),
- str_sword = (STR_FUNC_QWORDS),
- str_dword = (STR_FUNC_QWORDS|STR_FUNC_EXPAND),
- str_ssym = (STR_FUNC_SYMBOL),
- str_dsym = (STR_FUNC_SYMBOL|STR_FUNC_EXPAND),
- };
- static void
- dispose_string(str)
- VALUE str;
- {
- free(RSTRING(str)->ptr);
- rb_gc_force_recycle(str);
- }
- static int
- tokadd_string(func, term, paren, nest)
- int func, term, paren, *nest;
- {
- int c;
- while ((c = nextc()) != -1) {
- if (paren && c == paren) {
- ++*nest;
- }
- else if (c == term) {
- if (!nest || !*nest) {
- pushback(c);
- break;
- }
- --*nest;
- }
- else if ((func & STR_FUNC_EXPAND) && c == '#' && lex_p < lex_pend) {
- int c2 = *lex_p;
- if (c2 == '$' || c2 == '@' || c2 == '{') {
- pushback(c);
- break;
- }
- }
- else if (c == '\\') {
- c = nextc();
- switch (c) {
- case '\n':
- if (func & STR_FUNC_QWORDS) break;
- if (func & STR_FUNC_EXPAND) continue;
- tokadd('\\');
- break;
- case '\\':
- if (func & STR_FUNC_ESCAPE) tokadd(c);
- break;
- default:
- if (func & STR_FUNC_REGEXP) {
- pushback(c);
- if (tokadd_escape(term) < 0)
- return -1;
- continue;
- }
- else if (func & STR_FUNC_EXPAND) {
- pushback(c);
- if (func & STR_FUNC_ESCAPE) tokadd('\\');
- c = read_escape();
- }
- else if ((func & STR_FUNC_QWORDS) && ISSPACE(c)) {
- /* ignore backslashed spaces in %w */
- }
- else if (c != term && !(paren && c == paren)) {
- tokadd('\\');
- }
- }
- }
- else if (ismbchar(c)) {
- int i, len = mbclen(c)-1;
- for (i = 0; i < len; i++) {
- tokadd(c);
- c = nextc();
- }
- }
- else if ((func & STR_FUNC_QWORDS) && ISSPACE(c)) {
- pushback(c);
- break;
- }
- if (!c && (func & STR_FUNC_SYMBOL)) {
- func &= ~STR_FUNC_SYMBOL;
- rb_compile_error("symbol cannot contain '\\0'");
- continue;
- }
- tokadd(c);
- }
- return c;
- }
- #define NEW_STRTERM(func, term, paren) \
- rb_node_newnode(NODE_STRTERM, (func), (term) | ((paren) << (CHAR_BIT * 2)), 0)
- static int
- parse_string(quote)
- NODE *quote;
- {
- int func = quote->nd_func;
- int term = nd_term(quote);
- int paren = nd_paren(quote);
- int c, space = 0;
- if (func == -1) return tSTRING_END;
- c = nextc();
- if ((func & STR_FUNC_QWORDS) && ISSPACE(c)) {
- do {c = nextc();} while (ISSPACE(c));
- space = 1;
- }
- if (c == term && !quote->nd_nest) {
- if (func & STR_FUNC_QWORDS) {
- quote->nd_func = -1;
- return ' ';
- }
- if (!(func & STR_FUNC_REGEXP)) return tSTRING_END;
- yylval.num = regx_options();
- return tREGEXP_END;
- }
- if (space) {
- pushback(c);
- return ' ';
- }
- newtok();
- if ((func & STR_FUNC_EXPAND) && c == '#') {
- switch (c = nextc()) {
- case '$':
- case '@':
- pushback(c);
- return tSTRING_DVAR;
- case '{':
- return tSTRING_DBEG;
- }
- tokadd('#');
- }
- pushback(c);
- if (tokadd_string(func, term, paren, &quote->nd_nest) == -1) {
- ruby_sourceline = nd_line(quote);
- rb_compile_error("unterminated string meets end of file");
- return tSTRING_END;
- }
- tokfix();
- yylval.node = NEW_STR(rb_str_new(tok(), toklen()));
- return tSTRING_CONTENT;
- }
- static int
- heredoc_identifier()
- {
- int c = nextc(), term, func = 0, len;
- if (c == '-') {
- c = nextc();
- func = STR_FUNC_INDENT;
- }
- switch (c) {
- case '\'':
- func |= str_squote; goto quoted;
- case '"':
- func |= str_dquote; goto quoted;
- case '`':
- func |= str_xquote;
- quoted:
- newtok();
- tokadd(func);
- term = c;
- while ((c = nextc()) != -1 && c != term) {
- len = mbclen(c);
- do {tokadd(c);} while (--len > 0 && (c = nextc()) != -1);
- }
- if (c == -1) {
- rb_compile_error("unterminated here document identifier");
- return 0;
- }
- break;
- default:
- if (!is_identchar(c)) {
- pushback(c);
- if (func & STR_FUNC_INDENT) {
- pushback('-');
- }
- return 0;
- }
- newtok();
- term = '"';
- tokadd(func |= str_dquote);
- do {
- len = mbclen(c);
- do {tokadd(c);} while (--len > 0 && (c = nextc()) != -1);
- } while ((c = nextc()) != -1 && is_identchar(c));
- pushback(c);
- break;
- }
- tokfix();
- len = lex_p - lex_pbeg;
- lex_p = lex_pend;
- lex_strterm = rb_node_newnode(NODE_HEREDOC,
- rb_str_new(tok(), toklen()), /* nd_lit */
- len, /* nd_nth */
- lex_lastline); /* nd_orig */
- return term == '`' ? tXSTRING_BEG : tSTRING_BEG;
- }
- static void
- heredoc_restore(here)
- NODE *here;
- {
- VALUE line = here->nd_orig;
- lex_lastline = line;
- lex_pbeg = RSTRING(line)->ptr;
- lex_pend = lex_pbeg + RSTRING(line)->len;
- lex_p = lex_pbeg + here->nd_nth;
- heredoc_end = ruby_sourceline;
- ruby_sourceline = nd_line(here);
- dispose_string(here->nd_lit);
- rb_gc_force_recycle((VALUE)here);
- }
- static int
- whole_match_p(eos, len, indent)
- char *eos;
- int len, indent;
- {
- char *p = lex_pbeg;
- int n;
- if (indent) {
- while (*p && ISSPACE(*p)) p++;
- }
- n= lex